1#include <metal_stdlib>
2#include "shaders.h"
3
4using namespace metal;
5
6float4 coloru_to_colorf(uchar4 coloru) {
7 return float4(coloru) / float4(0xff, 0xff, 0xff, 0xff);
8}
9
10float4 to_device_position(float2 pixel_position, float2 viewport_size) {
11 return float4(pixel_position / viewport_size * float2(2., -2.) + float2(-1., 1.), 0., 1.);
12}
13
14// A standard gaussian function, used for weighting samples
15float gaussian(float x, float sigma) {
16 return exp(-(x * x) / (2. * sigma * sigma)) / (sqrt(2. * M_PI_F) * sigma);
17}
18
19// This approximates the error function, needed for the gaussian integral
20float2 erf(float2 x) {
21 float2 s = sign(x);
22 float2 a = abs(x);
23 x = 1. + (0.278393 + (0.230389 + 0.078108 * (a * a)) * a) * a;
24 x *= x;
25 return s - s / (x * x);
26}
27
28float blur_along_x(float x, float y, float sigma, float corner, float2 halfSize) {
29 float delta = min(halfSize.y - corner - abs(y), 0.);
30 float curved = halfSize.x - corner + sqrt(max(0., corner * corner - delta * delta));
31 float2 integral = 0.5 + 0.5 * erf((x + float2(-curved, curved)) * (sqrt(0.5) / sigma));
32 return integral.y - integral.x;
33}
34
35struct QuadFragmentInput {
36 float4 position [[position]];
37 float2 atlas_position; // only used in the image shader
38 float2 origin;
39 float2 size;
40 float4 background_color;
41 float border_top;
42 float border_right;
43 float border_bottom;
44 float border_left;
45 float4 border_color;
46 float corner_radius;
47};
48
49float4 quad_sdf(QuadFragmentInput input) {
50 float2 half_size = input.size / 2.;
51 float2 center = input.origin + half_size;
52 float2 center_to_point = input.position.xy - center;
53 float2 rounded_edge_to_point = abs(center_to_point) - half_size + input.corner_radius;
54 float distance = length(max(0., rounded_edge_to_point)) + min(0., max(rounded_edge_to_point.x, rounded_edge_to_point.y)) - input.corner_radius;
55
56 float vertical_border = center_to_point.x <= 0. ? input.border_left : input.border_right;
57 float horizontal_border = center_to_point.y <= 0. ? input.border_top : input.border_bottom;
58 float2 inset_size = half_size - input.corner_radius - float2(vertical_border, horizontal_border);
59 float2 point_to_inset_corner = abs(center_to_point) - inset_size;
60 float border_width;
61 if (point_to_inset_corner.x < 0. && point_to_inset_corner.y < 0.) {
62 border_width = 0.;
63 } else if (point_to_inset_corner.y > point_to_inset_corner.x) {
64 border_width = horizontal_border;
65 } else {
66 border_width = vertical_border;
67 }
68
69 float4 color;
70 if (border_width == 0.) {
71 color = input.background_color;
72 } else {
73 float4 border_color = float4(mix(float3(input.background_color), float3(input.border_color), input.border_color.a), 1.);
74 float inset_distance = distance + border_width;
75 color = mix(
76 border_color,
77 input.background_color,
78 saturate(0.5 - inset_distance)
79 );
80 }
81
82 float4 coverage = float4(1., 1., 1., saturate(0.5 - distance));
83 return coverage * color;
84}
85
86vertex QuadFragmentInput quad_vertex(
87 uint unit_vertex_id [[vertex_id]],
88 uint quad_id [[instance_id]],
89 constant float2 *unit_vertices [[buffer(GPUIQuadInputIndexVertices)]],
90 constant GPUIQuad *quads [[buffer(GPUIQuadInputIndexQuads)]],
91 constant GPUIUniforms *uniforms [[buffer(GPUIQuadInputIndexUniforms)]]
92) {
93 float2 unit_vertex = unit_vertices[unit_vertex_id];
94 GPUIQuad quad = quads[quad_id];
95 float2 position = unit_vertex * quad.size + quad.origin;
96 float4 device_position = to_device_position(position, uniforms->viewport_size);
97
98 return QuadFragmentInput {
99 device_position,
100 float2(0., 0.),
101 quad.origin,
102 quad.size,
103 coloru_to_colorf(quad.background_color),
104 quad.border_top,
105 quad.border_right,
106 quad.border_bottom,
107 quad.border_left,
108 coloru_to_colorf(quad.border_color),
109 quad.corner_radius,
110 };
111}
112
113fragment float4 quad_fragment(
114 QuadFragmentInput input [[stage_in]]
115) {
116 return quad_sdf(input);
117}
118
119struct ShadowFragmentInput {
120 float4 position [[position]];
121 vector_float2 origin;
122 vector_float2 size;
123 float corner_radius;
124 float sigma;
125 vector_uchar4 color;
126};
127
128vertex ShadowFragmentInput shadow_vertex(
129 uint unit_vertex_id [[vertex_id]],
130 uint shadow_id [[instance_id]],
131 constant float2 *unit_vertices [[buffer(GPUIShadowInputIndexVertices)]],
132 constant GPUIShadow *shadows [[buffer(GPUIShadowInputIndexShadows)]],
133 constant GPUIUniforms *uniforms [[buffer(GPUIShadowInputIndexUniforms)]]
134) {
135 float2 unit_vertex = unit_vertices[unit_vertex_id];
136 GPUIShadow shadow = shadows[shadow_id];
137
138 float margin = 3. * shadow.sigma;
139 float2 position = unit_vertex * (shadow.size + 2. * margin) + shadow.origin - margin;
140 float4 device_position = to_device_position(position, uniforms->viewport_size);
141
142 return ShadowFragmentInput {
143 device_position,
144 shadow.origin,
145 shadow.size,
146 shadow.corner_radius,
147 shadow.sigma,
148 shadow.color,
149 };
150}
151
152fragment float4 shadow_fragment(
153 ShadowFragmentInput input [[stage_in]]
154) {
155 float sigma = input.sigma;
156 float corner_radius = input.corner_radius;
157 float2 half_size = input.size / 2.;
158 float2 center = input.origin + half_size;
159 float2 point = input.position.xy - center;
160
161 // The signal is only non-zero in a limited range, so don't waste samples
162 float low = point.y - half_size.y;
163 float high = point.y + half_size.y;
164 float start = clamp(-3. * sigma, low, high);
165 float end = clamp(3. * sigma, low, high);
166
167 // Accumulate samples (we can get away with surprisingly few samples)
168 float step = (end - start) / 4.;
169 float y = start + step * 0.5;
170 float alpha = 0.;
171 for (int i = 0; i < 4; i++) {
172 alpha += blur_along_x(point.x, point.y - y, sigma, corner_radius, half_size) * gaussian(y, sigma) * step;
173 y += step;
174 }
175
176 return float4(1., 1., 1., alpha) * coloru_to_colorf(input.color);
177}
178
179struct SpriteFragmentInput {
180 float4 position [[position]];
181 float2 atlas_position;
182 float4 color [[flat]];
183 uchar compute_winding [[flat]];
184};
185
186vertex SpriteFragmentInput sprite_vertex(
187 uint unit_vertex_id [[vertex_id]],
188 uint sprite_id [[instance_id]],
189 constant float2 *unit_vertices [[buffer(GPUISpriteVertexInputIndexVertices)]],
190 constant GPUISprite *sprites [[buffer(GPUISpriteVertexInputIndexSprites)]],
191 constant float2 *viewport_size [[buffer(GPUISpriteVertexInputIndexViewportSize)]],
192 constant float2 *atlas_size [[buffer(GPUISpriteVertexInputIndexAtlasSize)]]
193) {
194 float2 unit_vertex = unit_vertices[unit_vertex_id];
195 GPUISprite sprite = sprites[sprite_id];
196 float2 position = unit_vertex * sprite.target_size + sprite.origin;
197 float4 device_position = to_device_position(position, *viewport_size);
198 float2 atlas_position = (unit_vertex * sprite.source_size + sprite.atlas_origin) / *atlas_size;
199
200 return SpriteFragmentInput {
201 device_position,
202 atlas_position,
203 coloru_to_colorf(sprite.color),
204 sprite.compute_winding
205 };
206}
207
208fragment float4 sprite_fragment(
209 SpriteFragmentInput input [[stage_in]],
210 texture2d<float> atlas [[ texture(GPUISpriteFragmentInputIndexAtlas) ]]
211) {
212 constexpr sampler atlas_sampler(mag_filter::linear, min_filter::linear);
213 float4 color = input.color;
214 float4 sample = atlas.sample(atlas_sampler, input.atlas_position);
215 float mask;
216 if (input.compute_winding) {
217 mask = 1. - abs(1. - fmod(sample.r, 2.));
218 } else {
219 mask = sample.a;
220 }
221 color.a *= mask;
222 return color;
223}
224
225vertex QuadFragmentInput image_vertex(
226 uint unit_vertex_id [[vertex_id]],
227 uint image_id [[instance_id]],
228 constant float2 *unit_vertices [[buffer(GPUIImageVertexInputIndexVertices)]],
229 constant GPUIImage *images [[buffer(GPUIImageVertexInputIndexImages)]],
230 constant float2 *viewport_size [[buffer(GPUIImageVertexInputIndexViewportSize)]],
231 constant float2 *atlas_size [[buffer(GPUIImageVertexInputIndexAtlasSize)]]
232) {
233 float2 unit_vertex = unit_vertices[unit_vertex_id];
234 GPUIImage image = images[image_id];
235 float2 position = unit_vertex * image.target_size + image.origin;
236 float4 device_position = to_device_position(position, *viewport_size);
237 float2 atlas_position = (unit_vertex * image.source_size + image.atlas_origin) / *atlas_size;
238
239 return QuadFragmentInput {
240 device_position,
241 atlas_position,
242 image.origin,
243 image.target_size,
244 float4(0.),
245 image.border_top,
246 image.border_right,
247 image.border_bottom,
248 image.border_left,
249 coloru_to_colorf(image.border_color),
250 image.corner_radius,
251 };
252}
253
254fragment float4 image_fragment(
255 QuadFragmentInput input [[stage_in]],
256 texture2d<float> atlas [[ texture(GPUIImageFragmentInputIndexAtlas) ]]
257) {
258 constexpr sampler atlas_sampler(mag_filter::linear, min_filter::linear);
259 input.background_color = atlas.sample(atlas_sampler, input.atlas_position);
260 return quad_sdf(input);
261}
262
263struct PathAtlasVertexOutput {
264 float4 position [[position]];
265 float2 st_position;
266 float clip_rect_distance [[clip_distance]] [4];
267};
268
269struct PathAtlasFragmentInput {
270 float4 position [[position]];
271 float2 st_position;
272};
273
274vertex PathAtlasVertexOutput path_atlas_vertex(
275 uint vertex_id [[vertex_id]],
276 constant GPUIPathVertex *vertices [[buffer(GPUIPathAtlasVertexInputIndexVertices)]],
277 constant float2 *atlas_size [[buffer(GPUIPathAtlasVertexInputIndexAtlasSize)]]
278) {
279 GPUIPathVertex v = vertices[vertex_id];
280 float4 device_position = to_device_position(v.xy_position, *atlas_size);
281 return PathAtlasVertexOutput {
282 device_position,
283 v.st_position,
284 {
285 v.xy_position.x - v.clip_rect_origin.x,
286 v.clip_rect_origin.x + v.clip_rect_size.x - v.xy_position.x,
287 v.xy_position.y - v.clip_rect_origin.y,
288 v.clip_rect_origin.y + v.clip_rect_size.y - v.xy_position.y
289 }
290 };
291}
292
293fragment float4 path_atlas_fragment(
294 PathAtlasFragmentInput input [[stage_in]]
295) {
296 float2 dx = dfdx(input.st_position);
297 float2 dy = dfdy(input.st_position);
298 float2 gradient = float2(
299 (2. * input.st_position.x) * dx.x - dx.y,
300 (2. * input.st_position.x) * dy.x - dy.y
301 );
302 float f = (input.st_position.x * input.st_position.x) - input.st_position.y;
303 float distance = f / length(gradient);
304 float alpha = saturate(0.5 - distance);
305 return float4(alpha, 0., 0., 1.);
306}