1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 mavenCentral()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:8.9.3'
10 classpath "com.diffplug.spotless:spotless-plugin-gradle:7.0.2"
11 }
12}
13
14plugins {
15 id 'org.ajoberstar.grgit' version '4.1.1'
16 // PLUGIN INSERT
17}
18
19apply plugin: 'com.android.application'
20apply plugin: "com.diffplug.spotless"
21
22repositories {
23 google()
24 mavenCentral()
25 maven { url='https://jitpack.io'}
26}
27
28def tags = grgit.tag.list().findAll { it.dateTime != null }.sort { it.dateTime }
29
30// ROOT INSERT
31
32configurations {
33 playstoreImplementation
34 freeImplementation
35 conversationsFreeImplementation
36 cheogramPlaystoreImplementation
37 conversationsPlaystoreImplementation
38 quicksyPlaystoreImplementation
39 quicksyPlaystoreImplementation
40 quicksyFreeImplementation
41 quicksyImplementation
42}
43
44spotless {
45 ratchetFrom '2.17.4'
46 java {
47 target '**/*.java'
48 googleJavaFormat().aosp().reflowLongStrings()
49 }
50}
51
52
53dependencies {
54 androidTestImplementation 'tools.fastlane:screengrab:2.1.1'
55 androidTestImplementation 'junit:junit:4.13.2'
56 androidTestImplementation 'androidx.test:runner:1.3.0'
57 androidTestImplementation 'androidx.test:rules:1.3.0'
58 androidTestImplementation 'androidx.test.ext:junit:1.1.2'
59 androidTestImplementation 'androidx.test.espresso:espresso-core:3.3.0'
60 androidTestImplementation 'org.mockito:mockito-android:5.14.2'
61
62 implementation "androidx.core:core:1.10.1"
63 coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:2.1.5'
64
65 annotationProcessor project(':libs:annotation-processor')
66 implementation project(':libs:annotation')
67 implementation 'androidx.appcompat:appcompat:1.7.0'
68 implementation 'androidx.cardview:cardview:1.0.0'
69 implementation 'androidx.emoji2:emoji2:1.5.0'
70 freeImplementation 'androidx.emoji2:emoji2-bundled:1.5.0'
71 implementation 'androidx.emoji2:emoji2-emojipicker:1.5.0'
72 implementation 'androidx.exifinterface:exifinterface:1.4.1'
73 implementation 'androidx.heifwriter:heifwriter:1.1.0-beta01'
74 implementation 'androidx.preference:preference:1.2.1'
75 implementation 'androidx.sharetarget:sharetarget:1.2.0'
76 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
77 implementation 'androidx.viewpager:viewpager:1.1.0'
78 implementation 'androidx.work:work-runtime:2.10.1'
79 implementation 'com.github.open-keychain.open-keychain:openpgp-api:v5.7.1'
80 implementation 'com.google.android.material:material:1.13.0-alpha10'
81 implementation 'com.google.guava:guava:33.4.6-android'
82 implementation 'com.google.zxing:core:3.5.3'
83 implementation 'com.leinardi.android:speed-dial:3.3.0'
84 implementation 'com.makeramen:roundedimageview:2.3.0'
85 implementation 'com.squareup.okhttp3:okhttp:4.12.0'
86 implementation 'com.squareup.retrofit2:converter-gson:2.11.0'
87 implementation 'com.squareup.retrofit2:retrofit:2.11.0'
88 implementation 'com.vanniktech:android-image-cropper:4.6.0'
89 implementation 'im.conversations.webrtc:webrtc-android:129.0.0'
90 implementation 'io.deepmedia.community:transcoder-android:0.11.2'
91 implementation 'me.drakeet.support:toastcompat:1.1.0'
92 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
93 implementation 'org.bouncycastle:bcmail-jdk18on:1.80'
94 implementation 'org.conscrypt:conscrypt-android:2.5.3'
95 implementation 'org.hsluv:hsluv:0.2'
96 implementation 'org.jxmpp:jxmpp-jid:1.0.3'
97 implementation 'org.jxmpp:jxmpp-stringprep-libidn:1.0.3'
98 implementation 'org.minidns:minidns-client:1.0.4'
99 implementation 'org.minidns:minidns-dnssec:1.0.4'
100 implementation 'org.osmdroid:osmdroid-android:6.1.20'
101 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
102 conversationsPlaystoreImplementation 'com.android.installreferrer:installreferrer:2.2'
103 playstoreImplementation('com.google.firebase:firebase-messaging:24.1.1') {
104 exclude group: 'com.google.firebase', module: 'firebase-core'
105 exclude group: 'com.google.firebase', module: 'firebase-analytics'
106 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
107
108 }
109 cheogramPlaystoreImplementation("com.android.installreferrer:installreferrer:2.2")
110 cheogramPlaystoreImplementation 'com.github.singpolyma:play-licensing:1c637ea03c'
111
112 implementation 'org.bouncycastle:bcpg-jdk18on:1.80'
113 implementation 'org.minidns:minidns-hla:1.1.1'
114 implementation "com.wefika:flowlayout:0.4.1"
115
116 implementation 'io.michaelrocks:libphonenumber-android:8.13.52'
117 implementation 'com.github.martin-stone:hsv-alpha-color-picker-android:3.1.0'
118 implementation 'com.github.ipld:java-cid:v1.3.1'
119 //implementation 'com.splitwise:tokenautocomplete:3.0.2'
120 implementation 'com.github.singpolyma:TokenAutoComplete:bfa93780e0'
121 implementation 'com.github.singpolyma:Better-Link-Movement-Method:393d35e453'
122 implementation 'com.github.singpolyma:android-identicons:3361281bd4'
123 implementation 'com.github.woltapp:blurhash:master'
124 implementation 'com.caverock:androidsvg-aar:1.4'
125 implementation 'org.tomlj:tomlj:1.1.0'
126 implementation 'com.tbuonomo:dotsindicator:4.2'
127 implementation 'com.github.singpolyma:OpenGraphParser:d0882eadb2'
128 implementation 'me.xdrop:fuzzywuzzy:1.4.0'
129 implementation 'net.fellbaum:jemoji:1.4.1'
130 implementation 'com.github.natario1:Autocomplete:v1.1.0'
131 implementation 'com.mikepenz:materialdrawer:10.0.0-b01'
132 implementation 'androidx.browser:browser:1.8.0'
133 implementation 'io.github.nishkarsh:android-permissions:2.1.6'
134
135 testImplementation 'junit:junit:4.13.2'
136 testImplementation 'org.robolectric:robolectric:4.14.1'
137 androidTestImplementation 'androidx.test.ext:junit:1.2.1'
138
139}
140
141ext {
142 preDexEnabled = System.getProperty("pre-dex", "true")
143 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
144}
145
146android {
147 namespace 'eu.siacs.conversations'
148 compileSdk 35
149
150 defaultConfig {
151 minSdkVersion 23
152 targetSdkVersion 35
153 versionCode 42025 + tags.size()
154 versionName grgit.describe(always: true)
155 applicationId "eu.siacs.conversations"
156 def appName = "Conversations"
157 resValue "string", "app_name", appName
158 buildConfigField "String", "APP_NAME", "\"$appName\"";
159 testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
160 }
161
162 splits {
163 abi {
164 def isBuildingBundle = gradle.startParameter.taskNames.any { it.toLowerCase().contains("bundle") }
165 universalApk true
166 enable !isBuildingBundle
167 reset()
168 //noinspection ChromeOsAbiSupport
169 include project.ext.abiCodes.keySet() as String[]
170 }
171 }
172
173 configurations {
174 implementation.exclude group: 'org.jetbrains' , module:'annotations'
175 }
176
177 dataBinding {
178 enabled true
179 }
180
181 compileOptions {
182 coreLibraryDesugaringEnabled true
183 sourceCompatibility JavaVersion.VERSION_17
184 targetCompatibility JavaVersion.VERSION_17
185 }
186
187 flavorDimensions += "mode"
188 flavorDimensions += "distribution"
189
190 productFlavors {
191
192 quicksy {
193 dimension "mode"
194 applicationId = "im.quicksy.client"
195
196 def appName = "Quicksy"
197 resValue "string", "app_name", appName
198 buildConfigField "String", "APP_NAME", "\"$appName\""
199 buildConfigField "String", "PRIVACY_POLICY", "\"https://quicksy.im/privacy.htm\""
200 }
201
202 conversations {
203 dimension "mode"
204 buildConfigField "String", "PRIVACY_POLICY", "\"https://conversations.im/privacy.html\""
205 }
206
207 cheogram {
208 dimension "mode"
209
210 applicationId = "com.cheogram.android"
211
212 def appName = "Cheogram"
213 resValue "string", "app_name", appName
214 buildConfigField "String", "APP_NAME", "\"$appName\"";
215 buildConfigField "String", "PRIVACY_POLICY", "\"https://cheogram.com/android-privacy.html\""
216 }
217
218 playstore {
219 dimension "distribution"
220 versionNameSuffix "+playstore"
221 applicationIdSuffix "playstore"
222 }
223 free {
224 dimension "distribution"
225 versionNameSuffix "+free"
226 }
227 }
228
229 applicationVariants.all { variant ->
230 variant.resValue "string", "applicationId", applicationId
231 }
232
233 sourceSets {
234 quicksyFree {
235 java {
236 srcDir 'src/quicksyFree/java'
237 }
238 }
239 quicksyPlaystore {
240 java {
241 srcDir 'src/quicksyPlaystore/java'
242 }
243 res {
244 srcDir 'src/quicksyPlaystore/res'
245 }
246 }
247 conversationsFree {
248 java {
249 srcDir 'src/conversationsFree/java'
250 }
251 }
252 cheogramFree {
253 java {
254 srcDir 'src/conversationsFree/java'
255 }
256 }
257 conversationsPlaystore {
258 java {
259 srcDir 'src/conversationsPlaystore/java'
260 }
261 res {
262 srcDir 'src/conversationsPlaystore/res'
263 }
264 }
265 }
266
267 buildTypes {
268 release {
269 shrinkResources true
270 minifyEnabled true
271 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
272 ndk.debugSymbolLevel = 'full'
273 }
274 }
275
276
277 if (new File("signing.properties").exists()) {
278 Properties props = new Properties()
279 props.load(new FileInputStream(file("signing.properties")))
280
281 signingConfigs {
282 release {
283 storeFile file(props['keystore'])
284 storePassword props['keystore.password']
285 keyAlias props['keystore.alias']
286 keyPassword props['keystore.password']
287 }
288 }
289 buildTypes.release.signingConfig = signingConfigs.release
290 }
291
292 lintOptions {
293 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
294 abortOnError false
295 }
296
297 testOptions {
298 unitTests {
299 includeAndroidResources = true
300 }
301 }
302
303 subprojects {
304
305 afterEvaluate {
306 if (getPlugins().hasPlugin('android') ||
307 getPlugins().hasPlugin('android-library')) {
308
309 configure(android.lintOptions) {
310 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
311 abortOnError false
312 }
313 }
314
315 }
316 }
317 packagingOptions {
318 resources {
319 excludes += ['META-INF/BCKEY.DSA', 'META-INF/BCKEY.SF', 'META-INF/versions/9/OSGI-INF/MANIFEST.MF']
320 }
321 }
322 lint {
323 disable 'MissingTranslation', 'InvalidPackage', 'AppCompatResource'
324 }
325 buildFeatures {
326 buildConfig true
327 }
328
329 android.applicationVariants.configureEach { variant ->
330 variant.outputs.each { output ->
331 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(com.android.build.OutputFile.ABI))
332 if (baseAbiVersionCode != null) {
333 output.versionCodeOverride = (100 * project.android.defaultConfig.versionCode) + baseAbiVersionCode
334 } else {
335 output.versionCodeOverride = (100 * project.android.defaultConfig.versionCode) + grgit.log(includes: ["HEAD"], excludes: [tags.last()]).size()
336 }
337 }
338
339 }
340}