1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 mavenCentral()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:7.1.1'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 mavenCentral()
18 jcenter()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 conversationsPlaystoreCompatImplementation
26 conversationsPlaystoreSystemImplementation
27 quicksyPlaystoreCompatImplementation
28 quicksyPlaystoreSystemImplementation
29 quicksyFreeCompatImplementation
30 quicksyImplementation
31}
32
33dependencies {
34 implementation 'androidx.viewpager:viewpager:1.0.0'
35
36 playstoreImplementation('com.google.firebase:firebase-messaging:23.0.0') {
37 exclude group: 'com.google.firebase', module: 'firebase-core'
38 exclude group: 'com.google.firebase', module: 'firebase-analytics'
39 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
40 }
41 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
42 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
43 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:18.0.1'
44 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:18.0.1'
45 implementation 'org.sufficientlysecure:openpgp-api:10.0'
46 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
47 implementation 'androidx.appcompat:appcompat:1.3.1'
48 implementation 'androidx.exifinterface:exifinterface:1.3.3'
49 implementation 'androidx.cardview:cardview:1.0.0'
50 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
51 implementation 'androidx.emoji:emoji:1.1.0'
52 implementation 'com.google.android.material:material:1.4.0'
53 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
54 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
55 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
56 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
57 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
58 //https://github.com/zxing/zxing/issues/1170
59 implementation 'com.google.zxing:core:3.3.3'
60 implementation 'de.measite.minidns:minidns-hla:0.2.4'
61 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
62 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
63 implementation 'com.makeramen:roundedimageview:2.3.0'
64 implementation "com.wefika:flowlayout:0.4.1"
65 implementation 'com.otaliastudios:transcoder:0.10.4'
66
67 implementation 'org.jxmpp:jxmpp-jid:1.0.2'
68 implementation 'org.osmdroid:osmdroid-android:6.1.10'
69 implementation 'org.hsluv:hsluv:0.2'
70 implementation 'org.conscrypt:conscrypt-android:2.5.2'
71 implementation 'me.drakeet.support:toastcompat:1.1.0'
72 implementation "com.leinardi.android:speed-dial:3.2.0"
73
74 implementation "com.squareup.retrofit2:retrofit:2.9.0"
75 implementation "com.squareup.retrofit2:converter-gson:2.9.0"
76 implementation "com.squareup.okhttp3:okhttp:4.9.3"
77
78 implementation 'com.google.guava:guava:30.1.1-android'
79 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.12.36'
80 implementation fileTree(include: ['libwebrtc-m92.aar'], dir: 'libs')
81}
82
83ext {
84 travisBuild = System.getenv("TRAVIS") == "true"
85 preDexEnabled = System.getProperty("pre-dex", "true")
86 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
87}
88
89android {
90 compileSdkVersion 30
91
92 defaultConfig {
93 minSdkVersion 21
94 targetSdkVersion 30
95 versionCode 42024
96 versionName "2.10.3-beta"
97 archivesBaseName += "-$versionName"
98 applicationId "eu.siacs.conversations"
99 resValue "string", "applicationId", applicationId
100 def appName = "Conversations"
101 resValue "string", "app_name", appName
102 buildConfigField "String", "APP_NAME", "\"$appName\"";
103 }
104
105 splits {
106 abi {
107 universalApk true
108 enable true
109 }
110 }
111
112 configurations {
113 implementation.exclude group: 'org.jetbrains' , module:'annotations'
114 }
115
116 dataBinding {
117 enabled true
118 }
119
120 compileOptions {
121 sourceCompatibility JavaVersion.VERSION_1_8
122 targetCompatibility JavaVersion.VERSION_1_8
123 }
124
125 flavorDimensions("mode", "distribution", "emoji")
126
127 productFlavors {
128
129 quicksy {
130 dimension "mode"
131 applicationId = "im.quicksy.client"
132 resValue "string", "applicationId", applicationId
133
134 def appName = "Quicksy"
135 resValue "string", "app_name", appName
136 buildConfigField "String", "APP_NAME", "\"$appName\"";
137 }
138
139 conversations {
140 dimension "mode"
141 }
142
143 playstore {
144 dimension "distribution"
145 versionNameSuffix "+p"
146 }
147 free {
148 dimension "distribution"
149 versionNameSuffix "+f"
150 }
151 system {
152 dimension "emoji"
153 versionNameSuffix "s"
154 }
155 compat {
156 dimension "emoji"
157 versionNameSuffix "c"
158 }
159 }
160
161 sourceSets {
162 quicksyFreeSystem {
163 java {
164 srcDir 'src/quicksyFree/java'
165 }
166 }
167 quicksyFreeCompat {
168 java {
169 srcDir 'src/freeCompat/java'
170 srcDir 'src/quicksyFree/java'
171 }
172 }
173 quicksyPlaystoreCompat {
174 java {
175 srcDir 'src/playstoreCompat/java'
176 srcDir 'src/quicksyPlaystore/java'
177 }
178 res {
179 srcDir 'src/playstoreCompat/res'
180 srcDir 'src/quicksyPlaystore/res'
181 }
182 }
183 quicksyPlaystoreSystem {
184 java {
185 srcDir 'src/quicksyPlaystore/java'
186 }
187 res {
188 srcDir 'src/quicksyPlaystore/res'
189 }
190 }
191 conversationsFreeCompat {
192 java {
193 srcDir 'src/freeCompat/java'
194 srcDir 'src/conversationsFree/java'
195 }
196 }
197 conversationsFreeSystem {
198 java {
199 srcDir 'src/conversationsFree/java'
200 }
201 }
202 conversationsPlaystoreCompat {
203 java {
204 srcDir 'src/playstoreCompat/java'
205 srcDir 'src/conversationsPlaystore/java'
206 }
207 res {
208 srcDir 'src/playstoreCompat/res'
209 srcDir 'src/conversationsPlaystore/res'
210 }
211 }
212 conversationsPlaystoreSystem {
213 java {
214 srcDir 'src/conversationsPlaystore/java'
215 }
216 res {
217 srcDir 'src/conversationsPlaystore/res'
218 }
219 }
220 }
221
222 buildTypes {
223 release {
224 shrinkResources true
225 minifyEnabled true
226 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
227 versionNameSuffix "r"
228 }
229 debug {
230 shrinkResources true
231 minifyEnabled true
232 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
233 versionNameSuffix "d"
234 }
235 }
236
237
238 if (new File("signing.properties").exists()) {
239 Properties props = new Properties()
240 props.load(new FileInputStream(file("signing.properties")))
241
242 signingConfigs {
243 release {
244 storeFile file(props['keystore'])
245 storePassword props['keystore.password']
246 keyAlias props['keystore.alias']
247 keyPassword props['keystore.password']
248 }
249 }
250 buildTypes.release.signingConfig = signingConfigs.release
251 }
252
253
254 subprojects {
255
256 afterEvaluate {
257 if (getPlugins().hasPlugin('android') ||
258 getPlugins().hasPlugin('android-library')) {
259
260 configure(android.lintOptions) {
261 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
262 }
263 }
264
265 }
266 }
267 packagingOptions {
268 resources {
269 excludes += ['META-INF/BCKEY.DSA', 'META-INF/BCKEY.SF']
270 }
271 }
272 lint {
273 disable 'MissingTranslation', 'InvalidPackage', 'AppCompatResource'
274 }
275
276
277 android.applicationVariants.all { variant ->
278 variant.outputs.each { output ->
279 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(com.android.build.OutputFile.ABI))
280 if (baseAbiVersionCode != null) {
281 output.versionCodeOverride = (100 * project.android.defaultConfig.versionCode) + baseAbiVersionCode
282 } else {
283 output.versionCodeOverride = 100 * project.android.defaultConfig.versionCode
284 }
285 }
286
287 }
288}