1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 jcenter()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:3.5.3'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 jcenter()
18 mavenCentral()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 conversationsPlaystoreCompatImplementation
26 conversationsPlaystoreSystemImplementation
27 quicksyFreeCompatImplementation
28 quicksyImplementation
29}
30
31ext {
32 supportLibVersion = '28.0.0'
33}
34
35dependencies {
36 playstoreImplementation('com.google.firebase:firebase-messaging:17.3.4') {
37 exclude group: 'com.google.firebase', module: 'firebase-core'
38 exclude group: 'com.google.firebase', module: 'firebase-analytics'
39 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
40 }
41 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:1.1")
42 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:1.1")
43 implementation 'org.sufficientlysecure:openpgp-api:10.0'
44 implementation('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
45 exclude group: 'com.android.support', module: 'appcompat-v7'
46 exclude group: 'com.android.support', module: 'exifinterface'
47 }
48 implementation "com.android.support:support-v13:$supportLibVersion"
49 implementation "com.android.support:appcompat-v7:$supportLibVersion"
50 implementation "com.android.support:exifinterface:$supportLibVersion"
51 implementation "com.android.support:cardview-v7:$supportLibVersion"
52 implementation "com.android.support:support-emoji:$supportLibVersion"
53 implementation "com.android.support:design:$supportLibVersion"
54 compatImplementation "com.android.support:support-emoji-appcompat:$supportLibVersion"
55 conversationsFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
56 quicksyFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
57 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
58 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
59 //https://github.com/zxing/zxing/issues/1170
60 implementation 'com.google.zxing:core:3.3.3'
61 implementation 'de.measite.minidns:minidns-hla:0.2.4'
62 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
63 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
64 implementation 'com.makeramen:roundedimageview:2.3.0'
65 implementation "com.wefika:flowlayout:0.4.1"
66 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
67 implementation project(':libs:xmpp-addr')
68 implementation 'org.osmdroid:osmdroid-android:6.1.5'
69 implementation 'org.hsluv:hsluv:0.2'
70 implementation 'org.conscrypt:conscrypt-android:2.2.1'
71 implementation 'me.drakeet.support:toastcompat:1.1.0'
72 implementation "com.leinardi.android:speed-dial:2.0.1"
73 //retrofit needs to stick with 2.6.x (https://github.com/square/retrofit/blob/master/CHANGELOG.md)
74 implementation "com.squareup.retrofit2:retrofit:2.6.4"
75 implementation "com.squareup.retrofit2:converter-gson:2.6.4"
76 //okhttp needs to stick with 3.12.x
77 implementation 'com.squareup.okhttp3:okhttp:3.12.7'
78 implementation 'com.google.guava:guava:27.1-android'
79 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.11.1'
80}
81
82ext {
83 travisBuild = System.getenv("TRAVIS") == "true"
84 preDexEnabled = System.getProperty("pre-dex", "true")
85}
86
87android {
88 compileSdkVersion 29
89
90 defaultConfig {
91 minSdkVersion 16
92 targetSdkVersion 28
93 versionCode 367
94 versionName "2.7.1"
95 archivesBaseName += "-$versionName"
96 applicationId "eu.siacs.conversations"
97 resValue "string", "applicationId", applicationId
98 resValue "string", "app_name", "Conversations"
99 buildConfigField "String", "LOGTAG", "\"conversations\""
100 }
101
102 dataBinding {
103 enabled true
104 }
105
106 dexOptions {
107 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
108 preDexLibraries = preDexEnabled && !travisBuild
109 jumboMode true
110 }
111
112 compileOptions {
113 sourceCompatibility JavaVersion.VERSION_1_8
114 targetCompatibility JavaVersion.VERSION_1_8
115 }
116
117 flavorDimensions("mode", "distribution", "emoji")
118
119 productFlavors {
120
121 quicksy {
122 dimension "mode"
123 applicationId = "im.quicksy.client"
124 resValue "string", "app_name", "Quicksy"
125 resValue "string", "applicationId", applicationId
126 buildConfigField "String", "LOGTAG", "\"quicksy\""
127 }
128
129 conversations {
130 dimension "mode"
131 }
132
133 playstore {
134 dimension "distribution"
135 versionNameSuffix "+p"
136 }
137 free {
138 dimension "distribution"
139 versionNameSuffix "+f"
140 }
141 system {
142 dimension "emoji"
143 versionNameSuffix "s"
144 }
145 compat {
146 dimension "emoji"
147 versionNameSuffix "c"
148 }
149 }
150
151 sourceSets {
152 quicksyFreeCompat {
153 java {
154 srcDir 'src/freeCompat/java'
155 }
156 }
157 quicksyPlaystoreCompat {
158 java {
159 srcDir 'src/playstoreCompat/java'
160 }
161 res {
162 srcDir 'src/playstoreCompat/res'
163 srcDir 'src/quicksyPlaystore/res'
164 }
165 }
166 quicksyPlaystoreSystem {
167 res {
168 srcDir 'src/quicksyPlaystore/res'
169 }
170 }
171 conversationsFreeCompat {
172 java {
173 srcDir 'src/freeCompat/java'
174 srcDir 'src/conversationsFree/java'
175 }
176 }
177 conversationsFreeSystem {
178 java {
179 srcDir 'src/conversationsFree/java'
180 }
181 }
182 conversationsPlaystoreCompat {
183 java {
184 srcDir 'src/playstoreCompat/java'
185 srcDir 'src/conversationsPlaystore/java'
186 }
187 res {
188 srcDir 'src/playstoreCompat/res'
189 srcDir 'src/conversationsPlaystore/res'
190 }
191 }
192 conversationsPlaystoreSystem {
193 java {
194 srcDir 'src/conversationsPlaystore/java'
195 }
196 res {
197 srcDir 'src/conversationsPlaystore/res'
198 }
199 }
200 }
201
202 buildTypes {
203 release {
204 shrinkResources true
205 minifyEnabled true
206 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
207 versionNameSuffix "r"
208 }
209 debug {
210 shrinkResources true
211 minifyEnabled true
212 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
213 versionNameSuffix "d"
214 }
215 }
216
217
218 if (new File("signing.properties").exists()) {
219 Properties props = new Properties()
220 props.load(new FileInputStream(file("signing.properties")))
221
222 signingConfigs {
223 release {
224 storeFile file(props['keystore'])
225 storePassword props['keystore.password']
226 keyAlias props['keystore.alias']
227 keyPassword props['keystore.password']
228 }
229 }
230 buildTypes.release.signingConfig = signingConfigs.release
231 }
232
233 lintOptions {
234 disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
235 }
236
237 subprojects {
238
239 afterEvaluate {
240 if (getPlugins().hasPlugin('android') ||
241 getPlugins().hasPlugin('android-library')) {
242
243 configure(android.lintOptions) {
244 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
245 }
246 }
247
248 }
249 }
250
251 packagingOptions {
252 exclude 'META-INF/BCKEY.DSA'
253 exclude 'META-INF/BCKEY.SF'
254 }
255}