1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 jcenter()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:3.5.0'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 jcenter()
18 mavenCentral()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 quicksyFreeCompatImplementation
26 quicksyImplementation
27}
28
29ext {
30 supportLibVersion = '28.0.0'
31}
32
33dependencies {
34 playstoreImplementation('com.google.firebase:firebase-messaging:17.3.4') {
35 exclude group: 'com.google.firebase', module: 'firebase-core'
36 exclude group: 'com.google.firebase', module: 'firebase-analytics'
37 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
38 }
39 implementation 'org.sufficientlysecure:openpgp-api:10.0'
40 implementation ('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
41 exclude group: 'com.android.support', module: 'appcompat-v7'
42 exclude group: 'com.android.support', module: 'exifinterface'
43 }
44 implementation "com.android.support:support-v13:$supportLibVersion"
45 implementation "com.android.support:appcompat-v7:$supportLibVersion"
46 implementation "com.android.support:exifinterface:$supportLibVersion"
47 implementation "com.android.support:cardview-v7:$supportLibVersion"
48 implementation "com.android.support:support-emoji:$supportLibVersion"
49 implementation "com.android.support:design:$supportLibVersion"
50 compatImplementation "com.android.support:support-emoji-appcompat:$supportLibVersion"
51 conversationsFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
52 quicksyFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
53 implementation 'org.bouncycastle:bcmail-jdk15on:1.58'
54 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
55 //https://github.com/zxing/zxing/issues/1170
56 implementation 'com.google.zxing:core:3.3.3'
57 implementation 'de.measite.minidns:minidns-hla:0.2.4'
58 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
59 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
60 implementation 'com.makeramen:roundedimageview:2.3.0'
61 implementation "com.wefika:flowlayout:0.4.1"
62 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
63 implementation project(':libs:xmpp-addr')
64 implementation 'org.osmdroid:osmdroid-android:6.1.0'
65 implementation 'org.hsluv:hsluv:0.2'
66 implementation 'org.conscrypt:conscrypt-android:2.1.0'
67 implementation 'me.drakeet.support:toastcompat:1.1.0'
68 implementation "com.leinardi.android:speed-dial:2.0.1"
69 implementation 'com.squareup.retrofit2:retrofit:2.6.0'
70 implementation 'com.squareup.retrofit2:converter-gson:2.6.0'
71 implementation 'com.google.guava:guava:27.1-android'
72 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.10.1'
73}
74
75ext {
76 travisBuild = System.getenv("TRAVIS") == "true"
77 preDexEnabled = System.getProperty("pre-dex", "true")
78}
79
80android {
81 compileSdkVersion 28
82
83 defaultConfig {
84 minSdkVersion 16
85 targetSdkVersion 28
86 versionCode 338
87 versionName "2.5.8"
88 archivesBaseName += "-$versionName"
89 applicationId "eu.siacs.conversations"
90 resValue "string", "applicationId", applicationId
91 resValue "string", "app_name", "Conversations"
92 buildConfigField "String", "LOGTAG", "\"conversations\""
93 }
94
95 dataBinding {
96 enabled true
97 }
98
99 dexOptions {
100 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
101 preDexLibraries = preDexEnabled && !travisBuild
102 jumboMode true
103 }
104
105 compileOptions {
106 sourceCompatibility JavaVersion.VERSION_1_8
107 targetCompatibility JavaVersion.VERSION_1_8
108 }
109
110 flavorDimensions("mode", "distribution", "emoji")
111
112 productFlavors {
113
114 quicksy {
115 dimension "mode"
116 applicationId = "im.quicksy.client"
117 resValue "string", "app_name", "Quicksy"
118 resValue "string", "applicationId", applicationId
119 buildConfigField "String", "LOGTAG", "\"quicksy\""
120 }
121
122 conversations {
123 dimension "mode"
124 }
125
126 playstore {
127 dimension "distribution"
128 versionNameSuffix "+p"
129 }
130 free {
131 dimension "distribution"
132 versionNameSuffix "+f"
133 }
134 system {
135 dimension "emoji"
136 versionNameSuffix "s"
137 }
138 compat {
139 dimension "emoji"
140 versionNameSuffix "c"
141 }
142 }
143
144 sourceSets {
145 quicksyFreeCompat {
146 java {
147 srcDirs 'src/freeCompat/java'
148 }
149 }
150 quicksyPlaystoreCompat {
151 java {
152 srcDirs 'src/playstoreCompat/java'
153 }
154 res {
155 srcDir 'src/playstoreCompat/res'
156 srcDir 'src/quicksyPlaystore/res'
157 }
158 }
159 quicksyPlaystoreSystem {
160 res {
161 srcDir 'src/quicksyPlaystore/res'
162 }
163 }
164 conversationsFreeCompat {
165 java {
166 srcDirs 'src/freeCompat/java'
167 }
168 }
169 conversationsPlaystoreCompat {
170 java {
171 srcDirs 'src/playstoreCompat/java'
172 }
173 res {
174 srcDir 'src/playstoreCompat/res'
175 srcDir 'src/conversationsPlaystore/res'
176 }
177 }
178 conversationsPlaystoreSystem {
179 res {
180 srcDir 'src/conversationsPlaystore/res'
181 }
182 }
183 }
184
185 buildTypes {
186 release {
187 shrinkResources true
188 minifyEnabled true
189 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
190 versionNameSuffix "r"
191 }
192 debug {
193 shrinkResources true
194 minifyEnabled true
195 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
196 versionNameSuffix "d"
197 }
198 }
199
200
201
202 if (new File("signing.properties").exists()) {
203 Properties props = new Properties()
204 props.load(new FileInputStream(file("signing.properties")))
205
206 signingConfigs {
207 release {
208 storeFile file(props['keystore'])
209 storePassword props['keystore.password']
210 keyAlias props['keystore.alias']
211 keyPassword props['keystore.password']
212 }
213 }
214 buildTypes.release.signingConfig = signingConfigs.release
215 }
216
217 lintOptions {
218 disable 'ExtraTranslation', 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
219 }
220
221 subprojects {
222
223 afterEvaluate {
224 if (getPlugins().hasPlugin('android') ||
225 getPlugins().hasPlugin('android-library')) {
226
227 configure(android.lintOptions) {
228 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
229 }
230 }
231
232 }
233 }
234
235 packagingOptions {
236 exclude 'META-INF/BCKEY.DSA'
237 exclude 'META-INF/BCKEY.SF'
238 }
239}