1import com.android.build.OutputFile
2
3// Top-level build file where you can add configuration options common to all
4// sub-projects/modules.
5buildscript {
6 repositories {
7 google()
8 jcenter()
9 }
10 dependencies {
11 classpath 'com.android.tools.build:gradle:4.1.2'
12 }
13}
14
15apply plugin: 'com.android.application'
16
17repositories {
18 google()
19 jcenter()
20 mavenCentral()
21}
22
23configurations {
24 playstoreImplementation
25 compatImplementation
26 conversationsFreeCompatImplementation
27 conversationsPlaystoreCompatImplementation
28 conversationsPlaystoreSystemImplementation
29 quicksyPlaystoreCompatImplementation
30 quicksyPlaystoreSystemImplementation
31 quicksyFreeCompatImplementation
32 quicksyImplementation
33}
34
35dependencies {
36 implementation 'androidx.viewpager:viewpager:1.0.0'
37
38 playstoreImplementation('com.google.firebase:firebase-messaging:21.0.1') {
39 exclude group: 'com.google.firebase', module: 'firebase-core'
40 exclude group: 'com.google.firebase', module: 'firebase-analytics'
41 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
42 }
43 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
44 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
45 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
46 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
47 implementation 'org.sufficientlysecure:openpgp-api:10.0'
48 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
49 implementation 'androidx.appcompat:appcompat:1.2.0'
50 implementation 'androidx.exifinterface:exifinterface:1.3.2'
51 implementation 'androidx.cardview:cardview:1.0.0'
52 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
53 implementation 'androidx.emoji:emoji:1.1.0'
54 implementation 'com.google.android.material:material:1.3.0'
55 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
56 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
57 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
58 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
59 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
60 //https://github.com/zxing/zxing/issues/1170
61 implementation 'com.google.zxing:core:3.3.3'
62 implementation 'de.measite.minidns:minidns-hla:0.2.4'
63 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
64 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
65 implementation 'com.makeramen:roundedimageview:2.3.0'
66 implementation "com.wefika:flowlayout:0.4.1"
67 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
68 implementation 'org.jxmpp:jxmpp-jid:0.6.4'
69 implementation 'org.osmdroid:osmdroid-android:6.1.10'
70 implementation 'org.hsluv:hsluv:0.2'
71 implementation 'org.conscrypt:conscrypt-android:2.2.1'
72 implementation 'me.drakeet.support:toastcompat:1.1.0'
73 implementation "com.leinardi.android:speed-dial:2.0.1"
74
75 implementation "com.squareup.retrofit2:retrofit:2.9.0"
76 implementation "com.squareup.retrofit2:converter-gson:2.9.0"
77 //implementation "com.squareup.okhttp3:logging-interceptor:3.14.9"
78 implementation 'com.google.guava:guava:30.1-android'
79 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.12.18'
80 implementation fileTree(include: ['libwebrtc-m89.aar'], dir: 'libs')
81}
82
83ext {
84 travisBuild = System.getenv("TRAVIS") == "true"
85 preDexEnabled = System.getProperty("pre-dex", "true")
86 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
87}
88
89android {
90 compileSdkVersion 29
91
92 defaultConfig {
93 minSdkVersion 21
94 targetSdkVersion 29
95 versionCode 42006
96 versionName "2.9.8"
97 archivesBaseName += "-$versionName"
98 applicationId "eu.siacs.conversations"
99 resValue "string", "applicationId", applicationId
100 resValue "string", "app_name", "Conversations"
101 buildConfigField "String", "LOGTAG", "\"conversations\""
102 }
103
104 splits {
105 abi {
106 universalApk true
107 enable true
108 }
109 }
110
111 dataBinding {
112 enabled true
113 }
114
115 dexOptions {
116 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
117 preDexLibraries = preDexEnabled && !travisBuild
118 jumboMode true
119 }
120
121 compileOptions {
122 sourceCompatibility JavaVersion.VERSION_1_8
123 targetCompatibility JavaVersion.VERSION_1_8
124 }
125
126 flavorDimensions("mode", "distribution", "emoji")
127
128 productFlavors {
129
130 quicksy {
131 dimension "mode"
132 applicationId = "im.quicksy.client"
133 resValue "string", "app_name", "Quicksy"
134 resValue "string", "applicationId", applicationId
135 buildConfigField "String", "LOGTAG", "\"quicksy\""
136 }
137
138 conversations {
139 dimension "mode"
140 }
141
142 playstore {
143 dimension "distribution"
144 versionNameSuffix "+p"
145 }
146 free {
147 dimension "distribution"
148 versionNameSuffix "+f"
149 }
150 system {
151 dimension "emoji"
152 versionNameSuffix "s"
153 }
154 compat {
155 dimension "emoji"
156 versionNameSuffix "c"
157 }
158 }
159
160 sourceSets {
161 quicksyFreeSystem {
162 java {
163 srcDir 'src/quicksyFree/java'
164 }
165 }
166 quicksyFreeCompat {
167 java {
168 srcDir 'src/freeCompat/java'
169 srcDir 'src/quicksyFree/java'
170 }
171 }
172 quicksyPlaystoreCompat {
173 java {
174 srcDir 'src/playstoreCompat/java'
175 srcDir 'src/quicksyPlaystore/java'
176 }
177 res {
178 srcDir 'src/playstoreCompat/res'
179 srcDir 'src/quicksyPlaystore/res'
180 }
181 }
182 quicksyPlaystoreSystem {
183 java {
184 srcDir 'src/quicksyPlaystore/java'
185 }
186 res {
187 srcDir 'src/quicksyPlaystore/res'
188 }
189 }
190 conversationsFreeCompat {
191 java {
192 srcDir 'src/freeCompat/java'
193 srcDir 'src/conversationsFree/java'
194 }
195 }
196 conversationsFreeSystem {
197 java {
198 srcDir 'src/conversationsFree/java'
199 }
200 }
201 conversationsPlaystoreCompat {
202 java {
203 srcDir 'src/playstoreCompat/java'
204 srcDir 'src/conversationsPlaystore/java'
205 }
206 res {
207 srcDir 'src/playstoreCompat/res'
208 srcDir 'src/conversationsPlaystore/res'
209 }
210 }
211 conversationsPlaystoreSystem {
212 java {
213 srcDir 'src/conversationsPlaystore/java'
214 }
215 res {
216 srcDir 'src/conversationsPlaystore/res'
217 }
218 }
219 }
220
221 buildTypes {
222 release {
223 shrinkResources true
224 minifyEnabled true
225 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
226 versionNameSuffix "r"
227 }
228 debug {
229 shrinkResources true
230 minifyEnabled true
231 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
232 versionNameSuffix "d"
233 }
234 }
235
236
237 if (new File("signing.properties").exists()) {
238 Properties props = new Properties()
239 props.load(new FileInputStream(file("signing.properties")))
240
241 signingConfigs {
242 release {
243 storeFile file(props['keystore'])
244 storePassword props['keystore.password']
245 keyAlias props['keystore.alias']
246 keyPassword props['keystore.password']
247 }
248 }
249 buildTypes.release.signingConfig = signingConfigs.release
250 }
251
252 lintOptions {
253 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
254 }
255
256 subprojects {
257
258 afterEvaluate {
259 if (getPlugins().hasPlugin('android') ||
260 getPlugins().hasPlugin('android-library')) {
261
262 configure(android.lintOptions) {
263 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
264 }
265 }
266
267 }
268 }
269
270 packagingOptions {
271 exclude 'META-INF/BCKEY.DSA'
272 exclude 'META-INF/BCKEY.SF'
273 }
274
275 android.applicationVariants.all { variant ->
276 variant.outputs.each { output ->
277 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))
278 if (baseAbiVersionCode != null) {
279 output.versionCodeOverride = (100 * variant.versionCode) + baseAbiVersionCode
280 }
281 }
282
283 }
284}