1/* Functions useful for debugging:
2
3// A heat map color for debugging (blue -> cyan -> green -> yellow -> red).
4fn heat_map_color(value: f32, minValue: f32, maxValue: f32, position: vec2<f32>) -> vec4<f32> {
5 // Normalize value to 0-1 range
6 let t = clamp((value - minValue) / (maxValue - minValue), 0.0, 1.0);
7
8 // Heat map color calculation
9 let r = t * t;
10 let g = 4.0 * t * (1.0 - t);
11 let b = (1.0 - t) * (1.0 - t);
12 let heat_color = vec3<f32>(r, g, b);
13
14 // Create a checkerboard pattern (black and white)
15 let sum = floor(position.x / 3) + floor(position.y / 3);
16 let is_odd = fract(sum * 0.5); // 0.0 for even, 0.5 for odd
17 let checker_value = is_odd * 2.0; // 0.0 for even, 1.0 for odd
18 let checker_color = vec3<f32>(checker_value);
19
20 // Determine if value is in range (1.0 if in range, 0.0 if out of range)
21 let in_range = step(minValue, value) * step(value, maxValue);
22
23 // Mix checkerboard and heat map based on whether value is in range
24 let final_color = mix(checker_color, heat_color, in_range);
25
26 return vec4<f32>(final_color, 1.0);
27}
28
29*/
30
31fn color_brightness(color: vec3<f32>) -> f32 {
32 // REC. 601 luminance coefficients for perceived brightness
33 return dot(color, vec3<f32>(0.30, 0.59, 0.11));
34}
35
36fn light_on_dark_contrast(enhancedContrast: f32, color: vec3<f32>) -> f32 {
37 let brightness = color_brightness(color);
38 let multiplier = saturate(4.0 * (0.75 - brightness));
39 return enhancedContrast * multiplier;
40}
41
42fn enhance_contrast(alpha: f32, k: f32) -> f32 {
43 return alpha * (k + 1.0) / (alpha * k + 1.0);
44}
45
46fn apply_alpha_correction(a: f32, b: f32, g: vec4<f32>) -> f32 {
47 let brightness_adjustment = g.x * b + g.y;
48 let correction = brightness_adjustment * a + (g.z * b + g.w);
49 return a + a * (1.0 - a) * correction;
50}
51
52fn apply_contrast_and_gamma_correction(sample: f32, color: vec3<f32>, enhanced_contrast_factor: f32, gamma_ratios: vec4<f32>) -> f32 {
53 let enhanced_contrast = light_on_dark_contrast(enhanced_contrast_factor, color);
54 let brightness = color_brightness(color);
55
56 let contrasted = enhance_contrast(sample, enhanced_contrast);
57 return apply_alpha_correction(contrasted, brightness, gamma_ratios);
58}
59
60struct GlobalParams {
61 viewport_size: vec2<f32>,
62 premultiplied_alpha: u32,
63 pad: u32,
64}
65
66var<uniform> globals: GlobalParams;
67var<uniform> gamma_ratios: vec4<f32>;
68var<uniform> grayscale_enhanced_contrast: f32;
69var t_sprite: texture_2d<f32>;
70var s_sprite: sampler;
71
72const M_PI_F: f32 = 3.1415926;
73const GRAYSCALE_FACTORS: vec3<f32> = vec3<f32>(0.2126, 0.7152, 0.0722);
74
75struct Bounds {
76 origin: vec2<f32>,
77 size: vec2<f32>,
78}
79
80struct Corners {
81 top_left: f32,
82 top_right: f32,
83 bottom_right: f32,
84 bottom_left: f32,
85}
86
87struct Edges {
88 top: f32,
89 right: f32,
90 bottom: f32,
91 left: f32,
92}
93
94struct Hsla {
95 h: f32,
96 s: f32,
97 l: f32,
98 a: f32,
99}
100
101struct LinearColorStop {
102 color: Hsla,
103 percentage: f32,
104}
105
106struct Background {
107 // 0u is Solid
108 // 1u is LinearGradient
109 // 2u is PatternSlash
110 tag: u32,
111 // 0u is sRGB linear color
112 // 1u is Oklab color
113 color_space: u32,
114 solid: Hsla,
115 gradient_angle_or_pattern_height: f32,
116 colors: array<LinearColorStop, 2>,
117 pad: u32,
118}
119
120struct AtlasTextureId {
121 index: u32,
122 kind: u32,
123}
124
125struct AtlasBounds {
126 origin: vec2<i32>,
127 size: vec2<i32>,
128}
129
130struct AtlasTile {
131 texture_id: AtlasTextureId,
132 tile_id: u32,
133 padding: u32,
134 bounds: AtlasBounds,
135}
136
137struct TransformationMatrix {
138 rotation_scale: mat2x2<f32>,
139 translation: vec2<f32>,
140}
141
142fn to_device_position_impl(position: vec2<f32>) -> vec4<f32> {
143 let device_position = position / globals.viewport_size * vec2<f32>(2.0, -2.0) + vec2<f32>(-1.0, 1.0);
144 return vec4<f32>(device_position, 0.0, 1.0);
145}
146
147fn to_device_position(unit_vertex: vec2<f32>, bounds: Bounds) -> vec4<f32> {
148 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
149 return to_device_position_impl(position);
150}
151
152fn to_device_position_transformed(unit_vertex: vec2<f32>, bounds: Bounds, transform: TransformationMatrix) -> vec4<f32> {
153 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
154 //Note: Rust side stores it as row-major, so transposing here
155 let transformed = transpose(transform.rotation_scale) * position + transform.translation;
156 return to_device_position_impl(transformed);
157}
158
159fn to_tile_position(unit_vertex: vec2<f32>, tile: AtlasTile) -> vec2<f32> {
160 let atlas_size = vec2<f32>(textureDimensions(t_sprite, 0));
161 return (vec2<f32>(tile.bounds.origin) + unit_vertex * vec2<f32>(tile.bounds.size)) / atlas_size;
162}
163
164fn distance_from_clip_rect_impl(position: vec2<f32>, clip_bounds: Bounds) -> vec4<f32> {
165 let tl = position - clip_bounds.origin;
166 let br = clip_bounds.origin + clip_bounds.size - position;
167 return vec4<f32>(tl.x, br.x, tl.y, br.y);
168}
169
170fn distance_from_clip_rect(unit_vertex: vec2<f32>, bounds: Bounds, clip_bounds: Bounds) -> vec4<f32> {
171 let position = unit_vertex * vec2<f32>(bounds.size) + bounds.origin;
172 return distance_from_clip_rect_impl(position, clip_bounds);
173}
174
175// https://gamedev.stackexchange.com/questions/92015/optimized-linear-to-srgb-glsl
176fn srgb_to_linear(srgb: vec3<f32>) -> vec3<f32> {
177 let cutoff = srgb < vec3<f32>(0.04045);
178 let higher = pow((srgb + vec3<f32>(0.055)) / vec3<f32>(1.055), vec3<f32>(2.4));
179 let lower = srgb / vec3<f32>(12.92);
180 return select(higher, lower, cutoff);
181}
182
183fn srgb_to_linear_component(a: f32) -> f32 {
184 let cutoff = a < 0.04045;
185 let higher = pow((a + 0.055) / 1.055, 2.4);
186 let lower = a / 12.92;
187 return select(higher, lower, cutoff);
188}
189
190fn linear_to_srgb(linear: vec3<f32>) -> vec3<f32> {
191 let cutoff = linear < vec3<f32>(0.0031308);
192 let higher = vec3<f32>(1.055) * pow(linear, vec3<f32>(1.0 / 2.4)) - vec3<f32>(0.055);
193 let lower = linear * vec3<f32>(12.92);
194 return select(higher, lower, cutoff);
195}
196
197/// Convert a linear color to sRGBA space.
198fn linear_to_srgba(color: vec4<f32>) -> vec4<f32> {
199 return vec4<f32>(linear_to_srgb(color.rgb), color.a);
200}
201
202/// Convert a sRGBA color to linear space.
203fn srgba_to_linear(color: vec4<f32>) -> vec4<f32> {
204 return vec4<f32>(srgb_to_linear(color.rgb), color.a);
205}
206
207/// Hsla to linear RGBA conversion.
208fn hsla_to_rgba(hsla: Hsla) -> vec4<f32> {
209 let h = hsla.h * 6.0; // Now, it's an angle but scaled in [0, 6) range
210 let s = hsla.s;
211 let l = hsla.l;
212 let a = hsla.a;
213
214 let c = (1.0 - abs(2.0 * l - 1.0)) * s;
215 let x = c * (1.0 - abs(h % 2.0 - 1.0));
216 let m = l - c / 2.0;
217 var color = vec3<f32>(m);
218
219 if (h >= 0.0 && h < 1.0) {
220 color.r += c;
221 color.g += x;
222 } else if (h >= 1.0 && h < 2.0) {
223 color.r += x;
224 color.g += c;
225 } else if (h >= 2.0 && h < 3.0) {
226 color.g += c;
227 color.b += x;
228 } else if (h >= 3.0 && h < 4.0) {
229 color.g += x;
230 color.b += c;
231 } else if (h >= 4.0 && h < 5.0) {
232 color.r += x;
233 color.b += c;
234 } else {
235 color.r += c;
236 color.b += x;
237 }
238
239 return vec4<f32>(color, a);
240}
241
242/// Convert a linear sRGB to Oklab space.
243/// Reference: https://bottosson.github.io/posts/oklab/#converting-from-linear-srgb-to-oklab
244fn linear_srgb_to_oklab(color: vec4<f32>) -> vec4<f32> {
245 let l = 0.4122214708 * color.r + 0.5363325363 * color.g + 0.0514459929 * color.b;
246 let m = 0.2119034982 * color.r + 0.6806995451 * color.g + 0.1073969566 * color.b;
247 let s = 0.0883024619 * color.r + 0.2817188376 * color.g + 0.6299787005 * color.b;
248
249 let l_ = pow(l, 1.0 / 3.0);
250 let m_ = pow(m, 1.0 / 3.0);
251 let s_ = pow(s, 1.0 / 3.0);
252
253 return vec4<f32>(
254 0.2104542553 * l_ + 0.7936177850 * m_ - 0.0040720468 * s_,
255 1.9779984951 * l_ - 2.4285922050 * m_ + 0.4505937099 * s_,
256 0.0259040371 * l_ + 0.7827717662 * m_ - 0.8086757660 * s_,
257 color.a
258 );
259}
260
261/// Convert an Oklab color to linear sRGB space.
262fn oklab_to_linear_srgb(color: vec4<f32>) -> vec4<f32> {
263 let l_ = color.r + 0.3963377774 * color.g + 0.2158037573 * color.b;
264 let m_ = color.r - 0.1055613458 * color.g - 0.0638541728 * color.b;
265 let s_ = color.r - 0.0894841775 * color.g - 1.2914855480 * color.b;
266
267 let l = l_ * l_ * l_;
268 let m = m_ * m_ * m_;
269 let s = s_ * s_ * s_;
270
271 return vec4<f32>(
272 4.0767416621 * l - 3.3077115913 * m + 0.2309699292 * s,
273 -1.2684380046 * l + 2.6097574011 * m - 0.3413193965 * s,
274 -0.0041960863 * l - 0.7034186147 * m + 1.7076147010 * s,
275 color.a
276 );
277}
278
279fn over(below: vec4<f32>, above: vec4<f32>) -> vec4<f32> {
280 let alpha = above.a + below.a * (1.0 - above.a);
281 let color = (above.rgb * above.a + below.rgb * below.a * (1.0 - above.a)) / alpha;
282 return vec4<f32>(color, alpha);
283}
284
285// A standard gaussian function, used for weighting samples
286fn gaussian(x: f32, sigma: f32) -> f32{
287 return exp(-(x * x) / (2.0 * sigma * sigma)) / (sqrt(2.0 * M_PI_F) * sigma);
288}
289
290// This approximates the error function, needed for the gaussian integral
291fn erf(v: vec2<f32>) -> vec2<f32> {
292 let s = sign(v);
293 let a = abs(v);
294 let r1 = 1.0 + (0.278393 + (0.230389 + (0.000972 + 0.078108 * a) * a) * a) * a;
295 let r2 = r1 * r1;
296 return s - s / (r2 * r2);
297}
298
299fn blur_along_x(x: f32, y: f32, sigma: f32, corner: f32, half_size: vec2<f32>) -> f32 {
300 let delta = min(half_size.y - corner - abs(y), 0.0);
301 let curved = half_size.x - corner + sqrt(max(0.0, corner * corner - delta * delta));
302 let integral = 0.5 + 0.5 * erf((x + vec2<f32>(-curved, curved)) * (sqrt(0.5) / sigma));
303 return integral.y - integral.x;
304}
305
306// Selects corner radius based on quadrant.
307fn pick_corner_radius(center_to_point: vec2<f32>, radii: Corners) -> f32 {
308 if (center_to_point.x < 0.0) {
309 if (center_to_point.y < 0.0) {
310 return radii.top_left;
311 } else {
312 return radii.bottom_left;
313 }
314 } else {
315 if (center_to_point.y < 0.0) {
316 return radii.top_right;
317 } else {
318 return radii.bottom_right;
319 }
320 }
321}
322
323// Signed distance of the point to the quad's border - positive outside the
324// border, and negative inside.
325//
326// See comments on similar code using `quad_sdf_impl` in `fs_quad` for
327// explanation.
328fn quad_sdf(point: vec2<f32>, bounds: Bounds, corner_radii: Corners) -> f32 {
329 let half_size = bounds.size / 2.0;
330 let center = bounds.origin + half_size;
331 let center_to_point = point - center;
332 let corner_radius = pick_corner_radius(center_to_point, corner_radii);
333 let corner_to_point = abs(center_to_point) - half_size;
334 let corner_center_to_point = corner_to_point + corner_radius;
335 return quad_sdf_impl(corner_center_to_point, corner_radius);
336}
337
338fn quad_sdf_impl(corner_center_to_point: vec2<f32>, corner_radius: f32) -> f32 {
339 if (corner_radius == 0.0) {
340 // Fast path for unrounded corners.
341 return max(corner_center_to_point.x, corner_center_to_point.y);
342 } else {
343 // Signed distance of the point from a quad that is inset by corner_radius.
344 // It is negative inside this quad, and positive outside.
345 let signed_distance_to_inset_quad =
346 // 0 inside the inset quad, and positive outside.
347 length(max(vec2<f32>(0.0), corner_center_to_point)) +
348 // 0 outside the inset quad, and negative inside.
349 min(0.0, max(corner_center_to_point.x, corner_center_to_point.y));
350
351 return signed_distance_to_inset_quad - corner_radius;
352 }
353}
354
355// Abstract away the final color transformation based on the
356// target alpha compositing mode.
357fn blend_color(color: vec4<f32>, alpha_factor: f32) -> vec4<f32> {
358 let alpha = color.a * alpha_factor;
359 let multiplier = select(1.0, alpha, globals.premultiplied_alpha != 0u);
360 return vec4<f32>(color.rgb * multiplier, alpha);
361}
362
363
364struct GradientColor {
365 solid: vec4<f32>,
366 color0: vec4<f32>,
367 color1: vec4<f32>,
368}
369
370fn prepare_gradient_color(tag: u32, color_space: u32,
371 solid: Hsla, colors: array<LinearColorStop, 2>) -> GradientColor {
372 var result = GradientColor();
373
374 if (tag == 0u || tag == 2u) {
375 result.solid = hsla_to_rgba(solid);
376 } else if (tag == 1u) {
377 // The hsla_to_rgba is returns a linear sRGB color
378 result.color0 = hsla_to_rgba(colors[0].color);
379 result.color1 = hsla_to_rgba(colors[1].color);
380
381 // Prepare color space in vertex for avoid conversion
382 // in fragment shader for performance reasons
383 if (color_space == 0u) {
384 // sRGB
385 result.color0 = linear_to_srgba(result.color0);
386 result.color1 = linear_to_srgba(result.color1);
387 } else if (color_space == 1u) {
388 // Oklab
389 result.color0 = linear_srgb_to_oklab(result.color0);
390 result.color1 = linear_srgb_to_oklab(result.color1);
391 }
392 }
393
394 return result;
395}
396
397fn gradient_color(background: Background, position: vec2<f32>, bounds: Bounds,
398 solid_color: vec4<f32>, color0: vec4<f32>, color1: vec4<f32>) -> vec4<f32> {
399 var background_color = vec4<f32>(0.0);
400
401 switch (background.tag) {
402 default: {
403 return solid_color;
404 }
405 case 1u: {
406 // Linear gradient background.
407 // -90 degrees to match the CSS gradient angle.
408 let angle = background.gradient_angle_or_pattern_height;
409 let radians = (angle % 360.0 - 90.0) * M_PI_F / 180.0;
410 var direction = vec2<f32>(cos(radians), sin(radians));
411 let stop0_percentage = background.colors[0].percentage;
412 let stop1_percentage = background.colors[1].percentage;
413
414 // Expand the short side to be the same as the long side
415 if (bounds.size.x > bounds.size.y) {
416 direction.y *= bounds.size.y / bounds.size.x;
417 } else {
418 direction.x *= bounds.size.x / bounds.size.y;
419 }
420
421 // Get the t value for the linear gradient with the color stop percentages.
422 let half_size = bounds.size / 2.0;
423 let center = bounds.origin + half_size;
424 let center_to_point = position - center;
425 var t = dot(center_to_point, direction) / length(direction);
426 // Check the direct to determine the use x or y
427 if (abs(direction.x) > abs(direction.y)) {
428 t = (t + half_size.x) / bounds.size.x;
429 } else {
430 t = (t + half_size.y) / bounds.size.y;
431 }
432
433 // Adjust t based on the stop percentages
434 t = (t - stop0_percentage) / (stop1_percentage - stop0_percentage);
435 t = clamp(t, 0.0, 1.0);
436
437 switch (background.color_space) {
438 default: {
439 background_color = srgba_to_linear(mix(color0, color1, t));
440 }
441 case 1u: {
442 let oklab_color = mix(color0, color1, t);
443 background_color = oklab_to_linear_srgb(oklab_color);
444 }
445 }
446 }
447 case 2u: {
448 let gradient_angle_or_pattern_height = background.gradient_angle_or_pattern_height;
449 let pattern_width = (gradient_angle_or_pattern_height / 65535.0f) / 255.0f;
450 let pattern_interval = (gradient_angle_or_pattern_height % 65535.0f) / 255.0f;
451 let pattern_height = pattern_width + pattern_interval;
452 let stripe_angle = M_PI_F / 4.0;
453 let pattern_period = pattern_height * sin(stripe_angle);
454 let rotation = mat2x2<f32>(
455 cos(stripe_angle), -sin(stripe_angle),
456 sin(stripe_angle), cos(stripe_angle)
457 );
458 let relative_position = position - bounds.origin;
459 let rotated_point = rotation * relative_position;
460 let pattern = rotated_point.x % pattern_period;
461 let distance = min(pattern, pattern_period - pattern) - pattern_period * (pattern_width / pattern_height) / 2.0f;
462 background_color = solid_color;
463 background_color.a *= saturate(0.5 - distance);
464 }
465 }
466
467 return background_color;
468}
469
470// --- quads --- //
471
472struct Quad {
473 order: u32,
474 border_style: u32,
475 bounds: Bounds,
476 content_mask: Bounds,
477 background: Background,
478 border_color: Hsla,
479 corner_radii: Corners,
480 border_widths: Edges,
481}
482var<storage, read> b_quads: array<Quad>;
483
484struct QuadVarying {
485 @builtin(position) position: vec4<f32>,
486 @location(0) @interpolate(flat) border_color: vec4<f32>,
487 @location(1) @interpolate(flat) quad_id: u32,
488 // TODO: use `clip_distance` once Naga supports it
489 @location(2) clip_distances: vec4<f32>,
490 @location(3) @interpolate(flat) background_solid: vec4<f32>,
491 @location(4) @interpolate(flat) background_color0: vec4<f32>,
492 @location(5) @interpolate(flat) background_color1: vec4<f32>,
493}
494
495@vertex
496fn vs_quad(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> QuadVarying {
497 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
498 let quad = b_quads[instance_id];
499
500 var out = QuadVarying();
501 out.position = to_device_position(unit_vertex, quad.bounds);
502
503 let gradient = prepare_gradient_color(
504 quad.background.tag,
505 quad.background.color_space,
506 quad.background.solid,
507 quad.background.colors
508 );
509 out.background_solid = gradient.solid;
510 out.background_color0 = gradient.color0;
511 out.background_color1 = gradient.color1;
512 out.border_color = hsla_to_rgba(quad.border_color);
513 out.quad_id = instance_id;
514 out.clip_distances = distance_from_clip_rect(unit_vertex, quad.bounds, quad.content_mask);
515 return out;
516}
517
518@fragment
519fn fs_quad(input: QuadVarying) -> @location(0) vec4<f32> {
520 // Alpha clip first, since we don't have `clip_distance`.
521 if (any(input.clip_distances < vec4<f32>(0.0))) {
522 return vec4<f32>(0.0);
523 }
524
525 let quad = b_quads[input.quad_id];
526
527 let background_color = gradient_color(quad.background, input.position.xy, quad.bounds,
528 input.background_solid, input.background_color0, input.background_color1);
529
530 let unrounded = quad.corner_radii.top_left == 0.0 &&
531 quad.corner_radii.bottom_left == 0.0 &&
532 quad.corner_radii.top_right == 0.0 &&
533 quad.corner_radii.bottom_right == 0.0;
534
535 // Fast path when the quad is not rounded and doesn't have any border
536 if (quad.border_widths.top == 0.0 &&
537 quad.border_widths.left == 0.0 &&
538 quad.border_widths.right == 0.0 &&
539 quad.border_widths.bottom == 0.0 &&
540 unrounded) {
541 return blend_color(background_color, 1.0);
542 }
543
544 let size = quad.bounds.size;
545 let half_size = size / 2.0;
546 let point = input.position.xy - quad.bounds.origin;
547 let center_to_point = point - half_size;
548
549 // Signed distance field threshold for inclusion of pixels. 0.5 is the
550 // minimum distance between the center of the pixel and the edge.
551 let antialias_threshold = 0.5;
552
553 // Radius of the nearest corner
554 let corner_radius = pick_corner_radius(center_to_point, quad.corner_radii);
555
556 // Width of the nearest borders
557 let border = vec2<f32>(
558 select(
559 quad.border_widths.right,
560 quad.border_widths.left,
561 center_to_point.x < 0.0),
562 select(
563 quad.border_widths.bottom,
564 quad.border_widths.top,
565 center_to_point.y < 0.0));
566
567 // 0-width borders are reduced so that `inner_sdf >= antialias_threshold`.
568 // The purpose of this is to not draw antialiasing pixels in this case.
569 let reduced_border =
570 vec2<f32>(select(border.x, -antialias_threshold, border.x == 0.0),
571 select(border.y, -antialias_threshold, border.y == 0.0));
572
573 // Vector from the corner of the quad bounds to the point, after mirroring
574 // the point into the bottom right quadrant. Both components are <= 0.
575 let corner_to_point = abs(center_to_point) - half_size;
576
577 // Vector from the point to the center of the rounded corner's circle, also
578 // mirrored into bottom right quadrant.
579 let corner_center_to_point = corner_to_point + corner_radius;
580
581 // Whether the nearest point on the border is rounded
582 let is_near_rounded_corner =
583 corner_center_to_point.x >= 0 &&
584 corner_center_to_point.y >= 0;
585
586 // Vector from straight border inner corner to point.
587 let straight_border_inner_corner_to_point = corner_to_point + reduced_border;
588
589 // Whether the point is beyond the inner edge of the straight border.
590 let is_beyond_inner_straight_border =
591 straight_border_inner_corner_to_point.x > 0 ||
592 straight_border_inner_corner_to_point.y > 0;
593
594 // Whether the point is far enough inside the quad, such that the pixels are
595 // not affected by the straight border.
596 let is_within_inner_straight_border =
597 straight_border_inner_corner_to_point.x < -antialias_threshold &&
598 straight_border_inner_corner_to_point.y < -antialias_threshold;
599
600 // Fast path for points that must be part of the background.
601 //
602 // This could be optimized further for large rounded corners by including
603 // points in an inscribed rectangle, or some other quick linear check.
604 // However, that might negatively impact performance in the case of
605 // reasonable sizes for rounded corners.
606 if (is_within_inner_straight_border && !is_near_rounded_corner) {
607 return blend_color(background_color, 1.0);
608 }
609
610 // Signed distance of the point to the outside edge of the quad's border. It
611 // is positive outside this edge, and negative inside.
612 let outer_sdf = quad_sdf_impl(corner_center_to_point, corner_radius);
613
614 // Approximate signed distance of the point to the inside edge of the quad's
615 // border. It is negative outside this edge (within the border), and
616 // positive inside.
617 //
618 // This is not always an accurate signed distance:
619 // * The rounded portions with varying border width use an approximation of
620 // nearest-point-on-ellipse.
621 // * When it is quickly known to be outside the edge, -1.0 is used.
622 var inner_sdf = 0.0;
623 if (corner_center_to_point.x <= 0 || corner_center_to_point.y <= 0) {
624 // Fast paths for straight borders.
625 inner_sdf = -max(straight_border_inner_corner_to_point.x,
626 straight_border_inner_corner_to_point.y);
627 } else if (is_beyond_inner_straight_border) {
628 // Fast path for points that must be outside the inner edge.
629 inner_sdf = -1.0;
630 } else if (reduced_border.x == reduced_border.y) {
631 // Fast path for circular inner edge.
632 inner_sdf = -(outer_sdf + reduced_border.x);
633 } else {
634 let ellipse_radii = max(vec2<f32>(0.0), corner_radius - reduced_border);
635 inner_sdf = quarter_ellipse_sdf(corner_center_to_point, ellipse_radii);
636 }
637
638 // Negative when inside the border
639 let border_sdf = max(inner_sdf, outer_sdf);
640
641 var color = background_color;
642 if (border_sdf < antialias_threshold) {
643 var border_color = input.border_color;
644
645 // Dashed border logic when border_style == 1
646 if (quad.border_style == 1) {
647 // Position along the perimeter in "dash space", where each dash
648 // period has length 1
649 var t = 0.0;
650
651 // Total number of dash periods, so that the dash spacing can be
652 // adjusted to evenly divide it
653 var max_t = 0.0;
654
655 // Border width is proportional to dash size. This is the behavior
656 // used by browsers, but also avoids dashes from different segments
657 // overlapping when dash size is smaller than the border width.
658 //
659 // Dash pattern: (2 * border width) dash, (1 * border width) gap
660 let dash_length_per_width = 2.0;
661 let dash_gap_per_width = 1.0;
662 let dash_period_per_width = dash_length_per_width + dash_gap_per_width;
663
664 // Since the dash size is determined by border width, the density of
665 // dashes varies. Multiplying a pixel distance by this returns a
666 // position in dash space - it has units (dash period / pixels). So
667 // a dash velocity of (1 / 10) is 1 dash every 10 pixels.
668 var dash_velocity = 0.0;
669
670 // Dividing this by the border width gives the dash velocity
671 let dv_numerator = 1.0 / dash_period_per_width;
672
673 if (unrounded) {
674 // When corners aren't rounded, the dashes are separately laid
675 // out on each straight line, rather than around the whole
676 // perimeter. This way each line starts and ends with a dash.
677 let is_horizontal =
678 corner_center_to_point.x <
679 corner_center_to_point.y;
680 let border_width = select(border.y, border.x, is_horizontal);
681 dash_velocity = dv_numerator / border_width;
682 t = select(point.y, point.x, is_horizontal) * dash_velocity;
683 max_t = select(size.y, size.x, is_horizontal) * dash_velocity;
684 } else {
685 // When corners are rounded, the dashes are laid out clockwise
686 // around the whole perimeter.
687
688 let r_tr = quad.corner_radii.top_right;
689 let r_br = quad.corner_radii.bottom_right;
690 let r_bl = quad.corner_radii.bottom_left;
691 let r_tl = quad.corner_radii.top_left;
692
693 let w_t = quad.border_widths.top;
694 let w_r = quad.border_widths.right;
695 let w_b = quad.border_widths.bottom;
696 let w_l = quad.border_widths.left;
697
698 // Straight side dash velocities
699 let dv_t = select(dv_numerator / w_t, 0.0, w_t <= 0.0);
700 let dv_r = select(dv_numerator / w_r, 0.0, w_r <= 0.0);
701 let dv_b = select(dv_numerator / w_b, 0.0, w_b <= 0.0);
702 let dv_l = select(dv_numerator / w_l, 0.0, w_l <= 0.0);
703
704 // Straight side lengths in dash space
705 let s_t = (size.x - r_tl - r_tr) * dv_t;
706 let s_r = (size.y - r_tr - r_br) * dv_r;
707 let s_b = (size.x - r_br - r_bl) * dv_b;
708 let s_l = (size.y - r_bl - r_tl) * dv_l;
709
710 let corner_dash_velocity_tr = corner_dash_velocity(dv_t, dv_r);
711 let corner_dash_velocity_br = corner_dash_velocity(dv_b, dv_r);
712 let corner_dash_velocity_bl = corner_dash_velocity(dv_b, dv_l);
713 let corner_dash_velocity_tl = corner_dash_velocity(dv_t, dv_l);
714
715 // Corner lengths in dash space
716 let c_tr = r_tr * (M_PI_F / 2.0) * corner_dash_velocity_tr;
717 let c_br = r_br * (M_PI_F / 2.0) * corner_dash_velocity_br;
718 let c_bl = r_bl * (M_PI_F / 2.0) * corner_dash_velocity_bl;
719 let c_tl = r_tl * (M_PI_F / 2.0) * corner_dash_velocity_tl;
720
721 // Cumulative dash space upto each segment
722 let upto_tr = s_t;
723 let upto_r = upto_tr + c_tr;
724 let upto_br = upto_r + s_r;
725 let upto_b = upto_br + c_br;
726 let upto_bl = upto_b + s_b;
727 let upto_l = upto_bl + c_bl;
728 let upto_tl = upto_l + s_l;
729 max_t = upto_tl + c_tl;
730
731 if (is_near_rounded_corner) {
732 let radians = atan2(corner_center_to_point.y,
733 corner_center_to_point.x);
734 let corner_t = radians * corner_radius;
735
736 if (center_to_point.x >= 0.0) {
737 if (center_to_point.y < 0.0) {
738 dash_velocity = corner_dash_velocity_tr;
739 // Subtracted because radians is pi/2 to 0 when
740 // going clockwise around the top right corner,
741 // since the y axis has been flipped
742 t = upto_r - corner_t * dash_velocity;
743 } else {
744 dash_velocity = corner_dash_velocity_br;
745 // Added because radians is 0 to pi/2 when going
746 // clockwise around the bottom-right corner
747 t = upto_br + corner_t * dash_velocity;
748 }
749 } else {
750 if (center_to_point.y >= 0.0) {
751 dash_velocity = corner_dash_velocity_bl;
752 // Subtracted because radians is pi/2 to 0 when
753 // going clockwise around the bottom-left corner,
754 // since the x axis has been flipped
755 t = upto_l - corner_t * dash_velocity;
756 } else {
757 dash_velocity = corner_dash_velocity_tl;
758 // Added because radians is 0 to pi/2 when going
759 // clockwise around the top-left corner, since both
760 // axis were flipped
761 t = upto_tl + corner_t * dash_velocity;
762 }
763 }
764 } else {
765 // Straight borders
766 let is_horizontal =
767 corner_center_to_point.x <
768 corner_center_to_point.y;
769 if (is_horizontal) {
770 if (center_to_point.y < 0.0) {
771 dash_velocity = dv_t;
772 t = (point.x - r_tl) * dash_velocity;
773 } else {
774 dash_velocity = dv_b;
775 t = upto_bl - (point.x - r_bl) * dash_velocity;
776 }
777 } else {
778 if (center_to_point.x < 0.0) {
779 dash_velocity = dv_l;
780 t = upto_tl - (point.y - r_tl) * dash_velocity;
781 } else {
782 dash_velocity = dv_r;
783 t = upto_r + (point.y - r_tr) * dash_velocity;
784 }
785 }
786 }
787 }
788
789 let dash_length = dash_length_per_width / dash_period_per_width;
790 let desired_dash_gap = dash_gap_per_width / dash_period_per_width;
791
792 // Straight borders should start and end with a dash, so max_t is
793 // reduced to cause this.
794 max_t -= select(0.0, dash_length, unrounded);
795 if (max_t >= 1.0) {
796 // Adjust dash gap to evenly divide max_t.
797 let dash_count = floor(max_t);
798 let dash_period = max_t / dash_count;
799 border_color.a *= dash_alpha(
800 t,
801 dash_period,
802 dash_length,
803 dash_velocity,
804 antialias_threshold);
805 } else if (unrounded) {
806 // When there isn't enough space for the full gap between the
807 // two start / end dashes of a straight border, reduce gap to
808 // make them fit.
809 let dash_gap = max_t - dash_length;
810 if (dash_gap > 0.0) {
811 let dash_period = dash_length + dash_gap;
812 border_color.a *= dash_alpha(
813 t,
814 dash_period,
815 dash_length,
816 dash_velocity,
817 antialias_threshold);
818 }
819 }
820 }
821
822 // Blend the border on top of the background and then linearly interpolate
823 // between the two as we slide inside the background.
824 let blended_border = over(background_color, border_color);
825 color = mix(background_color, blended_border,
826 saturate(antialias_threshold - inner_sdf));
827 }
828
829 return blend_color(color, saturate(antialias_threshold - outer_sdf));
830}
831
832// Returns the dash velocity of a corner given the dash velocity of the two
833// sides, by returning the slower velocity (larger dashes).
834//
835// Since 0 is used for dash velocity when the border width is 0 (instead of
836// +inf), this returns the other dash velocity in that case.
837//
838// An alternative to this might be to appropriately interpolate the dash
839// velocity around the corner, but that seems overcomplicated.
840fn corner_dash_velocity(dv1: f32, dv2: f32) -> f32 {
841 if (dv1 == 0.0) {
842 return dv2;
843 } else if (dv2 == 0.0) {
844 return dv1;
845 } else {
846 return min(dv1, dv2);
847 }
848}
849
850// Returns alpha used to render antialiased dashes.
851// `t` is within the dash when `fmod(t, period) < length`.
852fn dash_alpha(t: f32, period: f32, length: f32, dash_velocity: f32, antialias_threshold: f32) -> f32 {
853 let half_period = period / 2;
854 let half_length = length / 2;
855 // Value in [-half_period, half_period].
856 // The dash is in [-half_length, half_length].
857 let centered = fmod(t + half_period - half_length, period) - half_period;
858 // Signed distance for the dash, negative values are inside the dash.
859 let signed_distance = abs(centered) - half_length;
860 // Antialiased alpha based on the signed distance.
861 return saturate(antialias_threshold - signed_distance / dash_velocity);
862}
863
864// This approximates distance to the nearest point to a quarter ellipse in a way
865// that is sufficient for anti-aliasing when the ellipse is not very eccentric.
866// The components of `point` are expected to be positive.
867//
868// Negative on the outside and positive on the inside.
869fn quarter_ellipse_sdf(point: vec2<f32>, radii: vec2<f32>) -> f32 {
870 // Scale the space to treat the ellipse like a unit circle.
871 let circle_vec = point / radii;
872 let unit_circle_sdf = length(circle_vec) - 1.0;
873 // Approximate up-scaling of the length by using the average of the radii.
874 //
875 // TODO: A better solution would be to use the gradient of the implicit
876 // function for an ellipse to approximate a scaling factor.
877 return unit_circle_sdf * (radii.x + radii.y) * -0.5;
878}
879
880// Modulus that has the same sign as `a`.
881fn fmod(a: f32, b: f32) -> f32 {
882 return a - b * trunc(a / b);
883}
884
885// --- shadows --- //
886
887struct Shadow {
888 order: u32,
889 blur_radius: f32,
890 bounds: Bounds,
891 corner_radii: Corners,
892 content_mask: Bounds,
893 color: Hsla,
894}
895var<storage, read> b_shadows: array<Shadow>;
896
897struct ShadowVarying {
898 @builtin(position) position: vec4<f32>,
899 @location(0) @interpolate(flat) color: vec4<f32>,
900 @location(1) @interpolate(flat) shadow_id: u32,
901 //TODO: use `clip_distance` once Naga supports it
902 @location(3) clip_distances: vec4<f32>,
903}
904
905@vertex
906fn vs_shadow(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> ShadowVarying {
907 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
908 var shadow = b_shadows[instance_id];
909
910 let margin = 3.0 * shadow.blur_radius;
911 // Set the bounds of the shadow and adjust its size based on the shadow's
912 // spread radius to achieve the spreading effect
913 shadow.bounds.origin -= vec2<f32>(margin);
914 shadow.bounds.size += 2.0 * vec2<f32>(margin);
915
916 var out = ShadowVarying();
917 out.position = to_device_position(unit_vertex, shadow.bounds);
918 out.color = hsla_to_rgba(shadow.color);
919 out.shadow_id = instance_id;
920 out.clip_distances = distance_from_clip_rect(unit_vertex, shadow.bounds, shadow.content_mask);
921 return out;
922}
923
924@fragment
925fn fs_shadow(input: ShadowVarying) -> @location(0) vec4<f32> {
926 // Alpha clip first, since we don't have `clip_distance`.
927 if (any(input.clip_distances < vec4<f32>(0.0))) {
928 return vec4<f32>(0.0);
929 }
930
931 let shadow = b_shadows[input.shadow_id];
932 let half_size = shadow.bounds.size / 2.0;
933 let center = shadow.bounds.origin + half_size;
934 let center_to_point = input.position.xy - center;
935
936 let corner_radius = pick_corner_radius(center_to_point, shadow.corner_radii);
937
938 // The signal is only non-zero in a limited range, so don't waste samples
939 let low = center_to_point.y - half_size.y;
940 let high = center_to_point.y + half_size.y;
941 let start = clamp(-3.0 * shadow.blur_radius, low, high);
942 let end = clamp(3.0 * shadow.blur_radius, low, high);
943
944 // Accumulate samples (we can get away with surprisingly few samples)
945 let step = (end - start) / 4.0;
946 var y = start + step * 0.5;
947 var alpha = 0.0;
948 for (var i = 0; i < 4; i += 1) {
949 let blur = blur_along_x(center_to_point.x, center_to_point.y - y,
950 shadow.blur_radius, corner_radius, half_size);
951 alpha += blur * gaussian(y, shadow.blur_radius) * step;
952 y += step;
953 }
954
955 return blend_color(input.color, alpha);
956}
957
958// --- path rasterization --- //
959
960struct PathRasterizationVertex {
961 xy_position: vec2<f32>,
962 st_position: vec2<f32>,
963 color: Background,
964 bounds: Bounds,
965}
966
967var<storage, read> b_path_vertices: array<PathRasterizationVertex>;
968
969struct PathRasterizationVarying {
970 @builtin(position) position: vec4<f32>,
971 @location(0) st_position: vec2<f32>,
972 @location(1) vertex_id: u32,
973 //TODO: use `clip_distance` once Naga supports it
974 @location(3) clip_distances: vec4<f32>,
975}
976
977@vertex
978fn vs_path_rasterization(@builtin(vertex_index) vertex_id: u32) -> PathRasterizationVarying {
979 let v = b_path_vertices[vertex_id];
980
981 var out = PathRasterizationVarying();
982 out.position = to_device_position_impl(v.xy_position);
983 out.st_position = v.st_position;
984 out.vertex_id = vertex_id;
985 out.clip_distances = distance_from_clip_rect_impl(v.xy_position, v.bounds);
986 return out;
987}
988
989@fragment
990fn fs_path_rasterization(input: PathRasterizationVarying) -> @location(0) vec4<f32> {
991 let dx = dpdx(input.st_position);
992 let dy = dpdy(input.st_position);
993 if (any(input.clip_distances < vec4<f32>(0.0))) {
994 return vec4<f32>(0.0);
995 }
996
997 let v = b_path_vertices[input.vertex_id];
998 let background = v.color;
999 let bounds = v.bounds;
1000
1001 var alpha: f32;
1002 if (length(vec2<f32>(dx.x, dy.x)) < 0.001) {
1003 // If the gradient is too small, return a solid color.
1004 alpha = 1.0;
1005 } else {
1006 let gradient = 2.0 * input.st_position.xx * vec2<f32>(dx.x, dy.x) - vec2<f32>(dx.y, dy.y);
1007 let f = input.st_position.x * input.st_position.x - input.st_position.y;
1008 let distance = f / length(gradient);
1009 alpha = saturate(0.5 - distance);
1010 }
1011 let gradient_color = prepare_gradient_color(
1012 background.tag,
1013 background.color_space,
1014 background.solid,
1015 background.colors,
1016 );
1017 let color = gradient_color(background, input.position.xy, bounds,
1018 gradient_color.solid, gradient_color.color0, gradient_color.color1);
1019 return vec4<f32>(color.rgb * color.a * alpha, color.a * alpha);
1020}
1021
1022// --- paths --- //
1023
1024struct PathSprite {
1025 bounds: Bounds,
1026}
1027var<storage, read> b_path_sprites: array<PathSprite>;
1028
1029struct PathVarying {
1030 @builtin(position) position: vec4<f32>,
1031 @location(0) texture_coords: vec2<f32>,
1032}
1033
1034@vertex
1035fn vs_path(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> PathVarying {
1036 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1037 let sprite = b_path_sprites[instance_id];
1038 // Don't apply content mask because it was already accounted for when rasterizing the path.
1039 let device_position = to_device_position(unit_vertex, sprite.bounds);
1040 // For screen-space intermediate texture, convert screen position to texture coordinates
1041 let screen_position = sprite.bounds.origin + unit_vertex * sprite.bounds.size;
1042 let texture_coords = screen_position / globals.viewport_size;
1043
1044 var out = PathVarying();
1045 out.position = device_position;
1046 out.texture_coords = texture_coords;
1047
1048 return out;
1049}
1050
1051@fragment
1052fn fs_path(input: PathVarying) -> @location(0) vec4<f32> {
1053 let sample = textureSample(t_sprite, s_sprite, input.texture_coords);
1054 return sample;
1055}
1056
1057// --- underlines --- //
1058
1059struct Underline {
1060 order: u32,
1061 pad: u32,
1062 bounds: Bounds,
1063 content_mask: Bounds,
1064 color: Hsla,
1065 thickness: f32,
1066 wavy: u32,
1067}
1068var<storage, read> b_underlines: array<Underline>;
1069
1070struct UnderlineVarying {
1071 @builtin(position) position: vec4<f32>,
1072 @location(0) @interpolate(flat) color: vec4<f32>,
1073 @location(1) @interpolate(flat) underline_id: u32,
1074 //TODO: use `clip_distance` once Naga supports it
1075 @location(3) clip_distances: vec4<f32>,
1076}
1077
1078@vertex
1079fn vs_underline(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> UnderlineVarying {
1080 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1081 let underline = b_underlines[instance_id];
1082
1083 var out = UnderlineVarying();
1084 out.position = to_device_position(unit_vertex, underline.bounds);
1085 out.color = hsla_to_rgba(underline.color);
1086 out.underline_id = instance_id;
1087 out.clip_distances = distance_from_clip_rect(unit_vertex, underline.bounds, underline.content_mask);
1088 return out;
1089}
1090
1091@fragment
1092fn fs_underline(input: UnderlineVarying) -> @location(0) vec4<f32> {
1093 const WAVE_FREQUENCY: f32 = 2.0;
1094 const WAVE_HEIGHT_RATIO: f32 = 0.8;
1095
1096 // Alpha clip first, since we don't have `clip_distance`.
1097 if (any(input.clip_distances < vec4<f32>(0.0))) {
1098 return vec4<f32>(0.0);
1099 }
1100
1101 let underline = b_underlines[input.underline_id];
1102 if ((underline.wavy & 0xFFu) == 0u)
1103 {
1104 return blend_color(input.color, input.color.a);
1105 }
1106
1107 let half_thickness = underline.thickness * 0.5;
1108
1109 let st = (input.position.xy - underline.bounds.origin) / underline.bounds.size.y - vec2<f32>(0.0, 0.5);
1110 let frequency = M_PI_F * WAVE_FREQUENCY * underline.thickness / underline.bounds.size.y;
1111 let amplitude = (underline.thickness * WAVE_HEIGHT_RATIO) / underline.bounds.size.y;
1112
1113 let sine = sin(st.x * frequency) * amplitude;
1114 let dSine = cos(st.x * frequency) * amplitude * frequency;
1115 let distance = (st.y - sine) / sqrt(1.0 + dSine * dSine);
1116 let distance_in_pixels = distance * underline.bounds.size.y;
1117 let distance_from_top_border = distance_in_pixels - half_thickness;
1118 let distance_from_bottom_border = distance_in_pixels + half_thickness;
1119 let alpha = saturate(0.5 - max(-distance_from_bottom_border, distance_from_top_border));
1120 return blend_color(input.color, alpha * input.color.a);
1121}
1122
1123// --- monochrome sprites --- //
1124
1125struct MonochromeSprite {
1126 order: u32,
1127 pad: u32,
1128 bounds: Bounds,
1129 content_mask: Bounds,
1130 color: Hsla,
1131 tile: AtlasTile,
1132 transformation: TransformationMatrix,
1133}
1134var<storage, read> b_mono_sprites: array<MonochromeSprite>;
1135
1136struct MonoSpriteVarying {
1137 @builtin(position) position: vec4<f32>,
1138 @location(0) tile_position: vec2<f32>,
1139 @location(1) @interpolate(flat) color: vec4<f32>,
1140 @location(3) clip_distances: vec4<f32>,
1141}
1142
1143@vertex
1144fn vs_mono_sprite(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> MonoSpriteVarying {
1145 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1146 let sprite = b_mono_sprites[instance_id];
1147
1148 var out = MonoSpriteVarying();
1149 out.position = to_device_position_transformed(unit_vertex, sprite.bounds, sprite.transformation);
1150
1151 out.tile_position = to_tile_position(unit_vertex, sprite.tile);
1152 out.color = hsla_to_rgba(sprite.color);
1153 out.clip_distances = distance_from_clip_rect(unit_vertex, sprite.bounds, sprite.content_mask);
1154 return out;
1155}
1156
1157@fragment
1158fn fs_mono_sprite(input: MonoSpriteVarying) -> @location(0) vec4<f32> {
1159 let sample = textureSample(t_sprite, s_sprite, input.tile_position).r;
1160 let alpha_corrected = apply_contrast_and_gamma_correction(sample, input.color.rgb, grayscale_enhanced_contrast, gamma_ratios);
1161
1162 // Alpha clip after using the derivatives.
1163 if (any(input.clip_distances < vec4<f32>(0.0))) {
1164 return vec4<f32>(0.0);
1165 }
1166
1167 // convert to srgb space as the rest of the code (output swapchain) expects that
1168 return blend_color(input.color, alpha_corrected);
1169}
1170
1171// --- polychrome sprites --- //
1172
1173struct PolychromeSprite {
1174 order: u32,
1175 pad: u32,
1176 grayscale: u32,
1177 opacity: f32,
1178 bounds: Bounds,
1179 content_mask: Bounds,
1180 corner_radii: Corners,
1181 tile: AtlasTile,
1182}
1183var<storage, read> b_poly_sprites: array<PolychromeSprite>;
1184
1185struct PolySpriteVarying {
1186 @builtin(position) position: vec4<f32>,
1187 @location(0) tile_position: vec2<f32>,
1188 @location(1) @interpolate(flat) sprite_id: u32,
1189 @location(3) clip_distances: vec4<f32>,
1190}
1191
1192@vertex
1193fn vs_poly_sprite(@builtin(vertex_index) vertex_id: u32, @builtin(instance_index) instance_id: u32) -> PolySpriteVarying {
1194 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1195 let sprite = b_poly_sprites[instance_id];
1196
1197 var out = PolySpriteVarying();
1198 out.position = to_device_position(unit_vertex, sprite.bounds);
1199 out.tile_position = to_tile_position(unit_vertex, sprite.tile);
1200 out.sprite_id = instance_id;
1201 out.clip_distances = distance_from_clip_rect(unit_vertex, sprite.bounds, sprite.content_mask);
1202 return out;
1203}
1204
1205@fragment
1206fn fs_poly_sprite(input: PolySpriteVarying) -> @location(0) vec4<f32> {
1207 let sample = textureSample(t_sprite, s_sprite, input.tile_position);
1208 // Alpha clip after using the derivatives.
1209 if (any(input.clip_distances < vec4<f32>(0.0))) {
1210 return vec4<f32>(0.0);
1211 }
1212
1213 let sprite = b_poly_sprites[input.sprite_id];
1214 let distance = quad_sdf(input.position.xy, sprite.bounds, sprite.corner_radii);
1215
1216 var color = sample;
1217 if ((sprite.grayscale & 0xFFu) != 0u) {
1218 let grayscale = dot(color.rgb, GRAYSCALE_FACTORS);
1219 color = vec4<f32>(vec3<f32>(grayscale), sample.a);
1220 }
1221 return blend_color(color, sprite.opacity * saturate(0.5 - distance));
1222}
1223
1224// --- surfaces --- //
1225
1226struct SurfaceParams {
1227 bounds: Bounds,
1228 content_mask: Bounds,
1229}
1230
1231var<uniform> surface_locals: SurfaceParams;
1232var t_y: texture_2d<f32>;
1233var t_cb_cr: texture_2d<f32>;
1234var s_surface: sampler;
1235
1236const ycbcr_to_RGB = mat4x4<f32>(
1237 vec4<f32>( 1.0000f, 1.0000f, 1.0000f, 0.0),
1238 vec4<f32>( 0.0000f, -0.3441f, 1.7720f, 0.0),
1239 vec4<f32>( 1.4020f, -0.7141f, 0.0000f, 0.0),
1240 vec4<f32>(-0.7010f, 0.5291f, -0.8860f, 1.0),
1241);
1242
1243struct SurfaceVarying {
1244 @builtin(position) position: vec4<f32>,
1245 @location(0) texture_position: vec2<f32>,
1246 @location(3) clip_distances: vec4<f32>,
1247}
1248
1249@vertex
1250fn vs_surface(@builtin(vertex_index) vertex_id: u32) -> SurfaceVarying {
1251 let unit_vertex = vec2<f32>(f32(vertex_id & 1u), 0.5 * f32(vertex_id & 2u));
1252
1253 var out = SurfaceVarying();
1254 out.position = to_device_position(unit_vertex, surface_locals.bounds);
1255 out.texture_position = unit_vertex;
1256 out.clip_distances = distance_from_clip_rect(unit_vertex, surface_locals.bounds, surface_locals.content_mask);
1257 return out;
1258}
1259
1260@fragment
1261fn fs_surface(input: SurfaceVarying) -> @location(0) vec4<f32> {
1262 // Alpha clip after using the derivatives.
1263 if (any(input.clip_distances < vec4<f32>(0.0))) {
1264 return vec4<f32>(0.0);
1265 }
1266
1267 let y_cb_cr = vec4<f32>(
1268 textureSampleLevel(t_y, s_surface, input.texture_position, 0.0).r,
1269 textureSampleLevel(t_cb_cr, s_surface, input.texture_position, 0.0).rg,
1270 1.0);
1271
1272 return ycbcr_to_RGB * y_cb_cr;
1273}