1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 mavenCentral()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:7.1.1'
10 }
11}
12
13plugins {
14 id 'org.ajoberstar.grgit' version '4.1.1'
15}
16
17apply plugin: 'com.android.application'
18
19repositories {
20 google()
21 mavenCentral()
22 jcenter()
23}
24
25// https://stackoverflow.com/a/38105112/8611
26def urlFile = { url, name ->
27 File file = new File("$buildDir/download/${name}")
28 file.parentFile.mkdirs()
29 if (!file.exists()) {
30 new URL(url).withInputStream { downloadStream ->
31 file.withOutputStream { fileOut ->
32 fileOut << downloadStream
33 }
34 }
35 }
36 files(file.absolutePath)
37}
38
39configurations {
40 playstoreImplementation
41 compatImplementation
42 conversationsFreeCompatImplementation
43 conversationsPlaystoreCompatImplementation
44 conversationsPlaystoreSystemImplementation
45 quicksyPlaystoreCompatImplementation
46 quicksyPlaystoreSystemImplementation
47 quicksyFreeCompatImplementation
48 quicksyImplementation
49}
50
51dependencies {
52 implementation 'androidx.viewpager:viewpager:1.0.0'
53
54 playstoreImplementation('com.google.firebase:firebase-messaging:23.0.0') {
55 exclude group: 'com.google.firebase', module: 'firebase-core'
56 exclude group: 'com.google.firebase', module: 'firebase-analytics'
57 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
58 }
59 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
60 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
61 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:18.0.1'
62 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:18.0.1'
63 implementation 'org.sufficientlysecure:openpgp-api:10.0'
64 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
65 implementation 'androidx.appcompat:appcompat:1.3.1'
66 implementation 'androidx.exifinterface:exifinterface:1.3.3'
67 implementation 'androidx.cardview:cardview:1.0.0'
68 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
69 implementation 'androidx.emoji:emoji:1.1.0'
70 implementation 'com.google.android.material:material:1.4.0'
71 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
72 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
73 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
74 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
75 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
76 //https://github.com/zxing/zxing/issues/1170
77 implementation 'com.google.zxing:core:3.3.3'
78 implementation 'de.measite.minidns:minidns-hla:0.2.4'
79 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
80 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
81 implementation 'com.makeramen:roundedimageview:2.3.0'
82 implementation "com.wefika:flowlayout:0.4.1"
83 implementation 'com.otaliastudios:transcoder:0.10.4'
84
85 implementation 'org.jxmpp:jxmpp-jid:1.0.2'
86 implementation 'org.osmdroid:osmdroid-android:6.1.10'
87 implementation 'org.hsluv:hsluv:0.2'
88 implementation 'org.conscrypt:conscrypt-android:2.5.2'
89 implementation 'me.drakeet.support:toastcompat:1.1.0'
90 implementation "com.leinardi.android:speed-dial:3.2.0"
91
92 implementation "com.squareup.retrofit2:retrofit:2.9.0"
93 implementation "com.squareup.retrofit2:converter-gson:2.9.0"
94 implementation "com.squareup.okhttp3:okhttp:4.9.3"
95
96 implementation 'com.google.guava:guava:30.1.1-android'
97 implementation 'io.michaelrocks:libphonenumber-android:8.12.36'
98 implementation 'io.github.nishkarsh:android-permissions:2.1.6'
99 implementation urlFile('https://cloudflare-ipfs.com/ipfs/QmeqMiLxHi8AAjXobxr3QTfa1bSSLyAu86YviAqQnjxCjM/libwebrtc.aar', 'libwebrtc.aar')
100 // INSERT
101}
102
103ext {
104 travisBuild = System.getenv("TRAVIS") == "true"
105 preDexEnabled = System.getProperty("pre-dex", "true")
106 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
107}
108
109android {
110 compileSdkVersion 31
111
112 defaultConfig {
113 minSdkVersion 24
114 targetSdkVersion 29
115 versionCode 42024 + grgit.tag.list().size()
116 versionName grgit.describe(tags: true, always: true)
117 archivesBaseName += "-$versionName"
118 applicationId "eu.siacs.conversations"
119 resValue "string", "applicationId", applicationId
120 def appName = "Conversations"
121 resValue "string", "app_name", appName
122 buildConfigField "String", "APP_NAME", "\"$appName\"";
123 }
124
125
126 configurations {
127 implementation.exclude group: 'org.jetbrains' , module:'annotations'
128 }
129
130 dataBinding {
131 enabled true
132 }
133
134 compileOptions {
135 sourceCompatibility JavaVersion.VERSION_1_8
136 targetCompatibility JavaVersion.VERSION_1_8
137 }
138
139 flavorDimensions("mode", "distribution", "emoji")
140
141 productFlavors {
142
143 quicksy {
144 dimension "mode"
145 applicationId = "im.quicksy.client"
146 resValue "string", "applicationId", applicationId
147
148 def appName = "Quicksy"
149 resValue "string", "app_name", appName
150 buildConfigField "String", "APP_NAME", "\"$appName\"";
151 }
152
153 conversations {
154 dimension "mode"
155 }
156
157 cheogram {
158 dimension "mode"
159
160 applicationId = "com.cheogram.android"
161 resValue "string", "applicationId", applicationId
162
163 def appName = "Cheogram"
164 resValue "string", "app_name", appName
165 buildConfigField "String", "APP_NAME", "\"$appName\"";
166 }
167
168 playstore {
169 dimension "distribution"
170 versionNameSuffix "+p"
171 }
172 free {
173 dimension "distribution"
174 versionNameSuffix "+f"
175 }
176 system {
177 dimension "emoji"
178 versionNameSuffix "s"
179 }
180 compat {
181 dimension "emoji"
182 versionNameSuffix "c"
183 }
184 }
185
186 sourceSets {
187 quicksyFreeSystem {
188 java {
189 srcDir 'src/quicksyFree/java'
190 }
191 }
192 quicksyFreeCompat {
193 java {
194 srcDir 'src/freeCompat/java'
195 srcDir 'src/quicksyFree/java'
196 }
197 }
198 quicksyPlaystoreCompat {
199 java {
200 srcDir 'src/playstoreCompat/java'
201 srcDir 'src/quicksyPlaystore/java'
202 }
203 res {
204 srcDir 'src/playstoreCompat/res'
205 srcDir 'src/quicksyPlaystore/res'
206 }
207 }
208 quicksyPlaystoreSystem {
209 java {
210 srcDir 'src/quicksyPlaystore/java'
211 }
212 res {
213 srcDir 'src/quicksyPlaystore/res'
214 }
215 }
216 conversationsFreeCompat {
217 java {
218 srcDir 'src/freeCompat/java'
219 srcDir 'src/conversationsFree/java'
220 }
221 }
222 conversationsFreeSystem {
223 java {
224 srcDir 'src/conversationsFree/java'
225 }
226 }
227 cheogramFreeCompat {
228 java {
229 srcDir 'src/freeCompat/java'
230 srcDir 'src/conversationsFree/java'
231 }
232 }
233 cheogramFreeSystem {
234 java {
235 srcDir 'src/conversationsFree/java'
236 }
237 }
238 conversationsPlaystoreCompat {
239 java {
240 srcDir 'src/playstoreCompat/java'
241 srcDir 'src/conversationsPlaystore/java'
242 }
243 res {
244 srcDir 'src/playstoreCompat/res'
245 srcDir 'src/conversationsPlaystore/res'
246 }
247 }
248 conversationsPlaystoreSystem {
249 java {
250 srcDir 'src/conversationsPlaystore/java'
251 }
252 res {
253 srcDir 'src/conversationsPlaystore/res'
254 }
255 }
256 }
257
258 buildTypes {
259 release {
260 shrinkResources true
261 minifyEnabled true
262 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
263 versionNameSuffix "r"
264 }
265 debug {
266 shrinkResources true
267 minifyEnabled true
268 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
269 versionNameSuffix "d"
270 }
271 }
272
273
274 if (new File("signing.properties").exists()) {
275 Properties props = new Properties()
276 props.load(new FileInputStream(file("signing.properties")))
277
278 signingConfigs {
279 release {
280 storeFile file(props['keystore'])
281 storePassword props['keystore.password']
282 keyAlias props['keystore.alias']
283 keyPassword props['keystore.password']
284 }
285 }
286 buildTypes.release.signingConfig = signingConfigs.release
287 }
288
289 lintOptions {
290 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
291 abortOnError false
292 }
293
294 subprojects {
295
296 afterEvaluate {
297 if (getPlugins().hasPlugin('android') ||
298 getPlugins().hasPlugin('android-library')) {
299
300 configure(android.lintOptions) {
301 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
302 abortOnError false
303 }
304 }
305
306 }
307 }
308 packagingOptions {
309 resources {
310 excludes += ['META-INF/BCKEY.DSA', 'META-INF/BCKEY.SF']
311 }
312 }
313 lint {
314 disable 'MissingTranslation', 'InvalidPackage', 'AppCompatResource'
315 }
316
317
318 android.applicationVariants.all { variant ->
319 variant.outputs.each { output ->
320 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(com.android.build.OutputFile.ABI))
321 if (baseAbiVersionCode != null) {
322 output.versionCodeOverride = (100 * project.android.defaultConfig.versionCode) + baseAbiVersionCode
323 } else {
324 output.versionCodeOverride = 100 * project.android.defaultConfig.versionCode
325 }
326 }
327
328 }
329}