1// Top-level build file where you can add configuration options common to all
2// sub-projects/modules.
3buildscript {
4 repositories {
5 google()
6 jcenter()
7 }
8 dependencies {
9 classpath 'com.android.tools.build:gradle:3.2.1'
10 }
11}
12
13apply plugin: 'com.android.application'
14
15repositories {
16 google()
17 jcenter()
18 mavenCentral()
19}
20
21configurations {
22 playstoreImplementation
23 compatImplementation
24 conversationsFreeCompatImplementation
25 quicksyFreeCompatImplementation
26 quicksyImplementation
27}
28
29ext {
30 supportLibVersion = '28.0.0'
31}
32
33dependencies {
34 playstoreImplementation('com.google.firebase:firebase-messaging:15.0.2') {
35 exclude group: 'com.google.firebase', module: 'firebase-core'
36 }
37 implementation 'org.sufficientlysecure:openpgp-api:10.0'
38 implementation ('com.theartofdev.edmodo:android-image-cropper:2.7.+') {
39 exclude group: 'com.android.support', module: 'appcompat-v7'
40 exclude group: 'com.android.support', module: 'exifinterface'
41 }
42 implementation "com.android.support:support-v13:$supportLibVersion"
43 implementation "com.android.support:appcompat-v7:$supportLibVersion"
44 implementation "com.android.support:exifinterface:$supportLibVersion"
45 implementation "com.android.support:cardview-v7:$supportLibVersion"
46 implementation "com.android.support:support-emoji:$supportLibVersion"
47 implementation "com.android.support:design:$supportLibVersion"
48 compatImplementation "com.android.support:support-emoji-appcompat:$supportLibVersion"
49 conversationsFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
50 quicksyFreeCompatImplementation "com.android.support:support-emoji-bundled:$supportLibVersion"
51 implementation 'org.bouncycastle:bcmail-jdk15on:1.58'
52 implementation 'com.google.zxing:core:3.3.0'
53 implementation 'de.measite.minidns:minidns-hla:0.2.4'
54 implementation 'me.leolin:ShortcutBadger:1.1.22@aar'
55 implementation 'org.whispersystems:signal-protocol-java:2.6.2'
56 implementation 'com.makeramen:roundedimageview:2.3.0'
57 implementation "com.wefika:flowlayout:0.4.1"
58 implementation 'net.ypresto.androidtranscoder:android-transcoder:0.2.0'
59 implementation 'rocks.xmpp:xmpp-addr:0.8.0'
60 implementation 'org.osmdroid:osmdroid-android:6.0.1'
61 implementation 'org.hsluv:hsluv:0.2'
62 implementation 'org.conscrypt:conscrypt-android:1.3.0'
63 quicksyImplementation 'io.michaelrocks:libphonenumber-android:8.9.14'
64}
65
66ext {
67 travisBuild = System.getenv("TRAVIS") == "true"
68 preDexEnabled = System.getProperty("pre-dex", "true")
69}
70
71android {
72 compileSdkVersion 28
73
74 defaultConfig {
75 minSdkVersion 19
76 targetSdkVersion 25
77 versionCode 297
78 versionName "2.3.5"
79 archivesBaseName += "-$versionName"
80 applicationId "eu.siacs.conversations"
81 resValue "string", "applicationId", applicationId
82 resValue "string", "app_name", "Conversations"
83 buildConfigField "String", "LOGTAG", "\"conversations\""
84 }
85
86 dataBinding {
87 enabled true
88 }
89
90 dexOptions {
91 // Skip pre-dexing when running on Travis CI or when disabled via -Dpre-dex=false.
92 preDexLibraries = preDexEnabled && !travisBuild
93 jumboMode true
94 }
95
96 compileOptions {
97 sourceCompatibility JavaVersion.VERSION_1_8
98 targetCompatibility JavaVersion.VERSION_1_8
99 }
100
101 flavorDimensions("mode", "distribution", "emoji")
102
103 productFlavors {
104
105 quicksy {
106 dimension "mode"
107 applicationId = "im.quicksy.client"
108 resValue "string", "app_name", "Quicksy"
109 resValue "string", "applicationId", applicationId
110 buildConfigField "String", "LOGTAG", "\"quicksy\""
111 }
112
113 conversations {
114 dimension "mode"
115 }
116
117 playstore {
118 dimension "distribution"
119 versionNameSuffix "+p"
120 }
121 free {
122 dimension "distribution"
123 versionNameSuffix "+f"
124 }
125 system {
126 dimension "emoji"
127 versionNameSuffix "s"
128 }
129 compat {
130 dimension "emoji"
131 versionNameSuffix "c"
132 }
133 }
134
135 sourceSets {
136 quicksyFreeCompat {
137 java {
138 srcDirs 'src/freeCompat/java'
139 }
140 }
141 quicksyPlaystoreCompat {
142 java {
143 srcDirs 'src/playstoreCompat/java'
144 }
145 res {
146 srcDir 'src/playstoreCompat/res'
147 srcDir 'src/quicksyPlaystore/res'
148 }
149 }
150 quicksyPlaystoreSystem {
151 res {
152 srcDir 'src/quicksyPlaystore/res'
153 }
154 }
155 conversationsFreeCompat {
156 java {
157 srcDirs 'src/freeCompat/java'
158 }
159 }
160 conversationsPlaystoreCompat {
161 java {
162 srcDirs 'src/playstoreCompat/java'
163 }
164 res {
165 srcDir 'src/playstoreCompat/res'
166 srcDir 'src/conversationsPlaystore/res'
167 }
168 }
169 conversationsPlaystoreSystem {
170 res {
171 srcDir 'src/conversationsPlaystore/res'
172 }
173 }
174 }
175
176 buildTypes {
177 release {
178 shrinkResources true
179 minifyEnabled true
180 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
181 versionNameSuffix "r"
182 }
183 debug {
184 shrinkResources true
185 minifyEnabled true
186 proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
187 versionNameSuffix "d"
188 }
189 }
190
191
192
193 if (new File("signing.properties").exists()) {
194 Properties props = new Properties()
195 props.load(new FileInputStream(file("signing.properties")))
196
197 signingConfigs {
198 release {
199 storeFile file(props['keystore'])
200 storePassword props['keystore.password']
201 keyAlias props['keystore.alias']
202 keyPassword props['keystore.password']
203 }
204 }
205 buildTypes.release.signingConfig = signingConfigs.release
206 }
207
208 lintOptions {
209 disable 'MissingTranslation', 'InvalidPackage', 'MissingQuantity', 'AppCompatResource'
210 }
211
212 subprojects {
213
214 afterEvaluate {
215 if (getPlugins().hasPlugin('android') ||
216 getPlugins().hasPlugin('android-library')) {
217
218 configure(android.lintOptions) {
219 disable 'AndroidGradlePluginVersion', 'MissingTranslation'
220 }
221 }
222
223 }
224 }
225
226 packagingOptions {
227 exclude 'META-INF/BCKEY.DSA'
228 exclude 'META-INF/BCKEY.SF'
229 }
230}