1/* Functions useful for debugging:
2
3// A heat map color for debugging (blue -> cyan -> green -> yellow -> red).
4fn heat_map_color(value: f32, minValue: f32, maxValue: f32, position: vec2<f32>) -> vec4<f32> {
5 // Normalize value to 0-1 range
6 let t = clamp((value - minValue) / (maxValue - minValue), 0.0, 1.0);
7
8 // Heat map color calculation
9 let r = t * t;
10 let g = 4.0 * t * (1.0 - t);
11 let b = (1.0 - t) * (1.0 - t);
12 let heat_color = vec3<f32>(r, g, b);
13
14 // Create a checkerboard pattern (black and white)
15 let sum = floor(position.x / 3) + floor(position.y / 3);
16 let is_odd = fract(sum * 0.5); // 0.0 for even, 0.5 for odd
17 let checker_value = is_odd * 2.0; // 0.0 for even, 1.0 for odd
18 let checker_color = vec3<f32>(checker_value);
19
20 // Determine if value is in range (1.0 if in range, 0.0 if out of range)
21 let in_range = step(minValue, value) * step(value, maxValue);
22
23 // Mix checkerboard and heat map based on whether value is in range
24 let final_color = mix(checker_color, heat_color, in_range);
25
26 return vec4<f32>(final_color, 1.0);
27}
28
29*/
30
31fn color_brightness(color: vec3<f32>) -> f32 {
32 // REC. 601 luminance coefficients for perceived brightness
33 return dot(color, vec3<f32>(0.30, 0.59, 0.11));
34}
35
36fn light_on_dark_contrast(enhancedContrast: f32, color: vec3<f32>) -> f32 {
37 let brightness = color_brightness(color);
38 let multiplier = saturate(4.0 * (0.75 - brightness));
39 return enhancedContrast * multiplier;
40}
41
42fn enhance_contrast(alpha: f32, k: f32) -> f32 {
43 return alpha * (k + 1.0) / (alpha * k + 1.0);
44}
45
46fn apply_alpha_correction(a: f32, b: f32, g: vec4<f32>) -> f32 {
47 let brightness_adjustment = g.x * b + g.y;
48 let correction = brightness_adjustment * a + (g.z * b + g.w);
49 return a + a * (1.0 - a) * correction;
50}
51
52fn apply_contrast_and_gamma_correction(sample: f32, color: vec3<f32>, enhanced_contrast_factor: f32, gamma_ratios: vec4<f32>) -> f32 {
53 let enhanced_contrast = light_on_dark_contrast(enhanced_contrast_factor, color);
54 let brightness = color_brightness(color);
55
56 let contrasted = enhance_contrast(sample, enhanced_contrast);
57 return apply_alpha_correction(contrasted, brightness, gamma_ratios);
58}
59
60struct GlobalParams {
61 viewport_size: vec2<f32>,
62 premultiplied_alpha: u32,
63 pad: u32,
64}
65
66var<uniform> globals: GlobalParams;
67var<uniform> gamma_ratios: vec4<f32>;
68var<uniform> grayscale_enhanced_contrast: f32;
69var t_sprite: texture_2d<f32>;
70var s_sprite: sampler;
71
72const M_PI_F: f32 = 3.1415926;
73const GRAYSCALE_FACTORS: vec3<f32> = vec3<f32>(0.2126, 0.7152, 0.0722);
74
75struct Bounds {
76 origin: vec2<f32>,
77 size: vec2<f32>,
78}
79
80struct Corners {
81 top_left: f32,
82 top_right: f32,
83 bottom_right: f32,
84 bottom_left: f32,
85}
86
87struct Edges {
88 top: f32,
89 right: f32,
90 bottom: f32,
91 left: f32,
92}
93
94struct Hsla {
95 h: f32,
96 s: f32,
97 l: f32,
98 a: f32,
99}
100
101struct LinearColorStop {
102 color: Hsla,
103 percentage: f32,
104}
105
106struct Background {
107 // 0u is Solid
108 // 1u is LinearGradient
109 // 2u is PatternSlash
110 tag: u32,
111 // 0u is sRGB linear color
112 // 1u is Oklab color
113 color_space: u32,
114 solid: Hsla,
115 gradient_angle_or_pattern_height: f32,
116 colors: array<LinearColorStop, 2>,
117 pad: u32,
118}
119
120struct AtlasTextureId {
121 index: u32,
122 kind: u32,
123}
124
125struct AtlasBounds {
126 origin: vec2<i32>,
127 size: vec2<i32>,
128}
129
130struct AtlasTile {
131 texture_id: AtlasTextureId,
132 tile_id: u32,
133 padding: u32,
134 bounds: AtlasBounds,
135}
136
137struct TransformationMatrix {
138 rotation_scale: mat2x2<f32>,
139 translation: vec2<f32>,
140}
141
142fn to_device_position_impl(position: vec2<f32>) -> vec4<f32> {
143 let device_position = position / globals.viewport_size * vec2<f32>(2.0, -2.0) + vec2<f32>(-1.0, 1.0);
144 return vec4<f32>(device_position, 0.0, 1.0);
145}
146
147fn to_device_position(unit_vertex: vec2<f32>, bounds: Bounds) -> vec4<f32> {
148 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
149 return to_device_position_impl(position);
150}
151
152fn to_device_position_transformed(unit_vertex: vec2<f32>, bounds: Bounds, transform: TransformationMatrix) -> vec4<f32> {
153 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
154 //Note: Rust side stores it as row-major, so transposing here
155 let transformed = transpose(transform.rotation_scale) * position + transform.translation;
156 return to_device_position_impl(transformed);
157}
158
159fn to_tile_position(unit_vertex: vec2<f32>, tile: AtlasTile) -> vec2<f32> {
160 let atlas_size = vec2<f32>(textureDimensions(t_sprite, 0));
161 return (vec2<f32>(tile.bounds.origin) + unit_vertex * vec2<f32>(tile.bounds.size)) / atlas_size;
162}
163
164fn distance_from_clip_rect_impl(position: vec2<f32>, clip_bounds: Bounds) -> vec4<f32> {
165 let tl = position - clip_bounds.origin;
166 let br = clip_bounds.origin + clip_bounds.size - position;
167 return vec4<f32>(tl.x, br.x, tl.y, br.y);
168}
169
170fn distance_from_clip_rect(unit_vertex: vec2<f32>, bounds: Bounds, clip_bounds: Bounds) -> vec4<f32> {
171 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
172 return distance_from_clip_rect_impl(position, clip_bounds);
173}
174
175fn distance_from_clip_rect_transformed(unit_vertex: vec2<f32>, bounds: Bounds, clip_bounds: Bounds, transform: TransformationMatrix) -> vec4<f32> {
176 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
177 let transformed = transpose(transform.rotation_scale) * position + transform.translation;
178 return distance_from_clip_rect_impl(transformed, clip_bounds);
179}
180
181// https://gamedev.stackexchange.com/questions/92015/optimized-linear-to-srgb-glsl
182fn srgb_to_linear(srgb: vec3<f32>) -> vec3<f32> {
183 let cutoff = srgb < vec3<f32>(0.04045);
184 let higher = pow((srgb + vec3<f32>(0.055)) / vec3<f32>(1.055), vec3<f32>(2.4));
185 let lower = srgb / vec3<f32>(12.92);
186 return select(higher, lower, cutoff);
187}
188
189fn srgb_to_linear_component(a: f32) -> f32 {
190 let cutoff = a < 0.04045;
191 let higher = pow((a + 0.055) / 1.055, 2.4);
192 let lower = a / 12.92;
193 return select(higher, lower, cutoff);
194}
195
196fn linear_to_srgb(linear: vec3<f32>) -> vec3<f32> {
197 let cutoff = linear < vec3<f32>(0.0031308);
198 let higher = vec3<f32>(1.055) * pow(linear, vec3<f32>(1.0 / 2.4)) - vec3<f32>(0.055);
199 let lower = linear * vec3<f32>(12.92);
200 return select(higher, lower, cutoff);
201}
202
203/// Convert a linear color to sRGBA space.
204fn linear_to_srgba(color: vec4<f32>) -> vec4<f32> {
205 return vec4<f32>(linear_to_srgb(color.rgb), color.a);
206}
207
208/// Convert a sRGBA color to linear space.
209fn srgba_to_linear(color: vec4<f32>) -> vec4<f32> {
210 return vec4<f32>(srgb_to_linear(color.rgb), color.a);
211}
212
213/// Hsla to linear RGBA conversion.
214fn hsla_to_rgba(hsla: Hsla) -> vec4<f32> {
215 let h = hsla.h * 6.0; // Now, it's an angle but scaled in [0, 6) range
216 let s = hsla.s;
217 let l = hsla.l;
218 let a = hsla.a;
219
220 let c = (1.0 - abs(2.0 * l - 1.0)) * s;
221 let x = c * (1.0 - abs(h % 2.0 - 1.0));
222 let m = l - c / 2.0;
223 var color = vec3<f32>(m);
224
225 if (h >= 0.0 && h < 1.0) {
226 color.r += c;
227 color.g += x;
228 } else if (h >= 1.0 && h < 2.0) {
229 color.r += x;
230 color.g += c;
231 } else if (h >= 2.0 && h < 3.0) {
232 color.g += c;
233 color.b += x;
234 } else if (h >= 3.0 && h < 4.0) {
235 color.g += x;
236 color.b += c;
237 } else if (h >= 4.0 && h < 5.0) {
238 color.r += x;
239 color.b += c;
240 } else {
241 color.r += c;
242 color.b += x;
243 }
244
245 return vec4<f32>(color, a);
246}
247
248/// Convert a linear sRGB to Oklab space.
249/// Reference: https://bottosson.github.io/posts/oklab/#converting-from-linear-srgb-to-oklab
250fn linear_srgb_to_oklab(color: vec4<f32>) -> vec4<f32> {
251 let l = 0.4122214708 * color.r + 0.5363325363 * color.g + 0.0514459929 * color.b;
252 let m = 0.2119034982 * color.r + 0.6806995451 * color.g + 0.1073969566 * color.b;
253 let s = 0.0883024619 * color.r + 0.2817188376 * color.g + 0.6299787005 * color.b;
254
255 let l_ = pow(l, 1.0 / 3.0);
256 let m_ = pow(m, 1.0 / 3.0);
257 let s_ = pow(s, 1.0 / 3.0);
258
259 return vec4<f32>(
260 0.2104542553 * l_ + 0.7936177850 * m_ - 0.0040720468 * s_,
261 1.9779984951 * l_ - 2.4285922050 * m_ + 0.4505937099 * s_,
262 0.0259040371 * l_ + 0.7827717662 * m_ - 0.8086757660 * s_,
263 color.a
264 );
265}
266
267/// Convert an Oklab color to linear sRGB space.
268fn oklab_to_linear_srgb(color: vec4<f32>) -> vec4<f32> {
269 let l_ = color.r + 0.3963377774 * color.g + 0.2158037573 * color.b;
270 let m_ = color.r - 0.1055613458 * color.g - 0.0638541728 * color.b;
271 let s_ = color.r - 0.0894841775 * color.g - 1.2914855480 * color.b;
272
273 let l = l_ * l_ * l_;
274 let m = m_ * m_ * m_;
275 let s = s_ * s_ * s_;
276
277 return vec4<f32>(
278 4.0767416621 * l - 3.3077115913 * m + 0.2309699292 * s,
279 -1.2684380046 * l + 2.6097574011 * m - 0.3413193965 * s,
280 -0.0041960863 * l - 0.7034186147 * m + 1.7076147010 * s,
281 color.a
282 );
283}
284
285fn over(below: vec4<f32>, above: vec4<f32>) -> vec4<f32> {
286 let alpha = above.a + below.a * (1.0 - above.a);
287 let color = (above.rgb * above.a + below.rgb * below.a * (1.0 - above.a)) / alpha;
288 return vec4<f32>(color, alpha);
289}
290
291// A standard gaussian function, used for weighting samples
292fn gaussian(x: f32, sigma: f32) -> f32{
293 return exp(-(x * x) / (2.0 * sigma * sigma)) / (sqrt(2.0 * M_PI_F) * sigma);
294}
295
296// This approximates the error function, needed for the gaussian integral
297fn erf(v: vec2<f32>) -> vec2<f32> {
298 let s = sign(v);
299 let a = abs(v);
300 let r1 = 1.0 + (0.278393 + (0.230389 + (0.000972 + 0.078108 * a) * a) * a) * a;
301 let r2 = r1 * r1;
302 return s - s / (r2 * r2);
303}
304
305fn blur_along_x(x: f32, y: f32, sigma: f32, corner: f32, half_size: vec2<f32>) -> f32 {
306 let delta = min(half_size.y - corner - abs(y), 0.0);
307 let curved = half_size.x - corner + sqrt(max(0.0, corner * corner - delta * delta));
308 let integral = 0.5 + 0.5 * erf((x + vec2<f32>(-curved, curved)) * (sqrt(0.5) / sigma));
309 return integral.y - integral.x;
310}
311
312// Selects corner radius based on quadrant.
313fn pick_corner_radius(center_to_point: vec2<f32>, radii: Corners) -> f32 {
314 if (center_to_point.x < 0.0) {
315 if (center_to_point.y < 0.0) {
316 return radii.top_left;
317 } else {
318 return radii.bottom_left;
319 }
320 } else {
321 if (center_to_point.y < 0.0) {
322 return radii.top_right;
323 } else {
324 return radii.bottom_right;
325 }
326 }
327}
328
329// Signed distance of the point to the quad's border - positive outside the
330// border, and negative inside.
331//
332// See comments on similar code using `quad_sdf_impl` in `fs_quad` for
333// explanation.
334fn quad_sdf(point: vec2<f32>, bounds: Bounds, corner_radii: Corners) -> f32 {
335 let half_size = bounds.size / 2.0;
336 let center = bounds.origin + half_size;
337 let center_to_point = point - center;
338 let corner_radius = pick_corner_radius(center_to_point, corner_radii);
339 let corner_to_point = abs(center_to_point) - half_size;
340 let corner_center_to_point = corner_to_point + corner_radius;
341 return quad_sdf_impl(corner_center_to_point, corner_radius);
342}
343
344fn quad_sdf_impl(corner_center_to_point: vec2<f32>, corner_radius: f32) -> f32 {
345 if (corner_radius == 0.0) {
346 // Fast path for unrounded corners.
347 return max(corner_center_to_point.x, corner_center_to_point.y);
348 } else {
349 // Signed distance of the point from a quad that is inset by corner_radius.
350 // It is negative inside this quad, and positive outside.
351 let signed_distance_to_inset_quad =
352 // 0 inside the inset quad, and positive outside.
353 length(max(vec2<f32>(0.0), corner_center_to_point)) +
354 // 0 outside the inset quad, and negative inside.
355 min(0.0, max(corner_center_to_point.x, corner_center_to_point.y));
356
357 return signed_distance_to_inset_quad - corner_radius;
358 }
359}
360
361// Abstract away the final color transformation based on the
362// target alpha compositing mode.
363fn blend_color(color: vec4<f32>, alpha_factor: f32) -> vec4<f32> {
364 let alpha = color.a * alpha_factor;
365 let multiplier = select(1.0, alpha, globals.premultiplied_alpha != 0u);
366 return vec4<f32>(color.rgb * multiplier, alpha);
367}
368
369
370struct GradientColor {
371 solid: vec4<f32>,
372 color0: vec4<f32>,
373 color1: vec4<f32>,
374}
375
376fn prepare_gradient_color(tag: u32, color_space: u32,
377 solid: Hsla, colors: array<LinearColorStop, 2>) -> GradientColor {
378 var result = GradientColor();
379
380 if (tag == 0u || tag == 2u) {
381 result.solid = hsla_to_rgba(solid);
382 } else if (tag == 1u) {
383 // The hsla_to_rgba is returns a linear sRGB color
384 result.color0 = hsla_to_rgba(colors[0].color);
385 result.color1 = hsla_to_rgba(colors[1].color);
386
387 // Prepare color space in vertex for avoid conversion
388 // in fragment shader for performance reasons
389 if (color_space == 0u) {
390 // sRGB
391 result.color0 = linear_to_srgba(result.color0);
392 result.color1 = linear_to_srgba(result.color1);
393 } else if (color_space == 1u) {
394 // Oklab
395 result.color0 = linear_srgb_to_oklab(result.color0);
396 result.color1 = linear_srgb_to_oklab(result.color1);
397 }
398 }
399
400 return result;
401}
402
403fn gradient_color(background: Background, position: vec2<f32>, bounds: Bounds,
404 solid_color: vec4<f32>, color0: vec4<f32>, color1: vec4<f32>) -> vec4<f32> {
405 var background_color = vec4<f32>(0.0);
406
407 switch (background.tag) {
408 default: {
409 return solid_color;
410 }
411 case 1u: {
412 // Linear gradient background.
413 // -90 degrees to match the CSS gradient angle.
414 let angle = background.gradient_angle_or_pattern_height;
415 let radians = (angle % 360.0 - 90.0) * M_PI_F / 180.0;
416 var direction = vec2<f32>(cos(radians), sin(radians));
417 let stop0_percentage = background.colors[0].percentage;
418 let stop1_percentage = background.colors[1].percentage;
419
420 // Expand the short side to be the same as the long side
421 if (bounds.size.x > bounds.size.y) {
422 direction.y *= bounds.size.y / bounds.size.x;
423 } else {
424 direction.x *= bounds.size.x / bounds.size.y;
425 }
426
427 // Get the t value for the linear gradient with the color stop percentages.
428 let half_size = bounds.size / 2.0;
429 let center = bounds.origin + half_size;
430 let center_to_point = position - center;
431 var t = dot(center_to_point, direction) / length(direction);
432 // Check the direct to determine the use x or y
433 if (abs(direction.x) > abs(direction.y)) {
434 t = (t + half_size.x) / bounds.size.x;
435 } else {
436 t = (t + half_size.y) / bounds.size.y;
437 }
438
439 // Adjust t based on the stop percentages
440 t = (t - stop0_percentage) / (stop1_percentage - stop0_percentage);
441 t = clamp(t, 0.0, 1.0);
442
443 switch (background.color_space) {
444 default: {
445 background_color = srgba_to_linear(mix(color0, color1, t));
446 }
447 case 1u: {
448 let oklab_color = mix(color0, color1, t);
449 background_color = oklab_to_linear_srgb(oklab_color);
450 }
451 }
452 }
453 case 2u: {
454 let gradient_angle_or_pattern_height = background.gradient_angle_or_pattern_height;
455 let pattern_width = (gradient_angle_or_pattern_height / 65535.0f) / 255.0f;
456 let pattern_interval = (gradient_angle_or_pattern_height % 65535.0f) / 255.0f;
457 let pattern_height = pattern_width + pattern_interval;
458 let stripe_angle = M_PI_F / 4.0;
459 let pattern_period = pattern_height * sin(stripe_angle);
460 let rotation = mat2x2<f32>(
461 cos(stripe_angle), -sin(stripe_angle),
462 sin(stripe_angle), cos(stripe_angle)
463 );
464 let relative_position = position - bounds.origin;
465 let rotated_point = rotation * relative_position;
466 let pattern = rotated_point.x % pattern_period;
467 let distance = min(pattern, pattern_period - pattern) - pattern_period * (pattern_width / pattern_height) / 2.0f;
468 background_color = solid_color;
469 background_color.a *= saturate(0.5 - distance);
470 }
471 }
472
473 return background_color;
474}
475
476// --- quads --- //
477
478struct Quad {
479 order: u32,
480 border_style: u32,
481 bounds: Bounds,
482 content_mask: Bounds,
483 background: Background,
484 border_color: Hsla,
485 corner_radii: Corners,
486 border_widths: Edges,
487}
488var<storage, read> b_quads: array<Quad>;
489
490struct QuadVarying {
491 @builtin(position) position: vec4<f32>,
492 @location(0) @interpolate(flat) border_color: vec4<f32>,
493 @location(1) @interpolate(flat) quad_id: u32,
494 // TODO: use `clip_distance` once Naga supports it
495 @location(2) clip_distances: vec4<f32>,
496 @location(3) @interpolate(flat) background_solid: vec4<f32>,
497 @location(4) @interpolate(flat) background_color0: vec4<f32>,
498 @location(5) @interpolate(flat) background_color1: vec4<f32>,
499}
500
501@vertex
502fn vs_quad(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> QuadVarying {
503 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
504 let quad = b_quads[instance_id];
505
506 var out = QuadVarying();
507 out.position = to_device_position(unit_vertex, quad.bounds);
508
509 let gradient = prepare_gradient_color(
510 quad.background.tag,
511 quad.background.color_space,
512 quad.background.solid,
513 quad.background.colors
514 );
515 out.background_solid = gradient.solid;
516 out.background_color0 = gradient.color0;
517 out.background_color1 = gradient.color1;
518 out.border_color = hsla_to_rgba(quad.border_color);
519 out.quad_id = instance_id;
520 out.clip_distances = distance_from_clip_rect(unit_vertex, quad.bounds, quad.content_mask);
521 return out;
522}
523
524@fragment
525fn fs_quad(input: QuadVarying) -> @location(0) vec4<f32> {
526 // Alpha clip first, since we don't have `clip_distance`.
527 if (any(input.clip_distances < vec4<f32>(0.0))) {
528 return vec4<f32>(0.0);
529 }
530
531 let quad = b_quads[input.quad_id];
532
533 let background_color = gradient_color(quad.background, input.position.xy, quad.bounds,
534 input.background_solid, input.background_color0, input.background_color1);
535
536 let unrounded = quad.corner_radii.top_left == 0.0 &&
537 quad.corner_radii.bottom_left == 0.0 &&
538 quad.corner_radii.top_right == 0.0 &&
539 quad.corner_radii.bottom_right == 0.0;
540
541 // Fast path when the quad is not rounded and doesn't have any border
542 if (quad.border_widths.top == 0.0 &&
543 quad.border_widths.left == 0.0 &&
544 quad.border_widths.right == 0.0 &&
545 quad.border_widths.bottom == 0.0 &&
546 unrounded) {
547 return blend_color(background_color, 1.0);
548 }
549
550 let size = quad.bounds.size;
551 let half_size = size / 2.0;
552 let point = input.position.xy - quad.bounds.origin;
553 let center_to_point = point - half_size;
554
555 // Signed distance field threshold for inclusion of pixels. 0.5 is the
556 // minimum distance between the center of the pixel and the edge.
557 let antialias_threshold = 0.5;
558
559 // Radius of the nearest corner
560 let corner_radius = pick_corner_radius(center_to_point, quad.corner_radii);
561
562 // Width of the nearest borders
563 let border = vec2<f32>(
564 select(
565 quad.border_widths.right,
566 quad.border_widths.left,
567 center_to_point.x < 0.0),
568 select(
569 quad.border_widths.bottom,
570 quad.border_widths.top,
571 center_to_point.y < 0.0));
572
573 // 0-width borders are reduced so that `inner_sdf >= antialias_threshold`.
574 // The purpose of this is to not draw antialiasing pixels in this case.
575 let reduced_border =
576 vec2<f32>(select(border.x, -antialias_threshold, border.x == 0.0),
577 select(border.y, -antialias_threshold, border.y == 0.0));
578
579 // Vector from the corner of the quad bounds to the point, after mirroring
580 // the point into the bottom right quadrant. Both components are <= 0.
581 let corner_to_point = abs(center_to_point) - half_size;
582
583 // Vector from the point to the center of the rounded corner's circle, also
584 // mirrored into bottom right quadrant.
585 let corner_center_to_point = corner_to_point + corner_radius;
586
587 // Whether the nearest point on the border is rounded
588 let is_near_rounded_corner =
589 corner_center_to_point.x >= 0 &&
590 corner_center_to_point.y >= 0;
591
592 // Vector from straight border inner corner to point.
593 let straight_border_inner_corner_to_point = corner_to_point + reduced_border;
594
595 // Whether the point is beyond the inner edge of the straight border.
596 let is_beyond_inner_straight_border =
597 straight_border_inner_corner_to_point.x > 0 ||
598 straight_border_inner_corner_to_point.y > 0;
599
600 // Whether the point is far enough inside the quad, such that the pixels are
601 // not affected by the straight border.
602 let is_within_inner_straight_border =
603 straight_border_inner_corner_to_point.x < -antialias_threshold &&
604 straight_border_inner_corner_to_point.y < -antialias_threshold;
605
606 // Fast path for points that must be part of the background.
607 //
608 // This could be optimized further for large rounded corners by including
609 // points in an inscribed rectangle, or some other quick linear check.
610 // However, that might negatively impact performance in the case of
611 // reasonable sizes for rounded corners.
612 if (is_within_inner_straight_border && !is_near_rounded_corner) {
613 return blend_color(background_color, 1.0);
614 }
615
616 // Signed distance of the point to the outside edge of the quad's border. It
617 // is positive outside this edge, and negative inside.
618 let outer_sdf = quad_sdf_impl(corner_center_to_point, corner_radius);
619
620 // Approximate signed distance of the point to the inside edge of the quad's
621 // border. It is negative outside this edge (within the border), and
622 // positive inside.
623 //
624 // This is not always an accurate signed distance:
625 // * The rounded portions with varying border width use an approximation of
626 // nearest-point-on-ellipse.
627 // * When it is quickly known to be outside the edge, -1.0 is used.
628 var inner_sdf = 0.0;
629 if (corner_center_to_point.x <= 0 || corner_center_to_point.y <= 0) {
630 // Fast paths for straight borders.
631 inner_sdf = -max(straight_border_inner_corner_to_point.x,
632 straight_border_inner_corner_to_point.y);
633 } else if (is_beyond_inner_straight_border) {
634 // Fast path for points that must be outside the inner edge.
635 inner_sdf = -1.0;
636 } else if (reduced_border.x == reduced_border.y) {
637 // Fast path for circular inner edge.
638 inner_sdf = -(outer_sdf + reduced_border.x);
639 } else {
640 let ellipse_radii = max(vec2<f32>(0.0), corner_radius - reduced_border);
641 inner_sdf = quarter_ellipse_sdf(corner_center_to_point, ellipse_radii);
642 }
643
644 // Negative when inside the border
645 let border_sdf = max(inner_sdf, outer_sdf);
646
647 var color = background_color;
648 if (border_sdf < antialias_threshold) {
649 var border_color = input.border_color;
650
651 // Dashed border logic when border_style == 1
652 if (quad.border_style == 1) {
653 // Position along the perimeter in "dash space", where each dash
654 // period has length 1
655 var t = 0.0;
656
657 // Total number of dash periods, so that the dash spacing can be
658 // adjusted to evenly divide it
659 var max_t = 0.0;
660
661 // Border width is proportional to dash size. This is the behavior
662 // used by browsers, but also avoids dashes from different segments
663 // overlapping when dash size is smaller than the border width.
664 //
665 // Dash pattern: (2 * border width) dash, (1 * border width) gap
666 let dash_length_per_width = 2.0;
667 let dash_gap_per_width = 1.0;
668 let dash_period_per_width = dash_length_per_width + dash_gap_per_width;
669
670 // Since the dash size is determined by border width, the density of
671 // dashes varies. Multiplying a pixel distance by this returns a
672 // position in dash space - it has units (dash period / pixels). So
673 // a dash velocity of (1 / 10) is 1 dash every 10 pixels.
674 var dash_velocity = 0.0;
675
676 // Dividing this by the border width gives the dash velocity
677 let dv_numerator = 1.0 / dash_period_per_width;
678
679 if (unrounded) {
680 // When corners aren't rounded, the dashes are separately laid
681 // out on each straight line, rather than around the whole
682 // perimeter. This way each line starts and ends with a dash.
683 let is_horizontal =
684 corner_center_to_point.x <
685 corner_center_to_point.y;
686 let border_width = select(border.y, border.x, is_horizontal);
687 dash_velocity = dv_numerator / border_width;
688 t = select(point.y, point.x, is_horizontal) * dash_velocity;
689 max_t = select(size.y, size.x, is_horizontal) * dash_velocity;
690 } else {
691 // When corners are rounded, the dashes are laid out clockwise
692 // around the whole perimeter.
693
694 let r_tr = quad.corner_radii.top_right;
695 let r_br = quad.corner_radii.bottom_right;
696 let r_bl = quad.corner_radii.bottom_left;
697 let r_tl = quad.corner_radii.top_left;
698
699 let w_t = quad.border_widths.top;
700 let w_r = quad.border_widths.right;
701 let w_b = quad.border_widths.bottom;
702 let w_l = quad.border_widths.left;
703
704 // Straight side dash velocities
705 let dv_t = select(dv_numerator / w_t, 0.0, w_t <= 0.0);
706 let dv_r = select(dv_numerator / w_r, 0.0, w_r <= 0.0);
707 let dv_b = select(dv_numerator / w_b, 0.0, w_b <= 0.0);
708 let dv_l = select(dv_numerator / w_l, 0.0, w_l <= 0.0);
709
710 // Straight side lengths in dash space
711 let s_t = (size.x - r_tl - r_tr) * dv_t;
712 let s_r = (size.y - r_tr - r_br) * dv_r;
713 let s_b = (size.x - r_br - r_bl) * dv_b;
714 let s_l = (size.y - r_bl - r_tl) * dv_l;
715
716 let corner_dash_velocity_tr = corner_dash_velocity(dv_t, dv_r);
717 let corner_dash_velocity_br = corner_dash_velocity(dv_b, dv_r);
718 let corner_dash_velocity_bl = corner_dash_velocity(dv_b, dv_l);
719 let corner_dash_velocity_tl = corner_dash_velocity(dv_t, dv_l);
720
721 // Corner lengths in dash space
722 let c_tr = r_tr * (M_PI_F / 2.0) * corner_dash_velocity_tr;
723 let c_br = r_br * (M_PI_F / 2.0) * corner_dash_velocity_br;
724 let c_bl = r_bl * (M_PI_F / 2.0) * corner_dash_velocity_bl;
725 let c_tl = r_tl * (M_PI_F / 2.0) * corner_dash_velocity_tl;
726
727 // Cumulative dash space upto each segment
728 let upto_tr = s_t;
729 let upto_r = upto_tr + c_tr;
730 let upto_br = upto_r + s_r;
731 let upto_b = upto_br + c_br;
732 let upto_bl = upto_b + s_b;
733 let upto_l = upto_bl + c_bl;
734 let upto_tl = upto_l + s_l;
735 max_t = upto_tl + c_tl;
736
737 if (is_near_rounded_corner) {
738 let radians = atan2(corner_center_to_point.y,
739 corner_center_to_point.x);
740 let corner_t = radians * corner_radius;
741
742 if (center_to_point.x >= 0.0) {
743 if (center_to_point.y < 0.0) {
744 dash_velocity = corner_dash_velocity_tr;
745 // Subtracted because radians is pi/2 to 0 when
746 // going clockwise around the top right corner,
747 // since the y axis has been flipped
748 t = upto_r - corner_t * dash_velocity;
749 } else {
750 dash_velocity = corner_dash_velocity_br;
751 // Added because radians is 0 to pi/2 when going
752 // clockwise around the bottom-right corner
753 t = upto_br + corner_t * dash_velocity;
754 }
755 } else {
756 if (center_to_point.y >= 0.0) {
757 dash_velocity = corner_dash_velocity_bl;
758 // Subtracted because radians is pi/2 to 0 when
759 // going clockwise around the bottom-left corner,
760 // since the x axis has been flipped
761 t = upto_l - corner_t * dash_velocity;
762 } else {
763 dash_velocity = corner_dash_velocity_tl;
764 // Added because radians is 0 to pi/2 when going
765 // clockwise around the top-left corner, since both
766 // axis were flipped
767 t = upto_tl + corner_t * dash_velocity;
768 }
769 }
770 } else {
771 // Straight borders
772 let is_horizontal =
773 corner_center_to_point.x <
774 corner_center_to_point.y;
775 if (is_horizontal) {
776 if (center_to_point.y < 0.0) {
777 dash_velocity = dv_t;
778 t = (point.x - r_tl) * dash_velocity;
779 } else {
780 dash_velocity = dv_b;
781 t = upto_bl - (point.x - r_bl) * dash_velocity;
782 }
783 } else {
784 if (center_to_point.x < 0.0) {
785 dash_velocity = dv_l;
786 t = upto_tl - (point.y - r_tl) * dash_velocity;
787 } else {
788 dash_velocity = dv_r;
789 t = upto_r + (point.y - r_tr) * dash_velocity;
790 }
791 }
792 }
793 }
794
795 let dash_length = dash_length_per_width / dash_period_per_width;
796 let desired_dash_gap = dash_gap_per_width / dash_period_per_width;
797
798 // Straight borders should start and end with a dash, so max_t is
799 // reduced to cause this.
800 max_t -= select(0.0, dash_length, unrounded);
801 if (max_t >= 1.0) {
802 // Adjust dash gap to evenly divide max_t.
803 let dash_count = floor(max_t);
804 let dash_period = max_t / dash_count;
805 border_color.a *= dash_alpha(
806 t,
807 dash_period,
808 dash_length,
809 dash_velocity,
810 antialias_threshold);
811 } else if (unrounded) {
812 // When there isn't enough space for the full gap between the
813 // two start / end dashes of a straight border, reduce gap to
814 // make them fit.
815 let dash_gap = max_t - dash_length;
816 if (dash_gap > 0.0) {
817 let dash_period = dash_length + dash_gap;
818 border_color.a *= dash_alpha(
819 t,
820 dash_period,
821 dash_length,
822 dash_velocity,
823 antialias_threshold);
824 }
825 }
826 }
827
828 // Blend the border on top of the background and then linearly interpolate
829 // between the two as we slide inside the background.
830 let blended_border = over(background_color, border_color);
831 color = mix(background_color, blended_border,
832 saturate(antialias_threshold - inner_sdf));
833 }
834
835 return blend_color(color, saturate(antialias_threshold - outer_sdf));
836}
837
838// Returns the dash velocity of a corner given the dash velocity of the two
839// sides, by returning the slower velocity (larger dashes).
840//
841// Since 0 is used for dash velocity when the border width is 0 (instead of
842// +inf), this returns the other dash velocity in that case.
843//
844// An alternative to this might be to appropriately interpolate the dash
845// velocity around the corner, but that seems overcomplicated.
846fn corner_dash_velocity(dv1: f32, dv2: f32) -> f32 {
847 if (dv1 == 0.0) {
848 return dv2;
849 } else if (dv2 == 0.0) {
850 return dv1;
851 } else {
852 return min(dv1, dv2);
853 }
854}
855
856// Returns alpha used to render antialiased dashes.
857// `t` is within the dash when `fmod(t, period) < length`.
858fn dash_alpha(t: f32, period: f32, length: f32, dash_velocity: f32, antialias_threshold: f32) -> f32 {
859 let half_period = period / 2;
860 let half_length = length / 2;
861 // Value in [-half_period, half_period].
862 // The dash is in [-half_length, half_length].
863 let centered = fmod(t + half_period - half_length, period) - half_period;
864 // Signed distance for the dash, negative values are inside the dash.
865 let signed_distance = abs(centered) - half_length;
866 // Antialiased alpha based on the signed distance.
867 return saturate(antialias_threshold - signed_distance / dash_velocity);
868}
869
870// This approximates distance to the nearest point to a quarter ellipse in a way
871// that is sufficient for anti-aliasing when the ellipse is not very eccentric.
872// The components of `point` are expected to be positive.
873//
874// Negative on the outside and positive on the inside.
875fn quarter_ellipse_sdf(point: vec2<f32>, radii: vec2<f32>) -> f32 {
876 // Scale the space to treat the ellipse like a unit circle.
877 let circle_vec = point / radii;
878 let unit_circle_sdf = length(circle_vec) - 1.0;
879 // Approximate up-scaling of the length by using the average of the radii.
880 //
881 // TODO: A better solution would be to use the gradient of the implicit
882 // function for an ellipse to approximate a scaling factor.
883 return unit_circle_sdf * (radii.x + radii.y) * -0.5;
884}
885
886// Modulus that has the same sign as `a`.
887fn fmod(a: f32, b: f32) -> f32 {
888 return a - b * trunc(a / b);
889}
890
891// --- shadows --- //
892
893struct Shadow {
894 order: u32,
895 blur_radius: f32,
896 bounds: Bounds,
897 corner_radii: Corners,
898 content_mask: Bounds,
899 color: Hsla,
900}
901var<storage, read> b_shadows: array<Shadow>;
902
903struct ShadowVarying {
904 @builtin(position) position: vec4<f32>,
905 @location(0) @interpolate(flat) color: vec4<f32>,
906 @location(1) @interpolate(flat) shadow_id: u32,
907 //TODO: use `clip_distance` once Naga supports it
908 @location(3) clip_distances: vec4<f32>,
909}
910
911@vertex
912fn vs_shadow(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> ShadowVarying {
913 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
914 var shadow = b_shadows[instance_id];
915
916 let margin = 3.0 * shadow.blur_radius;
917 // Set the bounds of the shadow and adjust its size based on the shadow's
918 // spread radius to achieve the spreading effect
919 shadow.bounds.origin -= vec2<f32>(margin);
920 shadow.bounds.size += 2.0 * vec2<f32>(margin);
921
922 var out = ShadowVarying();
923 out.position = to_device_position(unit_vertex, shadow.bounds);
924 out.color = hsla_to_rgba(shadow.color);
925 out.shadow_id = instance_id;
926 out.clip_distances = distance_from_clip_rect(unit_vertex, shadow.bounds, shadow.content_mask);
927 return out;
928}
929
930@fragment
931fn fs_shadow(input: ShadowVarying) -> @location(0) vec4<f32> {
932 // Alpha clip first, since we don't have `clip_distance`.
933 if (any(input.clip_distances < vec4<f32>(0.0))) {
934 return vec4<f32>(0.0);
935 }
936
937 let shadow = b_shadows[input.shadow_id];
938 let half_size = shadow.bounds.size / 2.0;
939 let center = shadow.bounds.origin + half_size;
940 let center_to_point = input.position.xy - center;
941
942 let corner_radius = pick_corner_radius(center_to_point, shadow.corner_radii);
943
944 // The signal is only non-zero in a limited range, so don't waste samples
945 let low = center_to_point.y - half_size.y;
946 let high = center_to_point.y + half_size.y;
947 let start = clamp(-3.0 * shadow.blur_radius, low, high);
948 let end = clamp(3.0 * shadow.blur_radius, low, high);
949
950 // Accumulate samples (we can get away with surprisingly few samples)
951 let step = (end - start) / 4.0;
952 var y = start + step * 0.5;
953 var alpha = 0.0;
954 for (var i = 0; i < 4; i += 1) {
955 let blur = blur_along_x(center_to_point.x, center_to_point.y - y,
956 shadow.blur_radius, corner_radius, half_size);
957 alpha += blur * gaussian(y, shadow.blur_radius) * step;
958 y += step;
959 }
960
961 return blend_color(input.color, alpha);
962}
963
964// --- path rasterization --- //
965
966struct PathRasterizationVertex {
967 xy_position: vec2<f32>,
968 st_position: vec2<f32>,
969 color: Background,
970 bounds: Bounds,
971}
972
973var<storage, read> b_path_vertices: array<PathRasterizationVertex>;
974
975struct PathRasterizationVarying {
976 @builtin(position) position: vec4<f32>,
977 @location(0) st_position: vec2<f32>,
978 @location(1) vertex_id: u32,
979 //TODO: use `clip_distance` once Naga supports it
980 @location(3) clip_distances: vec4<f32>,
981}
982
983@vertex
984fn vs_path_rasterization(@builtin(vertex_index) vertex_id: u32) -> PathRasterizationVarying {
985 let v = b_path_vertices[vertex_id];
986
987 var out = PathRasterizationVarying();
988 out.position = to_device_position_impl(v.xy_position);
989 out.st_position = v.st_position;
990 out.vertex_id = vertex_id;
991 out.clip_distances = distance_from_clip_rect_impl(v.xy_position, v.bounds);
992 return out;
993}
994
995@fragment
996fn fs_path_rasterization(input: PathRasterizationVarying) -> @location(0) vec4<f32> {
997 let dx = dpdx(input.st_position);
998 let dy = dpdy(input.st_position);
999 if (any(input.clip_distances < vec4<f32>(0.0))) {
1000 return vec4<f32>(0.0);
1001 }
1002
1003 let v = b_path_vertices[input.vertex_id];
1004 let background = v.color;
1005 let bounds = v.bounds;
1006
1007 var alpha: f32;
1008 if (length(vec2<f32>(dx.x, dy.x)) < 0.001) {
1009 // If the gradient is too small, return a solid color.
1010 alpha = 1.0;
1011 } else {
1012 let gradient = 2.0 * input.st_position.xx * vec2<f32>(dx.x, dy.x) - vec2<f32>(dx.y, dy.y);
1013 let f = input.st_position.x * input.st_position.x - input.st_position.y;
1014 let distance = f / length(gradient);
1015 alpha = saturate(0.5 - distance);
1016 }
1017 let gradient_color = prepare_gradient_color(
1018 background.tag,
1019 background.color_space,
1020 background.solid,
1021 background.colors,
1022 );
1023 let color = gradient_color(background, input.position.xy, bounds,
1024 gradient_color.solid, gradient_color.color0, gradient_color.color1);
1025 return vec4<f32>(color.rgb * color.a * alpha, color.a * alpha);
1026}
1027
1028// --- paths --- //
1029
1030struct PathSprite {
1031 bounds: Bounds,
1032}
1033var<storage, read> b_path_sprites: array<PathSprite>;
1034
1035struct PathVarying {
1036 @builtin(position) position: vec4<f32>,
1037 @location(0) texture_coords: vec2<f32>,
1038}
1039
1040@vertex
1041fn vs_path(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> PathVarying {
1042 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1043 let sprite = b_path_sprites[instance_id];
1044 // Don't apply content mask because it was already accounted for when rasterizing the path.
1045 let device_position = to_device_position(unit_vertex, sprite.bounds);
1046 // For screen-space intermediate texture, convert screen position to texture coordinates
1047 let screen_position = sprite.bounds.origin + unit_vertex * sprite.bounds.size;
1048 let texture_coords = screen_position / globals.viewport_size;
1049
1050 var out = PathVarying();
1051 out.position = device_position;
1052 out.texture_coords = texture_coords;
1053
1054 return out;
1055}
1056
1057@fragment
1058fn fs_path(input: PathVarying) -> @location(0) vec4<f32> {
1059 let sample = textureSample(t_sprite, s_sprite, input.texture_coords);
1060 return sample;
1061}
1062
1063// --- underlines --- //
1064
1065struct Underline {
1066 order: u32,
1067 pad: u32,
1068 bounds: Bounds,
1069 content_mask: Bounds,
1070 color: Hsla,
1071 thickness: f32,
1072 wavy: u32,
1073}
1074var<storage, read> b_underlines: array<Underline>;
1075
1076struct UnderlineVarying {
1077 @builtin(position) position: vec4<f32>,
1078 @location(0) @interpolate(flat) color: vec4<f32>,
1079 @location(1) @interpolate(flat) underline_id: u32,
1080 //TODO: use `clip_distance` once Naga supports it
1081 @location(3) clip_distances: vec4<f32>,
1082}
1083
1084@vertex
1085fn vs_underline(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> UnderlineVarying {
1086 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1087 let underline = b_underlines[instance_id];
1088
1089 var out = UnderlineVarying();
1090 out.position = to_device_position(unit_vertex, underline.bounds);
1091 out.color = hsla_to_rgba(underline.color);
1092 out.underline_id = instance_id;
1093 out.clip_distances = distance_from_clip_rect(unit_vertex, underline.bounds, underline.content_mask);
1094 return out;
1095}
1096
1097@fragment
1098fn fs_underline(input: UnderlineVarying) -> @location(0) vec4<f32> {
1099 const WAVE_FREQUENCY: f32 = 2.0;
1100 const WAVE_HEIGHT_RATIO: f32 = 0.8;
1101
1102 // Alpha clip first, since we don't have `clip_distance`.
1103 if (any(input.clip_distances < vec4<f32>(0.0))) {
1104 return vec4<f32>(0.0);
1105 }
1106
1107 let underline = b_underlines[input.underline_id];
1108 if ((underline.wavy & 0xFFu) == 0u)
1109 {
1110 return blend_color(input.color, input.color.a);
1111 }
1112
1113 let half_thickness = underline.thickness * 0.5;
1114
1115 let st = (input.position.xy - underline.bounds.origin) / underline.bounds.size.y - vec2<f32>(0.0, 0.5);
1116 let frequency = M_PI_F * WAVE_FREQUENCY * underline.thickness / underline.bounds.size.y;
1117 let amplitude = (underline.thickness * WAVE_HEIGHT_RATIO) / underline.bounds.size.y;
1118
1119 let sine = sin(st.x * frequency) * amplitude;
1120 let dSine = cos(st.x * frequency) * amplitude * frequency;
1121 let distance = (st.y - sine) / sqrt(1.0 + dSine * dSine);
1122 let distance_in_pixels = distance * underline.bounds.size.y;
1123 let distance_from_top_border = distance_in_pixels - half_thickness;
1124 let distance_from_bottom_border = distance_in_pixels + half_thickness;
1125 let alpha = saturate(0.5 - max(-distance_from_bottom_border, distance_from_top_border));
1126 return blend_color(input.color, alpha * input.color.a);
1127}
1128
1129// --- monochrome sprites --- //
1130
1131struct MonochromeSprite {
1132 order: u32,
1133 pad: u32,
1134 bounds: Bounds,
1135 content_mask: Bounds,
1136 color: Hsla,
1137 tile: AtlasTile,
1138 transformation: TransformationMatrix,
1139}
1140var<storage, read> b_mono_sprites: array<MonochromeSprite>;
1141
1142struct MonoSpriteVarying {
1143 @builtin(position) position: vec4<f32>,
1144 @location(0) tile_position: vec2<f32>,
1145 @location(1) @interpolate(flat) color: vec4<f32>,
1146 @location(3) clip_distances: vec4<f32>,
1147}
1148
1149@vertex
1150fn vs_mono_sprite(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> MonoSpriteVarying {
1151 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1152 let sprite = b_mono_sprites[instance_id];
1153
1154 var out = MonoSpriteVarying();
1155 out.position = to_device_position_transformed(unit_vertex, sprite.bounds, sprite.transformation);
1156
1157 out.tile_position = to_tile_position(unit_vertex, sprite.tile);
1158 out.color = hsla_to_rgba(sprite.color);
1159 out.clip_distances = distance_from_clip_rect_transformed(unit_vertex, sprite.bounds, sprite.content_mask, sprite.transformation);
1160 return out;
1161}
1162
1163@fragment
1164fn fs_mono_sprite(input: MonoSpriteVarying) -> @location(0) vec4<f32> {
1165 let sample = textureSample(t_sprite, s_sprite, input.tile_position).r;
1166 let alpha_corrected = apply_contrast_and_gamma_correction(sample, input.color.rgb, grayscale_enhanced_contrast, gamma_ratios);
1167
1168 // Alpha clip after using the derivatives.
1169 if (any(input.clip_distances < vec4<f32>(0.0))) {
1170 return vec4<f32>(0.0);
1171 }
1172
1173 // convert to srgb space as the rest of the code (output swapchain) expects that
1174 return blend_color(input.color, alpha_corrected);
1175}
1176
1177// --- polychrome sprites --- //
1178
1179struct PolychromeSprite {
1180 order: u32,
1181 pad: u32,
1182 grayscale: u32,
1183 opacity: f32,
1184 bounds: Bounds,
1185 content_mask: Bounds,
1186 corner_radii: Corners,
1187 tile: AtlasTile,
1188}
1189var<storage, read> b_poly_sprites: array<PolychromeSprite>;
1190
1191struct PolySpriteVarying {
1192 @builtin(position) position: vec4<f32>,
1193 @location(0) tile_position: vec2<f32>,
1194 @location(1) @interpolate(flat) sprite_id: u32,
1195 @location(3) clip_distances: vec4<f32>,
1196}
1197
1198@vertex
1199fn vs_poly_sprite(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> PolySpriteVarying {
1200 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1201 let sprite = b_poly_sprites[instance_id];
1202
1203 var out = PolySpriteVarying();
1204 out.position = to_device_position(unit_vertex, sprite.bounds);
1205 out.tile_position = to_tile_position(unit_vertex, sprite.tile);
1206 out.sprite_id = instance_id;
1207 out.clip_distances = distance_from_clip_rect(unit_vertex, sprite.bounds, sprite.content_mask);
1208 return out;
1209}
1210
1211@fragment
1212fn fs_poly_sprite(input: PolySpriteVarying) -> @location(0) vec4<f32> {
1213 let sample = textureSample(t_sprite, s_sprite, input.tile_position);
1214 // Alpha clip after using the derivatives.
1215 if (any(input.clip_distances < vec4<f32>(0.0))) {
1216 return vec4<f32>(0.0);
1217 }
1218
1219 let sprite = b_poly_sprites[input.sprite_id];
1220 let distance = quad_sdf(input.position.xy, sprite.bounds, sprite.corner_radii);
1221
1222 var color = sample;
1223 if ((sprite.grayscale & 0xFFu) != 0u) {
1224 let grayscale = dot(color.rgb, GRAYSCALE_FACTORS);
1225 color = vec4<f32>(vec3<f32>(grayscale), sample.a);
1226 }
1227 return blend_color(color, sprite.opacity * saturate(0.5 - distance));
1228}
1229
1230// --- surfaces --- //
1231
1232struct SurfaceParams {
1233 bounds: Bounds,
1234 content_mask: Bounds,
1235}
1236
1237var<uniform> surface_locals: SurfaceParams;
1238var t_y: texture_2d<f32>;
1239var t_cb_cr: texture_2d<f32>;
1240var s_surface: sampler;
1241
1242const ycbcr_to_RGB = mat4x4<f32>(
1243 vec4<f32>( 1.0000f, 1.0000f, 1.0000f, 0.0),
1244 vec4<f32>( 0.0000f, -0.3441f, 1.7720f, 0.0),
1245 vec4<f32>( 1.4020f, -0.7141f, 0.0000f, 0.0),
1246 vec4<f32>(-0.7010f, 0.5291f, -0.8860f, 1.0),
1247);
1248
1249struct SurfaceVarying {
1250 @builtin(position) position: vec4<f32>,
1251 @location(0) texture_position: vec2<f32>,
1252 @location(3) clip_distances: vec4<f32>,
1253}
1254
1255@vertex
1256fn vs_surface(@builtin(vertex_index) vertex_id: u32) -> SurfaceVarying {
1257 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1258
1259 var out = SurfaceVarying();
1260 out.position = to_device_position(unit_vertex, surface_locals.bounds);
1261 out.texture_position = unit_vertex;
1262 out.clip_distances = distance_from_clip_rect(unit_vertex, surface_locals.bounds, surface_locals.content_mask);
1263 return out;
1264}
1265
1266@fragment
1267fn fs_surface(input: SurfaceVarying) -> @location(0) vec4<f32> {
1268 // Alpha clip after using the derivatives.
1269 if (any(input.clip_distances < vec4<f32>(0.0))) {
1270 return vec4<f32>(0.0);
1271 }
1272
1273 let y_cb_cr = vec4<f32>(
1274 textureSampleLevel(t_y, s_surface, input.texture_position, 0.0).r,
1275 textureSampleLevel(t_cb_cr, s_surface, input.texture_position, 0.0).rg,
1276 1.0);
1277
1278 return ycbcr_to_RGB * y_cb_cr;
1279}