1#include <metal_stdlib>
2#include "shaders.h"
3
4using namespace metal;
5
6float4 coloru_to_colorf(uchar4 coloru) {
7 return float4(coloru) / float4(0xff, 0xff, 0xff, 0xff);
8}
9
10float4 to_device_position(float2 pixel_position, float2 viewport_size) {
11 return float4(pixel_position / viewport_size * float2(2., -2.) + float2(-1., 1.), 0., 1.);
12}
13
14// A standard gaussian function, used for weighting samples
15float gaussian(float x, float sigma) {
16 return exp(-(x * x) / (2. * sigma * sigma)) / (sqrt(2. * M_PI_F) * sigma);
17}
18
19// This approximates the error function, needed for the gaussian integral
20float2 erf(float2 x) {
21 float2 s = sign(x);
22 float2 a = abs(x);
23 x = 1. + (0.278393 + (0.230389 + 0.078108 * (a * a)) * a) * a;
24 x *= x;
25 return s - s / (x * x);
26}
27
28float blur_along_x(float x, float y, float sigma, float corner, float2 halfSize) {
29 float delta = min(halfSize.y - corner - abs(y), 0.);
30 float curved = halfSize.x - corner + sqrt(max(0., corner * corner - delta * delta));
31 float2 integral = 0.5 + 0.5 * erf((x + float2(-curved, curved)) * (sqrt(0.5) / sigma));
32 return integral.y - integral.x;
33}
34
35struct QuadFragmentInput {
36 float4 position [[position]];
37 vector_float2 origin;
38 vector_float2 size;
39 vector_uchar4 background_color;
40 float border_top;
41 float border_right;
42 float border_bottom;
43 float border_left;
44 vector_uchar4 border_color;
45 float corner_radius;
46};
47
48vertex QuadFragmentInput quad_vertex(
49 uint unit_vertex_id [[vertex_id]],
50 uint quad_id [[instance_id]],
51 constant float2 *unit_vertices [[buffer(GPUIQuadInputIndexVertices)]],
52 constant GPUIQuad *quads [[buffer(GPUIQuadInputIndexQuads)]],
53 constant GPUIUniforms *uniforms [[buffer(GPUIQuadInputIndexUniforms)]]
54) {
55 float2 unit_vertex = unit_vertices[unit_vertex_id];
56 GPUIQuad quad = quads[quad_id];
57 float2 position = unit_vertex * quad.size + quad.origin;
58 float4 device_position = to_device_position(position, uniforms->viewport_size);
59
60 return QuadFragmentInput {
61 device_position,
62 quad.origin,
63 quad.size,
64 quad.background_color,
65 quad.border_top,
66 quad.border_right,
67 quad.border_bottom,
68 quad.border_left,
69 quad.border_color,
70 quad.corner_radius,
71 };
72}
73
74fragment float4 quad_fragment(
75 QuadFragmentInput input [[stage_in]]
76) {
77 float2 half_size = input.size / 2.;
78 float2 center = input.origin + half_size;
79 float2 center_to_point = input.position.xy - center;
80 float2 edge_to_point = abs(center_to_point) - half_size;
81 float2 rounded_edge_to_point = abs(center_to_point) - half_size + input.corner_radius;
82 float distance = length(max(0., rounded_edge_to_point)) + min(0., max(rounded_edge_to_point.x, rounded_edge_to_point.y)) - input.corner_radius;
83
84 float border_width = 0.;
85 if (edge_to_point.x > edge_to_point.y) {
86 border_width = center_to_point.x <= 0. ? input.border_left : input.border_right;
87 } else {
88 border_width = center_to_point.y <= 0. ? input.border_top : input.border_bottom;
89 }
90
91 float4 color;
92 if (border_width == 0.) {
93 color = coloru_to_colorf(input.background_color);
94 } else {
95 float inset_distance = distance + border_width;
96 color = mix(
97 coloru_to_colorf(input.border_color),
98 coloru_to_colorf(input.background_color),
99 saturate(0.5 - inset_distance)
100 );
101 }
102
103 float4 coverage = float4(1., 1., 1., saturate(0.5 - distance));
104 return coverage * color;
105}
106
107struct ShadowFragmentInput {
108 float4 position [[position]];
109 vector_float2 origin;
110 vector_float2 size;
111 float corner_radius;
112 float sigma;
113 vector_uchar4 color;
114};
115
116vertex ShadowFragmentInput shadow_vertex(
117 uint unit_vertex_id [[vertex_id]],
118 uint shadow_id [[instance_id]],
119 constant float2 *unit_vertices [[buffer(GPUIShadowInputIndexVertices)]],
120 constant GPUIShadow *shadows [[buffer(GPUIShadowInputIndexShadows)]],
121 constant GPUIUniforms *uniforms [[buffer(GPUIShadowInputIndexUniforms)]]
122) {
123 float2 unit_vertex = unit_vertices[unit_vertex_id];
124 GPUIShadow shadow = shadows[shadow_id];
125
126 float margin = 3. * shadow.sigma;
127 float2 position = unit_vertex * (shadow.size + 2. * margin) + shadow.origin - margin;
128 float4 device_position = to_device_position(position, uniforms->viewport_size);
129
130 return ShadowFragmentInput {
131 device_position,
132 shadow.origin,
133 shadow.size,
134 shadow.corner_radius,
135 shadow.sigma,
136 shadow.color,
137 };
138}
139
140fragment float4 shadow_fragment(
141 ShadowFragmentInput input [[stage_in]]
142) {
143 float sigma = input.sigma;
144 float corner_radius = input.corner_radius;
145 float2 half_size = input.size / 2.;
146 float2 center = input.origin + half_size;
147 float2 point = input.position.xy - center;
148
149 // The signal is only non-zero in a limited range, so don't waste samples
150 float low = point.y - half_size.y;
151 float high = point.y + half_size.y;
152 float start = clamp(-3. * sigma, low, high);
153 float end = clamp(3. * sigma, low, high);
154
155 // Accumulate samples (we can get away with surprisingly few samples)
156 float step = (end - start) / 4.;
157 float y = start + step * 0.5;
158 float alpha = 0.;
159 for (int i = 0; i < 4; i++) {
160 alpha += blur_along_x(point.x, point.y - y, sigma, corner_radius, half_size) * gaussian(y, sigma) * step;
161 y += step;
162 }
163
164 return float4(1., 1., 1., alpha) * coloru_to_colorf(input.color);
165}
166
167struct SpriteFragmentInput {
168 float4 position [[position]];
169 float2 atlas_position;
170 float4 color [[flat]];
171};
172
173vertex SpriteFragmentInput sprite_vertex(
174 uint unit_vertex_id [[vertex_id]],
175 uint sprite_id [[instance_id]],
176 constant float2 *unit_vertices [[buffer(GPUISpriteVertexInputIndexVertices)]],
177 constant GPUISprite *sprites [[buffer(GPUISpriteVertexInputIndexSprites)]],
178 constant float2 *viewport_size [[buffer(GPUISpriteVertexInputIndexViewportSize)]],
179 constant float2 *atlas_size [[buffer(GPUISpriteVertexInputIndexAtlasSize)]]
180) {
181 float2 unit_vertex = unit_vertices[unit_vertex_id];
182 GPUISprite sprite = sprites[sprite_id];
183 float2 position = unit_vertex * sprite.size + sprite.origin;
184 float4 device_position = to_device_position(position, *viewport_size);
185 float2 atlas_position = (unit_vertex * sprite.size + sprite.atlas_origin) / *atlas_size;
186
187 return SpriteFragmentInput {
188 device_position,
189 atlas_position,
190 coloru_to_colorf(sprite.color),
191 };
192}
193
194fragment float4 sprite_fragment(
195 SpriteFragmentInput input [[stage_in]],
196 texture2d<float> atlas [[ texture(GPUISpriteFragmentInputIndexAtlas) ]]
197) {
198 constexpr sampler atlas_sampler(mag_filter::linear, min_filter::linear);
199 float4 color = input.color;
200 float4 mask = atlas.sample(atlas_sampler, input.atlas_position);
201 color.a *= mask.a;
202 return color;
203}
204
205struct PathWindingFragmentInput {
206 float4 position [[position]];
207 float2 st_position;
208};
209
210vertex PathWindingFragmentInput path_winding_vertex(
211 uint vertex_id [[vertex_id]],
212 constant GPUIPathVertex *vertices [[buffer(GPUIPathWindingVertexInputIndexVertices)]],
213 constant float2 *viewport_size [[buffer(GPUIPathWindingVertexInputIndexViewportSize)]]
214) {
215 GPUIPathVertex v = vertices[vertex_id];
216 float4 device_position = to_device_position(v.xy_position, *viewport_size);
217 return PathWindingFragmentInput {
218 device_position,
219 v.st_position,
220 };
221}
222
223fragment float4 path_winding_fragment(
224 PathWindingFragmentInput input [[stage_in]]
225) {
226 if (input.st_position.x * input.st_position.x - input.st_position.y > 0.0) {
227 return float4(0.0);
228 } else {
229 return float4(float3(0.0), 1.0 / 255.0);
230 }
231}