1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 jcenter()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:3.3.0'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 jcenter()
18 mavenCentral()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 quicksyFreeCompatImplementation
26 quicksyImplementation
27}
28
29ext {
30 supportLibVersion = '28.0.0'
31}
32
33dependencies {
34 playstoreImplementation('com.google.firebase:firebase-messaging:17.3.4') {
35 exclude group: 'com.google.firebase', module: 'firebase-core'
36 exclude group: 'com.google.firebase', module: 'firebase-analytics'
37 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
38 }
39 implementation 'org.sufficientlysecure:openpgp-api:10.0'
40 implementation ('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
41 exclude group: 'com.android.support', module: 'appcompat-v7'
42 exclude group: 'com.android.support', module: 'exifinterface'
43 }
44 implementation "com.android.support:support-v13:$supportLibVersion"
45 implementation "com.android.support:appcompat-v7:$supportLibVersion"
46 implementation "com.android.support:exifinterface:$supportLibVersion"
47 implementation "com.android.support:cardview-v7:$supportLibVersion"
48 implementation "com.android.support:support-emoji:$supportLibVersion"
49 implementation "com.android.support:design:$supportLibVersion"
50 compatImplementation "com.android.support:support-emoji-appcompat:$supportLibVersion"
51 conversationsFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
52 quicksyFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
53 implementation 'org.bouncycastle:bcmail-jdk15on:1.58'
54 implementation 'com.google.zxing:core:3.3.3'
55 implementation 'de.measite.minidns:minidns-hla:0.2.4'
56 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
57 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
58 implementation 'com.makeramen:roundedimageview:2.3.0'
59 implementation "com.wefika:flowlayout:0.4.1"
60 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
61 implementation project(':libs:xmpp-addr')
62 implementation 'org.osmdroid:osmdroid-android:6.0.3'
63 implementation 'org.hsluv:hsluv:0.2'
64 implementation 'org.conscrypt:conscrypt-android:1.3.0'
65 implementation 'me.drakeet.support:toastcompat:1.1.0'
66 implementation "com.leinardi.android:speed-dial:2.0.1"
67 implementation 'com.squareup.retrofit2:retrofit:2.5.0'
68 implementation 'com.squareup.retrofit2:converter-gson:2.5.0'
69 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.10.1'
70}
71
72ext {
73 travisBuild = System.getenv("TRAVIS") == "true"
74 preDexEnabled = System.getProperty("pre-dex", "true")
75}
76
77android {
78 compileSdkVersion 28
79
80 defaultConfig {
81 minSdkVersion 16
82 targetSdkVersion 28
83 versionCode 323
84 versionName "2.4.3"
85 archivesBaseName += "-$versionName"
86 applicationId "eu.siacs.conversations"
87 resValue "string", "applicationId", applicationId
88 resValue "string", "app_name", "Conversations"
89 buildConfigField "String", "LOGTAG", "\"conversations\""
90 }
91
92 dataBinding {
93 enabled true
94 }
95
96 dexOptions {
97 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
98 preDexLibraries = preDexEnabled && !travisBuild
99 jumboMode true
100 }
101
102 compileOptions {
103 sourceCompatibility JavaVersion.VERSION_1_8
104 targetCompatibility JavaVersion.VERSION_1_8
105 }
106
107 flavorDimensions("mode", "distribution", "emoji")
108
109 productFlavors {
110
111 quicksy {
112 dimension "mode"
113 applicationId = "im.quicksy.client"
114 resValue "string", "app_name", "Quicksy"
115 resValue "string", "applicationId", applicationId
116 buildConfigField "String", "LOGTAG", "\"quicksy\""
117 }
118
119 conversations {
120 dimension "mode"
121 }
122
123 playstore {
124 dimension "distribution"
125 versionNameSuffix "+p"
126 }
127 free {
128 dimension "distribution"
129 versionNameSuffix "+f"
130 }
131 system {
132 dimension "emoji"
133 versionNameSuffix "s"
134 }
135 compat {
136 dimension "emoji"
137 versionNameSuffix "c"
138 }
139 }
140
141 sourceSets {
142 quicksyFreeCompat {
143 java {
144 srcDirs 'src/freeCompat/java'
145 }
146 }
147 quicksyPlaystoreCompat {
148 java {
149 srcDirs 'src/playstoreCompat/java'
150 }
151 res {
152 srcDir 'src/playstoreCompat/res'
153 srcDir 'src/quicksyPlaystore/res'
154 }
155 }
156 quicksyPlaystoreSystem {
157 res {
158 srcDir 'src/quicksyPlaystore/res'
159 }
160 }
161 conversationsFreeCompat {
162 java {
163 srcDirs 'src/freeCompat/java'
164 }
165 }
166 conversationsPlaystoreCompat {
167 java {
168 srcDirs 'src/playstoreCompat/java'
169 }
170 res {
171 srcDir 'src/playstoreCompat/res'
172 srcDir 'src/conversationsPlaystore/res'
173 }
174 }
175 conversationsPlaystoreSystem {
176 res {
177 srcDir 'src/conversationsPlaystore/res'
178 }
179 }
180 }
181
182 buildTypes {
183 release {
184 shrinkResources true
185 minifyEnabled true
186 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
187 versionNameSuffix "r"
188 }
189 debug {
190 shrinkResources true
191 minifyEnabled true
192 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
193 versionNameSuffix "d"
194 }
195 }
196
197
198
199 if (new File("signing.properties").exists()) {
200 Properties props = new Properties()
201 props.load(new FileInputStream(file("signing.properties")))
202
203 signingConfigs {
204 release {
205 storeFile file(props['keystore'])
206 storePassword props['keystore.password']
207 keyAlias props['keystore.alias']
208 keyPassword props['keystore.password']
209 }
210 }
211 buildTypes.release.signingConfig = signingConfigs.release
212 }
213
214 lintOptions {
215 disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
216 }
217
218 subprojects {
219
220 afterEvaluate {
221 if (getPlugins().hasPlugin('android') ||
222 getPlugins().hasPlugin('android-library')) {
223
224 configure(android.lintOptions) {
225 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
226 }
227 }
228
229 }
230 }
231
232 packagingOptions {
233 exclude 'META-INF/BCKEY.DSA'
234 exclude 'META-INF/BCKEY.SF'
235 }
236}