1import com.android.build.OutputFile
2
3// Top-level build file where you can add configuration options common to all
4// sub-projects/modules.
5buildscript {
6 repositories {
7 google()
8 mavenCentral()
9 }
10 dependencies {
11 classpath 'com.android.tools.build:gradle:4.2.1'
12 }
13}
14
15apply plugin: 'com.android.application'
16
17repositories {
18 google()
19 mavenCentral()
20 jcenter()
21}
22
23configurations {
24 playstoreImplementation
25 compatImplementation
26 conversationsFreeCompatImplementation
27 conversationsPlaystoreCompatImplementation
28 conversationsPlaystoreSystemImplementation
29 quicksyPlaystoreCompatImplementation
30 quicksyPlaystoreSystemImplementation
31 quicksyFreeCompatImplementation
32 quicksyImplementation
33}
34
35dependencies {
36 implementation 'androidx.viewpager:viewpager:1.0.0'
37
38 playstoreImplementation('com.google.firebase:firebase-messaging:22.0.0') {
39 exclude group: 'com.google.firebase', module: 'firebase-core'
40 exclude group: 'com.google.firebase', module: 'firebase-analytics'
41 exclude group: 'com.google.firebase', module: 'firebase-measurement-connector'
42 }
43 conversationsPlaystoreCompatImplementation("com.android.installreferrer:installreferrer:2.2")
44 conversationsPlaystoreSystemImplementation("com.android.installreferrer:installreferrer:2.2")
45 quicksyPlaystoreCompatImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
46 quicksyPlaystoreSystemImplementation 'com.google.android.gms:play-services-auth-api-phone:17.5.0'
47 implementation 'org.sufficientlysecure:openpgp-api:10.0'
48 implementation 'com.theartofdev.edmodo:android-image-cropper:2.8.0'
49 implementation 'androidx.appcompat:appcompat:1.2.0'
50 implementation 'androidx.exifinterface:exifinterface:1.3.2'
51 implementation 'androidx.cardview:cardview:1.0.0'
52 implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
53 implementation 'androidx.emoji:emoji:1.1.0'
54 implementation 'com.google.android.material:material:1.3.0'
55 compatImplementation 'androidx.emoji:emoji-appcompat:1.1.0'
56 conversationsFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
57 quicksyFreeCompatImplementation 'androidx.emoji:emoji-bundled:1.1.0'
58 implementation 'org.bouncycastle:bcmail-jdk15on:1.64'
59 //zxing stopped supporting Java 7 so we have to stick with 3.3.3
60 //https://github.com/zxing/zxing/issues/1170
61 implementation 'com.google.zxing:core:3.3.3'
62 implementation 'de.measite.minidns:minidns-hla:0.2.4'
63 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
64 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
65 implementation 'com.makeramen:roundedimageview:2.3.0'
66 implementation "com.wefika:flowlayout:0.4.1"
67 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.3.0'
68 implementation 'org.jxmpp:jxmpp-jid:1.0.1'
69 implementation 'org.osmdroid:osmdroid-android:6.1.10'
70 implementation 'org.hsluv:hsluv:0.2'
71 implementation 'org.conscrypt:conscrypt-android:2.5.2'
72 implementation 'me.drakeet.support:toastcompat:1.1.0'
73 implementation "com.leinardi.android:speed-dial:2.0.1"
74
75 implementation "com.squareup.retrofit2:retrofit:2.9.0"
76 implementation "com.squareup.retrofit2:converter-gson:2.9.0"
77 implementation "com.squareup.okhttp3:okhttp:4.9.1"
78
79 implementation 'com.google.guava:guava:30.1.1-android'
80 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.12.18'
81 implementation fileTree(include: ['libwebrtc-m90.aar'], dir: 'libs')
82}
83
84ext {
85 travisBuild = System.getenv("TRAVIS") == "true"
86 preDexEnabled = System.getProperty("pre-dex", "true")
87 abiCodes = ['armeabi-v7a': 1, 'x86': 2, 'x86_64': 3, 'arm64-v8a': 4]
88}
89
90android {
91 compileSdkVersion 29
92
93 defaultConfig {
94 minSdkVersion 21
95 targetSdkVersion 29
96 versionCode 42015
97 versionName "2.9.13"
98 archivesBaseName += "-$versionName"
99 applicationId "eu.siacs.conversations"
100 resValue "string", "applicationId", applicationId
101 def appName = "Conversations"
102 resValue "string", "app_name", appName
103 buildConfigField "String", "APP_NAME", "\"$appName\"";
104 }
105
106 splits {
107 abi {
108 universalApk true
109 enable true
110 }
111 }
112
113 configurations {
114 compile.exclude group: 'org.jetbrains' , module:'annotations'
115 }
116
117 dataBinding {
118 enabled true
119 }
120
121 dexOptions {
122 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
123 preDexLibraries = preDexEnabled && !travisBuild
124 jumboMode true
125 }
126
127 compileOptions {
128 sourceCompatibility JavaVersion.VERSION_1_8
129 targetCompatibility JavaVersion.VERSION_1_8
130 }
131
132 flavorDimensions("mode", "distribution", "emoji")
133
134 productFlavors {
135
136 quicksy {
137 dimension "mode"
138 applicationId = "im.quicksy.client"
139 resValue "string", "applicationId", applicationId
140
141 def appName = "Quicksy"
142 resValue "string", "app_name", appName
143 buildConfigField "String", "APP_NAME", "\"$appName\"";
144 }
145
146 conversations {
147 dimension "mode"
148 }
149
150 playstore {
151 dimension "distribution"
152 versionNameSuffix "+p"
153 }
154 free {
155 dimension "distribution"
156 versionNameSuffix "+f"
157 }
158 system {
159 dimension "emoji"
160 versionNameSuffix "s"
161 }
162 compat {
163 dimension "emoji"
164 versionNameSuffix "c"
165 }
166 }
167
168 sourceSets {
169 quicksyFreeSystem {
170 java {
171 srcDir 'src/quicksyFree/java'
172 }
173 }
174 quicksyFreeCompat {
175 java {
176 srcDir 'src/freeCompat/java'
177 srcDir 'src/quicksyFree/java'
178 }
179 }
180 quicksyPlaystoreCompat {
181 java {
182 srcDir 'src/playstoreCompat/java'
183 srcDir 'src/quicksyPlaystore/java'
184 }
185 res {
186 srcDir 'src/playstoreCompat/res'
187 srcDir 'src/quicksyPlaystore/res'
188 }
189 }
190 quicksyPlaystoreSystem {
191 java {
192 srcDir 'src/quicksyPlaystore/java'
193 }
194 res {
195 srcDir 'src/quicksyPlaystore/res'
196 }
197 }
198 conversationsFreeCompat {
199 java {
200 srcDir 'src/freeCompat/java'
201 srcDir 'src/conversationsFree/java'
202 }
203 }
204 conversationsFreeSystem {
205 java {
206 srcDir 'src/conversationsFree/java'
207 }
208 }
209 conversationsPlaystoreCompat {
210 java {
211 srcDir 'src/playstoreCompat/java'
212 srcDir 'src/conversationsPlaystore/java'
213 }
214 res {
215 srcDir 'src/playstoreCompat/res'
216 srcDir 'src/conversationsPlaystore/res'
217 }
218 }
219 conversationsPlaystoreSystem {
220 java {
221 srcDir 'src/conversationsPlaystore/java'
222 }
223 res {
224 srcDir 'src/conversationsPlaystore/res'
225 }
226 }
227 }
228
229 buildTypes {
230 release {
231 shrinkResources true
232 minifyEnabled true
233 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
234 versionNameSuffix "r"
235 }
236 debug {
237 shrinkResources true
238 minifyEnabled true
239 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
240 versionNameSuffix "d"
241 }
242 }
243
244
245 if (new File("signing.properties").exists()) {
246 Properties props = new Properties()
247 props.load(new FileInputStream(file("signing.properties")))
248
249 signingConfigs {
250 release {
251 storeFile file(props['keystore'])
252 storePassword props['keystore.password']
253 keyAlias props['keystore.alias']
254 keyPassword props['keystore.password']
255 }
256 }
257 buildTypes.release.signingConfig = signingConfigs.release
258 }
259
260 lintOptions {
261 disable 'MissingTranslation', 'InvalidPackage','AppCompatResource'
262 }
263
264 subprojects {
265
266 afterEvaluate {
267 if (getPlugins().hasPlugin('android') ||
268 getPlugins().hasPlugin('android-library')) {
269
270 configure(android.lintOptions) {
271 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
272 }
273 }
274
275 }
276 }
277
278 packagingOptions {
279 exclude 'META-INF/BCKEY.DSA'
280 exclude 'META-INF/BCKEY.SF'
281 }
282
283 android.applicationVariants.all { variant ->
284 variant.outputs.each { output ->
285 def baseAbiVersionCode = project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))
286 if (baseAbiVersionCode != null) {
287 output.versionCodeOverride = (100 * variant.versionCode) + baseAbiVersionCode
288 }
289 }
290
291 }
292}