From 7f50055d70929be3c03438874397a7b5f5a013e4 Mon Sep 17 00:00:00 2001
From: Ghostylab <giuliano.gostinfini.93@gmail.com>
Date: Mon, 8 Jul 2024 16:32:20 +0200
Subject: [PATCH] windows: Replace symlinks with files for TSX Tree-sitter
 queries (#13893)

Previously to these changes, as stated in the issue, when someone tried
to use TSX as language for the file, the language was not set and it
disappeared from the selectable language list. This was due to the fact
that that the three files were symlinks, and windows couldn't read them.
I replaced them with normal files.

Fixes #12208.

Release Notes:

- N/A

---------

Co-authored-by: Marshall Bowers <elliott.codes@gmail.com>
---
 crates/languages/src/tsx/brackets.scm |  6 ++-
 crates/languages/src/tsx/indents.scm  | 16 +++++-
 crates/languages/src/tsx/outline.scm  | 77 ++++++++++++++++++++++++++-
 3 files changed, 96 insertions(+), 3 deletions(-)
 mode change 120000 => 100644 crates/languages/src/tsx/brackets.scm
 mode change 120000 => 100644 crates/languages/src/tsx/indents.scm
 mode change 120000 => 100644 crates/languages/src/tsx/outline.scm

diff --git a/crates/languages/src/tsx/brackets.scm b/crates/languages/src/tsx/brackets.scm
deleted file mode 120000
index e6835c943b05c54ca6ecccc0b3bbd7673f668788..0000000000000000000000000000000000000000
--- a/crates/languages/src/tsx/brackets.scm
+++ /dev/null
@@ -1 +0,0 @@
-../typescript/brackets.scm
\ No newline at end of file
diff --git a/crates/languages/src/tsx/brackets.scm b/crates/languages/src/tsx/brackets.scm
new file mode 100644
index 0000000000000000000000000000000000000000..63395f81d84e6452c631a9e582e2d697cba445ef
--- /dev/null
+++ b/crates/languages/src/tsx/brackets.scm
@@ -0,0 +1,5 @@
+("(" @open ")" @close)
+("[" @open "]" @close)
+("{" @open "}" @close)
+("<" @open ">" @close)
+("\"" @open "\"" @close)
diff --git a/crates/languages/src/tsx/indents.scm b/crates/languages/src/tsx/indents.scm
deleted file mode 120000
index 502c2a060af208e476e793db6b0d69060f0a5377..0000000000000000000000000000000000000000
--- a/crates/languages/src/tsx/indents.scm
+++ /dev/null
@@ -1 +0,0 @@
-../typescript/indents.scm
\ No newline at end of file
diff --git a/crates/languages/src/tsx/indents.scm b/crates/languages/src/tsx/indents.scm
new file mode 100644
index 0000000000000000000000000000000000000000..107e6ff8e03b633f408676243c24d0d9707a2a26
--- /dev/null
+++ b/crates/languages/src/tsx/indents.scm
@@ -0,0 +1,15 @@
+[
+    (call_expression)
+    (assignment_expression)
+    (member_expression)
+    (lexical_declaration)
+    (variable_declaration)
+    (assignment_expression)
+    (if_statement)
+    (for_statement)
+] @indent
+
+(_ "[" "]" @end) @indent
+(_ "<" ">" @end) @indent
+(_ "{" "}" @end) @indent
+(_ "(" ")" @end) @indent
diff --git a/crates/languages/src/tsx/outline.scm b/crates/languages/src/tsx/outline.scm
deleted file mode 120000
index a0df409fda15ec9b384fc7659b5c56a6797f9034..0000000000000000000000000000000000000000
--- a/crates/languages/src/tsx/outline.scm
+++ /dev/null
@@ -1 +0,0 @@
-../typescript/outline.scm
\ No newline at end of file
diff --git a/crates/languages/src/tsx/outline.scm b/crates/languages/src/tsx/outline.scm
new file mode 100644
index 0000000000000000000000000000000000000000..fe114e990e9d12ff31a6096284d9f4f8059b8d7f
--- /dev/null
+++ b/crates/languages/src/tsx/outline.scm
@@ -0,0 +1,76 @@
+(internal_module
+    "namespace" @context
+    name: (_) @name) @item
+
+(enum_declaration
+    "enum" @context
+    name: (_) @name) @item
+
+(type_alias_declaration
+    "type" @context
+    name: (_) @name) @item
+
+(function_declaration
+    "async"? @context
+    "function" @context
+    name: (_) @name
+    parameters: (formal_parameters
+      "(" @context
+      ")" @context)) @item
+
+(interface_declaration
+    "interface" @context
+    name: (_) @name) @item
+
+(export_statement
+    (lexical_declaration
+        ["let" "const"] @context
+        (variable_declarator
+            name: (_) @name) @item))
+
+(program
+    (lexical_declaration
+        ["let" "const"] @context
+        (variable_declarator
+            name: (_) @name) @item))
+
+(class_declaration
+    "class" @context
+    name: (_) @name) @item
+
+(method_definition
+    [
+        "get"
+        "set"
+        "async"
+        "*"
+        "readonly"
+        "static"
+        (override_modifier)
+        (accessibility_modifier)
+    ]* @context
+    name: (_) @name
+    parameters: (formal_parameters
+      "(" @context
+      ")" @context)) @item
+
+(public_field_definition
+    [
+        "declare"
+        "readonly"
+        "abstract"
+        "static"
+        (accessibility_modifier)
+    ]* @context
+    name: (_) @name) @item
+
+; Add support for (node:test, bun:test and Jest) runnable
+(call_expression
+    function: (_) @context
+    (#any-of? @context "it" "test" "describe")
+    arguments: (
+        arguments . (string
+            (string_fragment) @name
+        )
+    )
+) @item