1; Variables
  2
  3(identifier) @variable
  4
  5; Properties
  6
  7(property_identifier) @property
  8(shorthand_property_identifier) @property
  9(shorthand_property_identifier_pattern) @property
 10
 11; Function and method calls
 12
 13(call_expression
 14  function: (identifier) @function)
 15
 16(call_expression
 17  function: (member_expression
 18    property: (property_identifier) @function.method))
 19
 20; Function and method definitions
 21
 22(function_expression
 23  name: (identifier) @function)
 24(function_declaration
 25  name: (identifier) @function)
 26(method_definition
 27  name: (property_identifier) @function.method)
 28
 29(pair
 30  key: (property_identifier) @function.method
 31  value: [(function_expression) (arrow_function)])
 32
 33(assignment_expression
 34  left: (member_expression
 35    property: (property_identifier) @function.method)
 36  right: [(function_expression) (arrow_function)])
 37
 38(variable_declarator
 39  name: (identifier) @function
 40  value: [(function_expression) (arrow_function)])
 41
 42(assignment_expression
 43  left: (identifier) @function
 44  right: [(function_expression) (arrow_function)])
 45
 46; Special identifiers
 47
 48((identifier) @constructor
 49 (#match? @constructor "^[A-Z]"))
 50
 51((identifier) @type
 52 (#match? @type "^[A-Z]"))
 53(type_identifier) @type
 54(predefined_type) @type.builtin
 55
 56([
 57  (identifier)
 58  (shorthand_property_identifier)
 59  (shorthand_property_identifier_pattern)
 60 ] @constant
 61 (#match? @constant "^_*[A-Z_][A-Z\\d_]*$"))
 62
 63; Literals
 64
 65(this) @variable.special
 66(super) @variable.special
 67
 68[
 69  (null)
 70  (undefined)
 71] @constant.builtin
 72
 73[
 74  (true)
 75  (false)
 76] @boolean
 77
 78(comment) @comment
 79
 80[
 81  (string)
 82  (template_string)
 83  (template_literal_type)
 84] @string
 85
 86(escape_sequence) @string.escape
 87
 88(regex) @string.regex
 89(number) @number
 90
 91; Tokens
 92
 93[
 94  ";"
 95  "?."
 96  "."
 97  ","
 98  ":"
 99  "?"
100] @punctuation.delimiter
101
102[
103  "..."
104  "-"
105  "--"
106  "-="
107  "+"
108  "++"
109  "+="
110  "*"
111  "*="
112  "**"
113  "**="
114  "/"
115  "/="
116  "%"
117  "%="
118  "<"
119  "<="
120  "<<"
121  "<<="
122  "="
123  "=="
124  "==="
125  "!"
126  "!="
127  "!=="
128  "=>"
129  ">"
130  ">="
131  ">>"
132  ">>="
133  ">>>"
134  ">>>="
135  "~"
136  "^"
137  "&"
138  "|"
139  "^="
140  "&="
141  "|="
142  "&&"
143  "||"
144  "??"
145  "&&="
146  "||="
147  "??="
148] @operator
149
150[
151  "("
152  ")"
153  "["
154  "]"
155  "{"
156  "}"
157]  @punctuation.bracket
158
159[
160  "as"
161  "async"
162  "await"
163  "break"
164  "case"
165  "catch"
166  "class"
167  "const"
168  "continue"
169  "debugger"
170  "default"
171  "delete"
172  "do"
173  "else"
174  "export"
175  "extends"
176  "finally"
177  "for"
178  "from"
179  "function"
180  "get"
181  "if"
182  "import"
183  "in"
184  "instanceof"
185  "is"
186  "let"
187  "new"
188  "of"
189  "return"
190  "satisfies"
191  "set"
192  "static"
193  "switch"
194  "target"
195  "throw"
196  "try"
197  "typeof"
198  "using"
199  "var"
200  "void"
201  "while"
202  "with"
203  "yield"
204] @keyword
205
206(template_substitution
207  "${" @punctuation.special
208  "}" @punctuation.special) @embedded
209
210(template_type
211  "${" @punctuation.special
212  "}" @punctuation.special) @embedded
213
214(type_arguments
215  "<" @punctuation.bracket
216  ">" @punctuation.bracket)
217
218; Keywords
219
220[ "abstract"
221  "declare"
222  "enum"
223  "export"
224  "implements"
225  "infer"
226  "interface"
227  "keyof"
228  "namespace"
229  "private"
230  "protected"
231  "public"
232  "type"
233  "readonly"
234  "override"
235] @keyword