1import com.android.build.OutputFile
2
3// Top-level build file where you can add configuration options common to all
4// sub-projects/modules.
5buildscript {
6 repositories {
7 google()
8 jcenter()
9 }
10 dependencies {
11 classpath 'com.android.tools.build:gradle:4.1.2'
12 }
13}
14
15apply plugin: 'com.android.application'
16
17repositories {
18 google()
19 jcenter()
20 mavenCentral()
21}
22
23configurations {
24 playstoreImplementation
25 compatImplementation
26 conversationsFreeCompatImplementation
27 conversationsPlaystoreCompatImplementation
28 conversationsPlaystoreSystemImplementation
29 quicksyPlaystoreCompatImplementation
30 quicksyPlaystoreSystemImplementation
31 quicksyFreeCompatImplementation
32 quicksyImplementation
33}
34
35dependencies {
36 implementation 'androidx.viewpager:viewpager:1.0.0'
37
38 playstoreImplementation('com.google.firebase:firebase-messaging:21.0.1') {
39 exclude group: 'com.google.firebase', module: 'firebase-core'
40 exclude group: 'com.google.firebase', module: 'firebase-analytics'
41 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
42 }
43 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
44 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
45 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
46 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
47 implementation 'org.sufficientlysecure:openpgp-api:10.0'
48 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
49 implementation 'androidx.appcompat:appcompat:1.2.0'
50 implementation 'androidx.exifinterface:exifinterface:1.3.2'
51 implementation 'androidx.cardview:cardview:1.0.0'
52 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
53 implementation 'androidx.emoji:emoji:1.1.0'
54 implementation 'com.google.android.material:material:1.3.0'
55 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
56 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
57 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
58 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
59 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
60 //https://github.com/zxing/zxing/issues/1170
61 implementation 'com.google.zxing:core:3.3.3'
62 implementation 'de.measite.minidns:minidns-hla:0.2.4'
63 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
64 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
65 implementation 'com.makeramen:roundedimageview:2.3.0'
66 implementation "com.wefika:flowlayout:0.4.1"
67 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
68 implementation 'org.jxmpp:jxmpp-jid:0.6.4'
69 implementation 'org.osmdroid:osmdroid-android:6.1.5'
70 implementation 'org.hsluv:hsluv:0.2'
71 implementation 'org.conscrypt:conscrypt-android:2.2.1'
72 implementation 'me.drakeet.support:toastcompat:1.1.0'
73 implementation "com.leinardi.android:speed-dial:2.0.1"
74
75 implementation "com.squareup.retrofit2:retrofit:2.9.0"
76 implementation "com.squareup.retrofit2:converter-gson:2.9.0"
77 implementation 'com.google.guava:guava:30.1-android'
78 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.12.18'
79 implementation fileTree(include: ['libwebrtc-m87.aar'], dir: 'libs')
80}
81
82ext {
83 travisBuild = System.getenv("TRAVIS") == "true"
84 preDexEnabled = System.getProperty("pre-dex", "true")
85 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
86}
87
88android {
89 compileSdkVersion 29
90
91 defaultConfig {
92 minSdkVersion 21
93 targetSdkVersion 29
94 versionCode 407
95 versionName "2.9.6"
96 archivesBaseName += "-$versionName"
97 applicationId "eu.siacs.conversations"
98 resValue "string", "applicationId", applicationId
99 resValue "string", "app_name", "Conversations"
100 buildConfigField "String", "LOGTAG", "\"conversations\""
101 }
102
103 splits {
104 abi {
105 universalApk true
106 enable true
107 }
108 }
109
110 dataBinding {
111 enabled true
112 }
113
114 dexOptions {
115 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
116 preDexLibraries = preDexEnabled && !travisBuild
117 jumboMode true
118 }
119
120 compileOptions {
121 sourceCompatibility JavaVersion.VERSION_1_8
122 targetCompatibility JavaVersion.VERSION_1_8
123 }
124
125 flavorDimensions("mode", "distribution", "emoji")
126
127 productFlavors {
128
129 quicksy {
130 dimension "mode"
131 applicationId = "im.quicksy.client"
132 resValue "string", "app_name", "Quicksy"
133 resValue "string", "applicationId", applicationId
134 buildConfigField "String", "LOGTAG", "\"quicksy\""
135 }
136
137 conversations {
138 dimension "mode"
139 }
140
141 playstore {
142 dimension "distribution"
143 versionNameSuffix "+p"
144 }
145 free {
146 dimension "distribution"
147 versionNameSuffix "+f"
148 }
149 system {
150 dimension "emoji"
151 versionNameSuffix "s"
152 }
153 compat {
154 dimension "emoji"
155 versionNameSuffix "c"
156 }
157 }
158
159 sourceSets {
160 quicksyFreeSystem {
161 java {
162 srcDir 'src/quicksyFree/java'
163 }
164 }
165 quicksyFreeCompat {
166 java {
167 srcDir 'src/freeCompat/java'
168 srcDir 'src/quicksyFree/java'
169 }
170 }
171 quicksyPlaystoreCompat {
172 java {
173 srcDir 'src/playstoreCompat/java'
174 srcDir 'src/quicksyPlaystore/java'
175 }
176 res {
177 srcDir 'src/playstoreCompat/res'
178 srcDir 'src/quicksyPlaystore/res'
179 }
180 }
181 quicksyPlaystoreSystem {
182 java {
183 srcDir 'src/quicksyPlaystore/java'
184 }
185 res {
186 srcDir 'src/quicksyPlaystore/res'
187 }
188 }
189 conversationsFreeCompat {
190 java {
191 srcDir 'src/freeCompat/java'
192 srcDir 'src/conversationsFree/java'
193 }
194 }
195 conversationsFreeSystem {
196 java {
197 srcDir 'src/conversationsFree/java'
198 }
199 }
200 conversationsPlaystoreCompat {
201 java {
202 srcDir 'src/playstoreCompat/java'
203 srcDir 'src/conversationsPlaystore/java'
204 }
205 res {
206 srcDir 'src/playstoreCompat/res'
207 srcDir 'src/conversationsPlaystore/res'
208 }
209 }
210 conversationsPlaystoreSystem {
211 java {
212 srcDir 'src/conversationsPlaystore/java'
213 }
214 res {
215 srcDir 'src/conversationsPlaystore/res'
216 }
217 }
218 }
219
220 buildTypes {
221 release {
222 shrinkResources true
223 minifyEnabled true
224 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
225 versionNameSuffix "r"
226 }
227 debug {
228 shrinkResources true
229 minifyEnabled true
230 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
231 versionNameSuffix "d"
232 }
233 }
234
235
236 if (new File("signing.properties").exists()) {
237 Properties props = new Properties()
238 props.load(new FileInputStream(file("signing.properties")))
239
240 signingConfigs {
241 release {
242 storeFile file(props['keystore'])
243 storePassword props['keystore.password']
244 keyAlias props['keystore.alias']
245 keyPassword props['keystore.password']
246 }
247 }
248 buildTypes.release.signingConfig = signingConfigs.release
249 }
250
251 lintOptions {
252 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
253 }
254
255 subprojects {
256
257 afterEvaluate {
258 if (getPlugins().hasPlugin('android') ||
259 getPlugins().hasPlugin('android-library')) {
260
261 configure(android.lintOptions) {
262 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
263 }
264 }
265
266 }
267 }
268
269 packagingOptions {
270 exclude 'META-INF/BCKEY.DSA'
271 exclude 'META-INF/BCKEY.SF'
272 }
273
274 android.applicationVariants.all { variant ->
275 variant.outputs.each { output ->
276 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))
277 if (baseAbiVersionCode != null) {
278 output.versionCodeOverride = (100 * variant.versionCode) + baseAbiVersionCode
279 } else {
280 output.versionCodeOverride = (100 * variant.versionCode)
281 }
282 }
283
284 }
285}