1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 jcenter()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:3.3.0'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 jcenter()
18 mavenCentral()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 quicksyFreeCompatImplementation
26 quicksyImplementation
27}
28
29ext {
30 supportLibVersion = '28.0.0'
31}
32
33dependencies {
34 playstoreImplementation('com.google.firebase:firebase-messaging:17.3.4') {
35 exclude group: 'com.google.firebase', module: 'firebase-core'
36 exclude group: 'com.google.firebase', module: 'firebase-analytics'
37 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
38 }
39 implementation 'org.sufficientlysecure:openpgp-api:10.0'
40 implementation ('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
41 exclude group: 'com.android.support', module: 'appcompat-v7'
42 exclude group: 'com.android.support', module: 'exifinterface'
43 }
44 implementation "com.android.support:support-v13:$supportLibVersion"
45 implementation "com.android.support:appcompat-v7:$supportLibVersion"
46 implementation "com.android.support:exifinterface:$supportLibVersion"
47 implementation "com.android.support:cardview-v7:$supportLibVersion"
48 implementation "com.android.support:support-emoji:$supportLibVersion"
49 implementation "com.android.support:design:$supportLibVersion"
50 compatImplementation "com.android.support:support-emoji-appcompat:$supportLibVersion"
51 conversationsFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
52 quicksyFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
53 implementation 'org.bouncycastle:bcmail-jdk15on:1.58'
54 implementation 'com.google.zxing:core:3.3.3'
55 implementation 'de.measite.minidns:minidns-hla:0.2.4'
56 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
57 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
58 implementation 'com.makeramen:roundedimageview:2.3.0'
59 implementation "com.wefika:flowlayout:0.4.1"
60 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
61 implementation project(':libs:xmpp-addr')
62 implementation 'org.osmdroid:osmdroid-android:6.0.3'
63 implementation 'org.hsluv:hsluv:0.2'
64 implementation 'org.conscrypt:conscrypt-android:1.3.0'
65 implementation 'me.drakeet.support:toastcompat:1.1.0'
66 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.10.1'
67}
68
69ext {
70 travisBuild = System.getenv("TRAVIS") == "true"
71 preDexEnabled = System.getProperty("pre-dex", "true")
72}
73
74android {
75 compileSdkVersion 28
76
77 defaultConfig {
78 minSdkVersion 16
79 targetSdkVersion 28
80 versionCode 317
81 versionName "2.3.12"
82 archivesBaseName += "-$versionName"
83 applicationId "eu.siacs.conversations"
84 resValue "string", "applicationId", applicationId
85 resValue "string", "app_name", "Conversations"
86 buildConfigField "String", "LOGTAG", "\"conversations\""
87 }
88
89 dataBinding {
90 enabled true
91 }
92
93 dexOptions {
94 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
95 preDexLibraries = preDexEnabled && !travisBuild
96 jumboMode true
97 }
98
99 compileOptions {
100 sourceCompatibility JavaVersion.VERSION_1_8
101 targetCompatibility JavaVersion.VERSION_1_8
102 }
103
104 flavorDimensions("mode", "distribution", "emoji")
105
106 productFlavors {
107
108 quicksy {
109 dimension "mode"
110 applicationId = "im.quicksy.client"
111 resValue "string", "app_name", "Quicksy"
112 resValue "string", "applicationId", applicationId
113 buildConfigField "String", "LOGTAG", "\"quicksy\""
114 }
115
116 conversations {
117 dimension "mode"
118 }
119
120 playstore {
121 dimension "distribution"
122 versionNameSuffix "+p"
123 }
124 free {
125 dimension "distribution"
126 versionNameSuffix "+f"
127 }
128 system {
129 dimension "emoji"
130 versionNameSuffix "s"
131 }
132 compat {
133 dimension "emoji"
134 versionNameSuffix "c"
135 }
136 }
137
138 sourceSets {
139 quicksyFreeCompat {
140 java {
141 srcDirs 'src/freeCompat/java'
142 }
143 }
144 quicksyPlaystoreCompat {
145 java {
146 srcDirs 'src/playstoreCompat/java'
147 }
148 res {
149 srcDir 'src/playstoreCompat/res'
150 srcDir 'src/quicksyPlaystore/res'
151 }
152 }
153 quicksyPlaystoreSystem {
154 res {
155 srcDir 'src/quicksyPlaystore/res'
156 }
157 }
158 conversationsFreeCompat {
159 java {
160 srcDirs 'src/freeCompat/java'
161 }
162 }
163 conversationsPlaystoreCompat {
164 java {
165 srcDirs 'src/playstoreCompat/java'
166 }
167 res {
168 srcDir 'src/playstoreCompat/res'
169 srcDir 'src/conversationsPlaystore/res'
170 }
171 }
172 conversationsPlaystoreSystem {
173 res {
174 srcDir 'src/conversationsPlaystore/res'
175 }
176 }
177 }
178
179 buildTypes {
180 release {
181 shrinkResources true
182 minifyEnabled true
183 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
184 versionNameSuffix "r"
185 }
186 debug {
187 shrinkResources true
188 minifyEnabled true
189 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
190 versionNameSuffix "d"
191 }
192 }
193
194
195
196 if (new File("signing.properties").exists()) {
197 Properties props = new Properties()
198 props.load(new FileInputStream(file("signing.properties")))
199
200 signingConfigs {
201 release {
202 storeFile file(props['keystore'])
203 storePassword props['keystore.password']
204 keyAlias props['keystore.alias']
205 keyPassword props['keystore.password']
206 }
207 }
208 buildTypes.release.signingConfig = signingConfigs.release
209 }
210
211 lintOptions {
212 disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
213 }
214
215 subprojects {
216
217 afterEvaluate {
218 if (getPlugins().hasPlugin('android') ||
219 getPlugins().hasPlugin('android-library')) {
220
221 configure(android.lintOptions) {
222 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
223 }
224 }
225
226 }
227 }
228
229 packagingOptions {
230 exclude 'META-INF/BCKEY.DSA'
231 exclude 'META-INF/BCKEY.SF'
232 }
233}