From 00278f43bb0c5ce7c9961fca42d8e924a0cb157a Mon Sep 17 00:00:00 2001
From: Cameron Mcloughlin <cameron.studdstreet@gmail.com>
Date: Mon, 27 Oct 2025 19:58:04 +0000
Subject: [PATCH] Add Rust convenience Tree-sitter injections for common crates
 (#41258)

---
 crates/languages/src/rust/injections.scm | 48 ++++++++++++++++++++++--
 1 file changed, 45 insertions(+), 3 deletions(-)

diff --git a/crates/languages/src/rust/injections.scm b/crates/languages/src/rust/injections.scm
index 91c092b353b615c5dff1f7189af816c9205cbf21..20d4cf83541f9241b2e296f8dbc4a5cb7a3a5fe7 100644
--- a/crates/languages/src/rust/injections.scm
+++ b/crates/languages/src/rust/injections.scm
@@ -2,8 +2,10 @@
     (#set! injection.language "comment"))
 
 (macro_invocation
-    macro: [(identifier) (scoped_identifier)] @_macro_name
-    (#not-any-of? @_macro_name "view" "html")
+    macro: [
+        ((identifier) @_macro_name)
+        (scoped_identifier (identifier) @_macro_name .)
+    ]
     (token_tree) @injection.content
     (#set! injection.language "rust"))
 
@@ -11,8 +13,48 @@
 ; it wants to inject inside of rust, instead of modifying the rust
 ; injections to support leptos injections
 (macro_invocation
-    macro: [(identifier) (scoped_identifier)] @_macro_name
+    macro: [
+        ((identifier) @_macro_name)
+        (scoped_identifier (identifier) @_macro_name .)
+    ]
     (#any-of? @_macro_name "view" "html")
     (token_tree) @injection.content
     (#set! injection.language "rstml")
     )
+
+(macro_invocation
+    macro: [
+        ((identifier) @_macro_name)
+        (scoped_identifier (identifier) @_macro_name .)
+    ]
+    (#any-of? @_macro_name "sql")
+    (_) @injection.content
+    (#set! injection.language "sql")
+    )
+
+; lazy_regex
+(macro_invocation
+    macro: [
+        ((identifier) @_macro_name)
+        (scoped_identifier (identifier) @_macro_name .)
+    ]
+    (token_tree [
+        (string_literal (string_content) @injection.content)
+        (raw_string_literal (string_content) @injection.content)
+    ])
+    (#set! injection.language "regex")
+    (#any-of? @_macro_name "regex" "bytes_regex")
+)
+
+(call_expression
+    function: (scoped_identifier) @_fn_path
+    arguments: (arguments
+        [
+            (string_literal (string_content) @injection.content)
+            (raw_string_literal (string_content) @injection.content)
+        ]
+    )
+
+    (#match? @_fn_path ".*Regex(Builder)?::new")
+    (#set! injection.language "regex")
+)