1import com.android.build.OutputFile
2
3// Top-level build file where you can add configuration options common to all
4// sub-projects/modules.
5buildscript {
6 repositories {
7 google()
8 mavenCentral()
9 }
10 dependencies {
11 classpath 'com.android.tools.build:gradle:4.2.1'
12 }
13}
14
15apply plugin: 'com.android.application'
16
17repositories {
18 google()
19 mavenCentral()
20 jcenter()
21}
22
23configurations {
24 playstoreImplementation
25 compatImplementation
26 conversationsFreeCompatImplementation
27 conversationsPlaystoreCompatImplementation
28 conversationsPlaystoreSystemImplementation
29 quicksyPlaystoreCompatImplementation
30 quicksyPlaystoreSystemImplementation
31 quicksyFreeCompatImplementation
32 quicksyImplementation
33}
34
35dependencies {
36 implementation 'androidx.viewpager:viewpager:1.0.0'
37
38 playstoreImplementation('com.google.firebase:firebase-messaging:22.0.0') {
39 exclude group: 'com.google.firebase', module: 'firebase-core'
40 exclude group: 'com.google.firebase', module: 'firebase-analytics'
41 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
42 }
43 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
44 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
45 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
46 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
47 implementation 'org.sufficientlysecure:openpgp-api:10.0'
48 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
49 implementation 'androidx.appcompat:appcompat:1.2.0'
50 implementation 'androidx.exifinterface:exifinterface:1.3.2'
51 implementation 'androidx.cardview:cardview:1.0.0'
52 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
53 implementation 'androidx.emoji:emoji:1.1.0'
54 implementation 'com.google.android.material:material:1.3.0'
55 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
56 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
57 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
58 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
59 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
60 //https://github.com/zxing/zxing/issues/1170
61 implementation 'com.google.zxing:core:3.3.3'
62 implementation 'de.measite.minidns:minidns-hla:0.2.4'
63 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
64 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
65 implementation 'com.makeramen:roundedimageview:2.3.0'
66 implementation "com.wefika:flowlayout:0.4.1"
67 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
68 implementation 'org.jxmpp:jxmpp-jid:1.0.1'
69 implementation 'org.osmdroid:osmdroid-android:6.1.10'
70 implementation 'org.hsluv:hsluv:0.2'
71 implementation 'org.conscrypt:conscrypt-android:2.5.2'
72 implementation 'me.drakeet.support:toastcompat:1.1.0'
73 implementation "com.leinardi.android:speed-dial:2.0.1"
74
75 implementation "com.squareup.retrofit2:retrofit:2.9.0"
76 implementation "com.squareup.retrofit2:converter-gson:2.9.0"
77 implementation "com.squareup.okhttp3:okhttp:4.9.1"
78
79 implementation 'com.google.guava:guava:30.1.1-android'
80 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.12.18'
81 implementation 'org.webrtc:google-webrtc:1.0.32006'
82}
83
84ext {
85 travisBuild = System.getenv("TRAVIS") == "true"
86 preDexEnabled = System.getProperty("pre-dex", "true")
87 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
88}
89
90android {
91 compileSdkVersion 29
92
93 defaultConfig {
94 minSdkVersion 21
95 targetSdkVersion 29
96 versionCode 42015
97 versionName "2.9.13"
98 archivesBaseName += "-$versionName"
99 applicationId "eu.siacs.conversations"
100 resValue "string", "applicationId", applicationId
101 def appName = "Conversations"
102 resValue "string", "app_name", appName
103 buildConfigField "String", "APP_NAME", "\"$appName\"";
104 }
105
106
107 configurations {
108 compile.exclude group: 'org.jetbrains' , module:'annotations'
109 }
110
111 dataBinding {
112 enabled true
113 }
114
115 dexOptions {
116 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
117 preDexLibraries = preDexEnabled && !travisBuild
118 jumboMode true
119 }
120
121 compileOptions {
122 sourceCompatibility JavaVersion.VERSION_1_8
123 targetCompatibility JavaVersion.VERSION_1_8
124 }
125
126 flavorDimensions("mode", "distribution", "emoji")
127
128 productFlavors {
129
130 quicksy {
131 dimension "mode"
132 applicationId = "im.quicksy.client"
133 resValue "string", "applicationId", applicationId
134
135 def appName = "Quicksy"
136 resValue "string", "app_name", appName
137 buildConfigField "String", "APP_NAME", "\"$appName\"";
138 }
139
140 conversations {
141 dimension "mode"
142 }
143
144 cheogram {
145 dimension "mode"
146
147 applicationId = "com.cheogram.android"
148 resValue "string", "applicationId", applicationId
149
150 def appName = "Cheogram"
151 resValue "string", "app_name", appName
152 buildConfigField "String", "APP_NAME", "\"$appName\"";
153 }
154
155 playstore {
156 dimension "distribution"
157 versionNameSuffix "+p"
158 }
159 free {
160 dimension "distribution"
161 versionNameSuffix "+f"
162 }
163 system {
164 dimension "emoji"
165 versionNameSuffix "s"
166 }
167 compat {
168 dimension "emoji"
169 versionNameSuffix "c"
170 }
171 }
172
173 sourceSets {
174 quicksyFreeSystem {
175 java {
176 srcDir 'src/quicksyFree/java'
177 }
178 }
179 quicksyFreeCompat {
180 java {
181 srcDir 'src/freeCompat/java'
182 srcDir 'src/quicksyFree/java'
183 }
184 }
185 quicksyPlaystoreCompat {
186 java {
187 srcDir 'src/playstoreCompat/java'
188 srcDir 'src/quicksyPlaystore/java'
189 }
190 res {
191 srcDir 'src/playstoreCompat/res'
192 srcDir 'src/quicksyPlaystore/res'
193 }
194 }
195 quicksyPlaystoreSystem {
196 java {
197 srcDir 'src/quicksyPlaystore/java'
198 }
199 res {
200 srcDir 'src/quicksyPlaystore/res'
201 }
202 }
203 conversationsFreeCompat {
204 java {
205 srcDir 'src/freeCompat/java'
206 srcDir 'src/conversationsFree/java'
207 }
208 }
209 conversationsFreeSystem {
210 java {
211 srcDir 'src/conversationsFree/java'
212 }
213 }
214 cheogramFreeCompat {
215 java {
216 srcDir 'src/freeCompat/java'
217 srcDir 'src/conversationsFree/java'
218 }
219 }
220 cheogramFreeSystem {
221 java {
222 srcDir 'src/conversationsFree/java'
223 }
224 }
225 conversationsPlaystoreCompat {
226 java {
227 srcDir 'src/playstoreCompat/java'
228 srcDir 'src/conversationsPlaystore/java'
229 }
230 res {
231 srcDir 'src/playstoreCompat/res'
232 srcDir 'src/conversationsPlaystore/res'
233 }
234 }
235 conversationsPlaystoreSystem {
236 java {
237 srcDir 'src/conversationsPlaystore/java'
238 }
239 res {
240 srcDir 'src/conversationsPlaystore/res'
241 }
242 }
243 }
244
245 buildTypes {
246 release {
247 shrinkResources true
248 minifyEnabled true
249 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
250 versionNameSuffix "r"
251 }
252 debug {
253 shrinkResources true
254 minifyEnabled true
255 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
256 versionNameSuffix "d"
257 }
258 }
259
260
261 if (new File("signing.properties").exists()) {
262 Properties props = new Properties()
263 props.load(new FileInputStream(file("signing.properties")))
264
265 signingConfigs {
266 release {
267 storeFile file(props['keystore'])
268 storePassword props['keystore.password']
269 keyAlias props['keystore.alias']
270 keyPassword props['keystore.password']
271 }
272 }
273 buildTypes.release.signingConfig = signingConfigs.release
274 }
275
276 lintOptions {
277 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
278 abortOnError false
279 }
280
281 subprojects {
282
283 afterEvaluate {
284 if (getPlugins().hasPlugin('android') ||
285 getPlugins().hasPlugin('android-library')) {
286
287 configure(android.lintOptions) {
288 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
289 abortOnError false
290 }
291 }
292
293 }
294 }
295
296 packagingOptions {
297 exclude 'META-INF/BCKEY.DSA'
298 exclude 'META-INF/BCKEY.SF'
299 }
300
301}