1import com.android.build.OutputFile
2
3// Top-level build file where you can add configuration options common to all
4// sub-projects/modules.
5buildscript {
6 repositories {
7 google()
8 jcenter()
9 }
10 dependencies {
11 classpath 'com.android.tools.build:gradle:4.1.2'
12 }
13}
14
15apply plugin: 'com.android.application'
16
17repositories {
18 google()
19 jcenter()
20 mavenCentral()
21}
22
23configurations {
24 playstoreImplementation
25 compatImplementation
26 conversationsFreeCompatImplementation
27 conversationsPlaystoreCompatImplementation
28 conversationsPlaystoreSystemImplementation
29 quicksyPlaystoreCompatImplementation
30 quicksyPlaystoreSystemImplementation
31 quicksyFreeCompatImplementation
32 quicksyImplementation
33}
34
35dependencies {
36 implementation 'androidx.viewpager:viewpager:1.0.0'
37
38 //should remain that low because later versions introduce dependency to androidx (not sure exactly from what version)
39 playstoreImplementation('com.google.firebase:firebase-messaging:21.0.1') {
40 exclude group: 'com.google.firebase', module: 'firebase-core'
41 exclude group: 'com.google.firebase', module: 'firebase-analytics'
42 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
43 }
44 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
45 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
46 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
47 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
48 implementation 'org.sufficientlysecure:openpgp-api:10.0'
49 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
50 implementation 'androidx.appcompat:appcompat:1.2.0'
51 implementation 'androidx.exifinterface:exifinterface:1.3.2'
52 implementation 'androidx.cardview:cardview:1.0.0'
53 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
54 implementation 'androidx.emoji:emoji:1.1.0'
55 implementation 'com.google.android.material:material:1.2.1'
56 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
57 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
58 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
59 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
60 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
61 //https://github.com/zxing/zxing/issues/1170
62 implementation 'com.google.zxing:core:3.3.3'
63 implementation 'de.measite.minidns:minidns-hla:0.2.4'
64 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
65 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
66 implementation 'com.makeramen:roundedimageview:2.3.0'
67 implementation "com.wefika:flowlayout:0.4.1"
68 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
69 implementation 'org.jxmpp:jxmpp-jid:0.6.4'
70 implementation 'org.osmdroid:osmdroid-android:6.1.5'
71 implementation 'org.hsluv:hsluv:0.2'
72 implementation 'org.conscrypt:conscrypt-android:2.2.1'
73 implementation 'me.drakeet.support:toastcompat:1.1.0'
74 implementation "com.leinardi.android:speed-dial:2.0.1"
75 //retrofit needs to stick with 2.6.x (https://github.com/square/retrofit/blob/master/CHANGELOG.md)
76 implementation "com.squareup.retrofit2:retrofit:2.6.4"
77 implementation "com.squareup.retrofit2:converter-gson:2.6.4"
78 //okhttp needs to stick with 3.12.x
79 implementation 'com.squareup.okhttp3:okhttp:3.12.12'
80 implementation 'com.google.guava:guava:27.1-android'
81 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.12.16'
82 implementation fileTree(include: ['libwebrtc-m87.aar'], dir: 'libs')
83}
84
85ext {
86 travisBuild = System.getenv("TRAVIS") == "true"
87 preDexEnabled = System.getProperty("pre-dex", "true")
88 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
89}
90
91android {
92 compileSdkVersion 29
93
94 defaultConfig {
95 minSdkVersion 21
96 targetSdkVersion 29
97 versionCode 406
98 versionName "2.9.6"
99 archivesBaseName += "-$versionName"
100 applicationId "eu.siacs.conversations"
101 resValue "string", "applicationId", applicationId
102 resValue "string", "app_name", "Conversations"
103 buildConfigField "String", "LOGTAG", "\"conversations\""
104 }
105
106 splits {
107 abi {
108 universalApk true
109 enable true
110 }
111 }
112
113 dataBinding {
114 enabled true
115 }
116
117 dexOptions {
118 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
119 preDexLibraries = preDexEnabled && !travisBuild
120 jumboMode true
121 }
122
123 compileOptions {
124 sourceCompatibility JavaVersion.VERSION_1_8
125 targetCompatibility JavaVersion.VERSION_1_8
126 }
127
128 flavorDimensions("mode", "distribution", "emoji")
129
130 productFlavors {
131
132 quicksy {
133 dimension "mode"
134 applicationId = "im.quicksy.client"
135 resValue "string", "app_name", "Quicksy"
136 resValue "string", "applicationId", applicationId
137 buildConfigField "String", "LOGTAG", "\"quicksy\""
138 }
139
140 conversations {
141 dimension "mode"
142 }
143
144 playstore {
145 dimension "distribution"
146 versionNameSuffix "+p"
147 }
148 free {
149 dimension "distribution"
150 versionNameSuffix "+f"
151 }
152 system {
153 dimension "emoji"
154 versionNameSuffix "s"
155 }
156 compat {
157 dimension "emoji"
158 versionNameSuffix "c"
159 }
160 }
161
162 sourceSets {
163 quicksyFreeSystem {
164 java {
165 srcDir 'src/quicksyFree/java'
166 }
167 }
168 quicksyFreeCompat {
169 java {
170 srcDir 'src/freeCompat/java'
171 srcDir 'src/quicksyFree/java'
172 }
173 }
174 quicksyPlaystoreCompat {
175 java {
176 srcDir 'src/playstoreCompat/java'
177 srcDir 'src/quicksyPlaystore/java'
178 }
179 res {
180 srcDir 'src/playstoreCompat/res'
181 srcDir 'src/quicksyPlaystore/res'
182 }
183 }
184 quicksyPlaystoreSystem {
185 java {
186 srcDir 'src/quicksyPlaystore/java'
187 }
188 res {
189 srcDir 'src/quicksyPlaystore/res'
190 }
191 }
192 conversationsFreeCompat {
193 java {
194 srcDir 'src/freeCompat/java'
195 srcDir 'src/conversationsFree/java'
196 }
197 }
198 conversationsFreeSystem {
199 java {
200 srcDir 'src/conversationsFree/java'
201 }
202 }
203 conversationsPlaystoreCompat {
204 java {
205 srcDir 'src/playstoreCompat/java'
206 srcDir 'src/conversationsPlaystore/java'
207 }
208 res {
209 srcDir 'src/playstoreCompat/res'
210 srcDir 'src/conversationsPlaystore/res'
211 }
212 }
213 conversationsPlaystoreSystem {
214 java {
215 srcDir 'src/conversationsPlaystore/java'
216 }
217 res {
218 srcDir 'src/conversationsPlaystore/res'
219 }
220 }
221 }
222
223 buildTypes {
224 release {
225 shrinkResources true
226 minifyEnabled true
227 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
228 versionNameSuffix "r"
229 }
230 debug {
231 shrinkResources true
232 minifyEnabled true
233 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
234 versionNameSuffix "d"
235 }
236 }
237
238
239 if (new File("signing.properties").exists()) {
240 Properties props = new Properties()
241 props.load(new FileInputStream(file("signing.properties")))
242
243 signingConfigs {
244 release {
245 storeFile file(props['keystore'])
246 storePassword props['keystore.password']
247 keyAlias props['keystore.alias']
248 keyPassword props['keystore.password']
249 }
250 }
251 buildTypes.release.signingConfig = signingConfigs.release
252 }
253
254 lintOptions {
255 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
256 }
257
258 subprojects {
259
260 afterEvaluate {
261 if (getPlugins().hasPlugin('android') ||
262 getPlugins().hasPlugin('android-library')) {
263
264 configure(android.lintOptions) {
265 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
266 }
267 }
268
269 }
270 }
271
272 packagingOptions {
273 exclude 'META-INF/BCKEY.DSA'
274 exclude 'META-INF/BCKEY.SF'
275 }
276
277 android.applicationVariants.all { variant ->
278 variant.outputs.each { output ->
279 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))
280 if (baseAbiVersionCode != null) {
281 output.versionCodeOverride = (100 * variant.versionCode) + baseAbiVersionCode
282 } else {
283 output.versionCodeOverride = (100 * variant.versionCode)
284 }
285 }
286
287 }
288}