1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 jcenter()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:3.3.0'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 jcenter()
18 mavenCentral()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 quicksyFreeCompatImplementation
26 quicksyImplementation
27}
28
29ext {
30 supportLibVersion = '28.0.0'
31}
32
33dependencies {
34 playstoreImplementation('com.google.firebase:firebase-messaging:17.3.4') {
35 exclude group: 'com.google.firebase', module: 'firebase-core'
36 exclude group: 'com.google.firebase', module: 'firebase-analytics'
37 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
38 }
39 implementation 'org.sufficientlysecure:openpgp-api:10.0'
40 implementation ('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
41 exclude group: 'com.android.support', module: 'appcompat-v7'
42 exclude group: 'com.android.support', module: 'exifinterface'
43 }
44 implementation "com.android.support:support-v13:$supportLibVersion"
45 implementation "com.android.support:appcompat-v7:$supportLibVersion"
46 implementation "com.android.support:exifinterface:$supportLibVersion"
47 implementation "com.android.support:cardview-v7:$supportLibVersion"
48 implementation "com.android.support:support-emoji:$supportLibVersion"
49 implementation "com.android.support:design:$supportLibVersion"
50 compatImplementation "com.android.support:support-emoji-appcompat:$supportLibVersion"
51 conversationsFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
52 quicksyFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
53 implementation 'org.bouncycastle:bcmail-jdk15on:1.58'
54 implementation 'com.google.zxing:core:3.3.3'
55 implementation 'de.measite.minidns:minidns-hla:0.2.4'
56 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
57 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
58 implementation 'com.makeramen:roundedimageview:2.3.0'
59 implementation "com.wefika:flowlayout:0.4.1"
60 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
61 implementation project(':libs:xmpp-addr')
62 implementation 'org.osmdroid:osmdroid-android:6.0.3'
63 implementation 'org.hsluv:hsluv:0.2'
64 implementation 'org.conscrypt:conscrypt-android:1.3.0'
65 implementation 'me.drakeet.support:toastcompat:1.1.0'
66 implementation "com.leinardi.android:speed-dial:2.0.1"
67 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.10.1'
68}
69
70ext {
71 travisBuild = System.getenv("TRAVIS") == "true"
72 preDexEnabled = System.getProperty("pre-dex", "true")
73}
74
75android {
76 compileSdkVersion 28
77
78 defaultConfig {
79 minSdkVersion 16
80 targetSdkVersion 28
81 versionCode 317
82 versionName "2.3.12"
83 archivesBaseName += "-$versionName"
84 applicationId "eu.siacs.conversations"
85 resValue "string", "applicationId", applicationId
86 resValue "string", "app_name", "Conversations"
87 buildConfigField "String", "LOGTAG", "\"conversations\""
88 }
89
90 dataBinding {
91 enabled true
92 }
93
94 dexOptions {
95 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
96 preDexLibraries = preDexEnabled && !travisBuild
97 jumboMode true
98 }
99
100 compileOptions {
101 sourceCompatibility JavaVersion.VERSION_1_8
102 targetCompatibility JavaVersion.VERSION_1_8
103 }
104
105 flavorDimensions("mode", "distribution", "emoji")
106
107 productFlavors {
108
109 quicksy {
110 dimension "mode"
111 applicationId = "im.quicksy.client"
112 resValue "string", "app_name", "Quicksy"
113 resValue "string", "applicationId", applicationId
114 buildConfigField "String", "LOGTAG", "\"quicksy\""
115 }
116
117 conversations {
118 dimension "mode"
119 }
120
121 playstore {
122 dimension "distribution"
123 versionNameSuffix "+p"
124 }
125 free {
126 dimension "distribution"
127 versionNameSuffix "+f"
128 }
129 system {
130 dimension "emoji"
131 versionNameSuffix "s"
132 }
133 compat {
134 dimension "emoji"
135 versionNameSuffix "c"
136 }
137 }
138
139 sourceSets {
140 quicksyFreeCompat {
141 java {
142 srcDirs 'src/freeCompat/java'
143 }
144 }
145 quicksyPlaystoreCompat {
146 java {
147 srcDirs 'src/playstoreCompat/java'
148 }
149 res {
150 srcDir 'src/playstoreCompat/res'
151 srcDir 'src/quicksyPlaystore/res'
152 }
153 }
154 quicksyPlaystoreSystem {
155 res {
156 srcDir 'src/quicksyPlaystore/res'
157 }
158 }
159 conversationsFreeCompat {
160 java {
161 srcDirs 'src/freeCompat/java'
162 }
163 }
164 conversationsPlaystoreCompat {
165 java {
166 srcDirs 'src/playstoreCompat/java'
167 }
168 res {
169 srcDir 'src/playstoreCompat/res'
170 srcDir 'src/conversationsPlaystore/res'
171 }
172 }
173 conversationsPlaystoreSystem {
174 res {
175 srcDir 'src/conversationsPlaystore/res'
176 }
177 }
178 }
179
180 buildTypes {
181 release {
182 shrinkResources true
183 minifyEnabled true
184 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
185 versionNameSuffix "r"
186 }
187 debug {
188 shrinkResources true
189 minifyEnabled true
190 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
191 versionNameSuffix "d"
192 }
193 }
194
195
196
197 if (new File("signing.properties").exists()) {
198 Properties props = new Properties()
199 props.load(new FileInputStream(file("signing.properties")))
200
201 signingConfigs {
202 release {
203 storeFile file(props['keystore'])
204 storePassword props['keystore.password']
205 keyAlias props['keystore.alias']
206 keyPassword props['keystore.password']
207 }
208 }
209 buildTypes.release.signingConfig = signingConfigs.release
210 }
211
212 lintOptions {
213 disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
214 }
215
216 subprojects {
217
218 afterEvaluate {
219 if (getPlugins().hasPlugin('android') ||
220 getPlugins().hasPlugin('android-library')) {
221
222 configure(android.lintOptions) {
223 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
224 }
225 }
226
227 }
228 }
229
230 packagingOptions {
231 exclude 'META-INF/BCKEY.DSA'
232 exclude 'META-INF/BCKEY.SF'
233 }
234}